2

SQL Server Protocols Network Configurationを取得したい。

ここに画像の説明を入力

Windows レジストリまたはこれに関連する構成ファイルを検索しようとしましたが、見つかった唯一のサンプルは、powershellサーバー ネットワーク プロトコルを有効または無効にする (SQL Server PowerShell)であり、.Net クラスを使用しています。

質問は次のとおりです。delphi を使用して SQL Server プロトコルのネットワーク構成を取得するにはどうすればよいですか?

4

1 に答える 1

5

WMI クラスを使用してServerNetworkProtocol、SQL Server のバージョンに応じて正しい名前空間に接続することもできます。

  • SQL Server 2005 = コンピュータ管理
  • SQL Server 2008 = ComputerManagement10
  • SQL Server 2012 = ComputerManagement11

このサンプルを試す

{$APPTYPE CONSOLE}


uses
  SysUtils,
  ActiveX,
  ComObj,
  Variants;

type
  TMSSQlServerType=(MSSQL2005, MSSQL2008, MSSQL2012);


procedure  GetServerNetworkProtocolInfo(SQlServerType: TMSSQlServerType; const InstanceName: string);
const
  WbemUser            ='';
  WbemPassword        ='';
  WbemComputer        ='localhost';
  wbemFlagForwardOnly = $00000020;
  MSSQLNameSpaces  : array [TMSSQlServerType] of string = ('ComputerManagement','ComputerManagement10','ComputerManagement11');
var
  FSWbemLocator : OLEVariant;
  FWMIService   : OLEVariant;
  FWbemObjectSet: OLEVariant;
  FWbemObject   : OLEVariant;
  oEnum         : IEnumvariant;
  iValue        : LongWord;
begin;
  FSWbemLocator := CreateOleObject('WbemScripting.SWbemLocator');
  FWMIService   := FSWbemLocator.ConnectServer(WbemComputer, Format('root\Microsoft\SqlServer\%s',[MSSQLNameSpaces[SQlServerType]]), WbemUser, WbemPassword);
  FWbemObjectSet:= FWMIService.ExecQuery(Format('SELECT * FROM ServerNetworkProtocol Where InstanceName="%s"', [InstanceName]),'WQL',wbemFlagForwardOnly);
  oEnum         := IUnknown(FWbemObjectSet._NewEnum) as IEnumVariant;
  while oEnum.Next(1, FWbemObject, iValue) = 0 do
  begin
    Writeln(Format('Enabled                        %s',[String(FWbemObject.Enabled)]));// Boolean
    Writeln(Format('MultiIpConfigurationSupport    %s',[String(FWbemObject.MultiIpConfigurationSupport)]));// Boolean
    Writeln(Format('ProtocolDisplayName            %s',[String(FWbemObject.ProtocolDisplayName)]));// String
    Writeln(Format('ProtocolName                   %s',[String(FWbemObject.ProtocolName)]));// String
    Writeln;
    FWbemObject:=Unassigned;
  end;
end;


begin
 try
    CoInitialize(nil);
    try
      GetServerNetworkProtocolInfo(MSSQL2008,'MSSQLSERVER');
    finally
      CoUninitialize;
    end;
 except
    on E:EOleException do
        Writeln(Format('EOleException %s %x', [E.Message,E.ErrorCode]));
    on E:Exception do
        Writeln(E.Classname, ':', E.Message);
 end;
 Writeln('Press Enter to exit');
 Readln;
end.
于 2013-07-18T22:02:15.870 に答える