delphi - SocketHandle から IP とポートを取得する

Question

sockaddr_inポートとアドレスを取得できるように、ソケットハンドルから関連付けを取得するにはどうすればよいですか? または、SocketHandle から IP とポートを取得する方法について他に何かありますか?

例えば：

function GetSocketPort ( s : TSocket ) : Integer;
var
  Addr                  : sockaddr_in;
begin
  // Get sockaddr_in from a socket
end;

function GetSocketAddress ( s : TSocket ) : String;
var
  Addr                  : sockaddr_in;
begin
  // Get sockaddr_in from a socket
end;

function ConnectToHost (Host : pchar; Port : Integer) : TSocket;
var
  Addr                  : sockaddr_in;
begin
  Addr.sin_family       := AF_INET;
  Addr.sin_port         := htons(Port);
  result                := Socket(AF_INET, 1, 6);
  Addr.sin_addr.S_addr  := INET_ADDR(Host);
  if not( (Connect(result, Addr, SizeOf(Addr)) = 0) ) then result := 0;
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  MySocket : TSocket;
begin
  MySocket := ConnectToHost ('127.0.0.1', 8080);
  if MySocket <> 0 then begin
    // GetSocketAddress (MySocket);
    // GetSocketPort (MySocket);
  end;
end;

Answer 1

getsockname次のように、ローカルポートとアドレスの関数とgetpeernameリモートポートの関数を使用できます

function GetLocalSocketPort ( s : TSocket ) : Integer;
var
  Addr                  : TSockAddrIn;
  Size: integer;
begin
  Size := sizeof(Addr);
  getsockname(s, Addr, Size);
  Result := ntohs(Addr.sin_port);
end;

function GetLocalSocketAddress ( s : TSocket ) : String;
var
  Addr                  : TSockAddrIn;
  Size: integer;
begin
  Size := sizeof(Addr);
  getsockname(s, Addr, Size);
  Result := inet_ntoa(Addr.sin_addr);
end;


function GetRemoteSocketPort ( s : TSocket ) : Integer;
var
  Addr                  : TSockAddrIn;
  Size: integer;
begin
  Size := sizeof(Addr);
  getpeername(s, Addr, Size);
  Result := ntohs(Addr.sin_port);
end;

function GetRemoteSocketAddress ( s : TSocket ) : String;
var
  Addr                  : TSockAddrIn;
  Size: integer;
begin
  Size := sizeof(Addr);
  getpeername(s, Addr, Size);
  Result := inet_ntoa(Addr.sin_addr);
end;