11

2 つの stringlist を比較する必要があります。2 番目の stringlist 内の最初の stringlist の検索が、この問題を実行するための唯一のバージョンまたは推奨されるバージョンなのだろうか

私のコードは次のようになります

var
  aFirstStrList: TStringList ;
  aSecondStringList: TStringList; 
  MissingElement_firstElement_not_inside_second: TStringList;
  MissingElement_SecondElement_not_inside_First: TStringList;

...

for i := 0 to aFirstStrList.Count - 1 do
begin
  if aSecondStringList.IndexOf(aFirstStrList[i] < 0 ) then
  begin
    // react on not found elements 
    ....
    MissingElement_firstElement_not_inside_second.add(...);
  end;
end;
// and now same code just opposite search direction .... 
....
4

3 に答える 3

12

を使用する代わりにIndexOf、前に両方のリストを並べ替えて、サイクルごとにリスト全体を検索しないようにします。さらに、これを 1 つのループで実現することもできます。

2 つの個別の文字列リストで結果が必要であると仮定して、次のことを試してください。

procedure CompareStringLists(List1, List2: TStringList;
  Missing1, Missing2: TStrings);
var
  I: Integer;
  J: Integer;
begin
  List1.Sort;
  List2.Sort;
  I := 0;
  J := 0;
  while (I < List1.Count) and (J < List2.Count) do
  begin
    if List1[I] < List2[J] then
    begin
      Missing2.Add(List1[I]);
      Inc(I);
    end
    else if List1[I] > List2[J] then
    begin
      Missing1.Add(List2[J]);
      Inc(J);
    end
    else
    begin
      Inc(I);
      Inc(J);
    end;
  end;
  for I := I to List1.Count - 1 do
    Missing2.Add(List1[I]);
  for J := J to List2.Count - 1 do
    Missing1.Add(List2[J]);
end;

使用法：

procedure TForm1.Button1Click(Sender: TObject);
var
  List1: TStringList;
  List2: TStringList;
begin
  List1 := TStringList.Create;
  List2 := TStringList.Create;
  try
    List1.CommaText := 'A, C, F, G, H, K, L, M, N, O, Q, R';
    List2.CommaText := 'C, D, E, F, J, P, Q, S, T, U, V, W';
    Memo1.Lines.Assign(List1);
    Memo2.Lines.Assign(List2);
    CompareStringLists(List1, List2, Memo3.Lines, Memo4.Lines);
  finally
    List2.Free;
    List1.Free;
  end;
end;
于 2013-07-27T08:05:15.520 に答える
0

最高のパフォーマンス:
入力文字列リストの並べ替え 並べ替えられたリストのマージ
に似たアルゴリズムと比較します(各リストに欠けているものが見つかります)

単純だが遅い:文字列リスト
を結果の文字列リストにコピー
する 最初の文字列リストに対して 1 つのループ (これには逆のループを使用for Count-1 downto 0 do) 2 番目に同じ文字 列
を検索し、見つかった場合 - 両方のリストから削除する

于 2013-07-27T08:00:12.100 に答える