29

ユーザーがキーを2回「押した」ときに、AutoHotkeyでイベントをトリガーしたいと思いescます。ただし、2 回押していない場合 (たとえば、1 秒以内) は、エスケープ キーストロークがフォーカスされているアプリに到達するようにします。

どうすればこれを行うことができますか？

これまでのところ、これを思いつきましたが、2回目のエスケープキーの押下を確認する方法がわかりません:

~Esc::

    Input, TextEntry1, L1 T1
    endKey=%ErrorLevel%

    if( endKey != "Timeout" )
    {
        ; perform my double press operation
        WinMinimize, A
    }
return
4

2 に答える 2

37

AutoHotkeyのドキュメントで答えを見つけました!

; Example #4: Detects when a key has been double-pressed (similar to double-click).
; KeyWait is used to stop the keyboard's auto-repeat feature from creating an unwanted
; double-press when you hold down the RControl key to modify another key.  It does this by
; keeping the hotkey's thread running, which blocks the auto-repeats by relying upon
; #MaxThreadsPerHotkey being at its default setting of 1.
; Note: There is a more elaborate script to distinguish between single, double, and
; triple-presses at the bottom of the SetTimer page.

~RControl::
if (A_PriorHotkey <> "~RControl" or A_TimeSincePriorHotkey > 400)
{
    ; Too much time between presses, so this isn't a double-press.
    KeyWait, RControl
    return
}
MsgBox You double-pressed the right control key.
return

だから私の場合：

~Esc::
if (A_PriorHotkey <> "~Esc" or A_TimeSincePriorHotkey > 400)
{
    ; Too much time between presses, so this isn't a double-press.
    KeyWait, Esc
    return
}
WinMinimize, A
return
于 2009-11-25T02:31:37.983 に答える