0

したがって、私のマリオ プロジェクトには、マリオの動きに欠かせないものを含める必要があります。もちろん、それは短い高さまたはかなり大きな高さでジャンプするためのオプションです。ご存知のように、ジャンプ ボタンを押し続けると、彼はより高くジャンプします。それが私の目標です。私の場合、そのボタンは X であり、その方法がわかりません。

これは現在私の失敗した試みであり、私の変数ではデフォルトで重力が 0.87 に設定されています。

これは私のkeyDownHandlerにあります（キーが押されたとき）

    if (event.keyCode == Keyboard.X && onGround == true)
        {
            vy +=  jumpForce;
            holdJump = true;
            onGround = false;

            if(holdJump == true && onGround == false)
            {
                _mario.y += 1;
            }
            else
            {
                vy = vy + (grav * 0.20);
                holdJump = false;
            }

これは私のkeyUpHandlerにあります（キーが押されていない/離されている場合）

    if (event.keyCode == Keyboard.X)
        {
            if (holdJump == false)
            {
                accy = 0;
                gravity = 0.80;
                incSpeedY = 0;
            }
        }
4

1 に答える 1

0

わかりました、コメントを拡張しました。

標準の を使用して、ジャンプキーを離したときに に設定し、地面でジャンプキーを押したときにジャンプ開始速度に設定するだけvy=vyLast-g*(t-tLast)です。vyLastmin(0,vyLast)

これは、赤い円がジャンプする Adob​​e Air アプリケーションのサンプルです。コメントに記述したロジックを実装します。

 <?xml version="1.0" encoding="utf-8"?>
<s:WindowedApplication xmlns:fx="http://ns.adobe.com/mxml/2009" 
                       xmlns:s="library://ns.adobe.com/flex/spark" 
                       xmlns:mx="library://ns.adobe.com/flex/mx"                
                       >
    <fx:Script>
        <![CDATA[
            import flash.utils.getTimer;
            import mx.graphics.SolidColor;
            public var marioY:Number = 0; //jump height above ground (meters)
            public var g:Number = -9.81; //meter/(second^2)
            public var lastTime:Number = NaN;
            public var lastVerticalSpeed:Number = 0;//speed of a flight -meters/second
            public var jumpSpeed:Number = 10;//initial jump speed - meters/second
            public var timeRatio:Number = 1000;//milliseconds in a second
            public var heightRatio:Number = 50; //pixels/meter

            protected function get landed():Boolean{
                return marioY <= 0 && lastVerticalSpeed <= 0;
            }

            protected function onKeyDown(event:KeyboardEvent):void{
                if(event.keyCode==Keyboard.UP && landed){
                    lastVerticalSpeed = jumpSpeed;
                    trace('fly!');
                }               
            }

            protected function onKeyUp(event:KeyboardEvent):void{
                if(event.keyCode==Keyboard.UP){
                    lastVerticalSpeed = Math.min(0,lastVerticalSpeed);
                    trace('fall!');
                }

            }

            protected function onEnterFrame(event:Event):void{
                if(!isNaN(lastTime)){
                    var deltaTime:Number = (getTimer() - lastTime)/timeRatio;                   
                    marioY+=lastVerticalSpeed*deltaTime;
                    if(landed){
                        lastVerticalSpeed=0;
                        marioY=0;
                    }else{
                        lastVerticalSpeed+=g*deltaTime;
                    }
                }
                mario.y=area.height-marioY*heightRatio-20;  
                lastTime = getTimer();              
            }

        ]]>
    </fx:Script> 
    <s:Group width="100%" height="100%" keyDown="onKeyDown(event)" keyUp="onKeyUp(event)"
             enterFrame="onEnterFrame(event)" id="area"
             creationComplete="area.setFocus()"
             >
        <s:Rect width="100%" height="100%" fill="{new SolidColor(0x0000FF)}"/>
        <s:Ellipse id="mario" width="10" height="10" fill="{new SolidColor(0xFF0000)}"
                   y="100" x="100"
                   />

    </s:Group>
</s:WindowedApplication>
于 2013-08-01T20:45:02.643 に答える