3

Excelで隔週の支払い期間を計算する関数を考え出そうとしています。例: 2011 年 7 月 12 日から 2011 年 7 月 26 日 金曜日のみ、給料日は 2011 年 7 月 21 日と 8 月 5 日を返します。ご協力いただきありがとうございます！

4

2 に答える 2

1

ゴール：

任意の入力日付で、隔週の予定支払日を生成する数式を作成します。

隔週と支払日を定義する

上部に表示される日付は 15 日離れています。隔週は 14 日です。2011 年 7 月 12 日 (火) と 2011 年 7 月 25 日 (月) の間に隔週があり、予想される支払い日は 2011 年 8 月 5 日金曜日であると想定しています。また、隔週パターンが無期限に繰り返されると想定しています。

  • 例 1: 2011 年 7 月 11 日の作業は 2011 年 7 月 22 日に支払われる必要があります。
  • 例 2: 2011 年 7 月 12 日の作業は 2011 年 8 月 5 日に支払われる必要があります。
  • 例 3: 2011 年 7 月 25 日の作業は 2011 年 8 月 5 日に支払われるべきであり、 &
  • 例 4: 2011 年 7 月 26 日の作業は、2011 年 8 月 19 日に支払われるべきです。

隔週は、任意の日付Sで始まり、任意の日付Eで終わる14 の連続した稼働日です。S + 13 = E

隔週の予定支払日( EPD ) は、常にE (隔週の終わり) の特定の日数後です。EPDは通常、金曜日です。

ソリューション (セルA1が入力日付であると仮定します)

  1. =A1-MOD(A1,14)+IF(MOD(A1,14)<10,20,34) これは、すべての日付を入力日付の前の土曜日に変換することで機能します: A1、これは便利です。これは、予想される支払い日が常に 20 日または 34 日先になるためです。IF式はこれを適切に適用します。
  2. または =A1+CHOOSE(MOD(A1,14)+1,20,19,18,17,16,15,14,13,12,11,24,23,22,21) 、この数式は同じ主題で機能しますが、すべてを土曜日に変換するのではなく、火曜日に開始して月曜日を含めて 13 日後に終了するすべての隔週の隔週定義では、EPDは常に 11 になるという事実を利用します。曜日によっては25日まで休みです。MOD式は曜日を決定し、CHOOSE式は追加する適切な日数 (11 から 25) を選択します。

私の会社の隔週と予想される支払い日の構成:

私の会社には、隔週の 14 日目が水曜日になるように、木曜日から始まる隔週があります。EPDは常に、隔週の水曜日の終了から 16 日後です。EPDの1 つである任意の金曜日は、 2015 年 12 月 4 日です。この情報を使用して、上記の 2 つの式を調整できます。

  1. =A1-MOD(A1,14)+IF(MOD(A1,14)<5,20,34) 再びすべての日付が土曜日に変換されますが、以前はIF式で "<10" でしたが、今では "<5" になっています。隔週が月曜日ではなく水曜日に終了するためです。
  2. =A1+CHOOSE(MOD(A1,14)+1,20,19,18,17,16,29,28,27,26,25,24,23,22,21) 私の隔週とEPDの定義を除いて、範囲は現在 16 から 29 日です。

日付セットに合わせて変更する方法:

最初の式は、おそらくほとんどの人にとって最も使いやすいものです。日付範囲に合わせて調整するには、次の 4 つのことを定義する必要があります。

  1. d = 入力日付(これはおそらく「A1」のような範囲です)
  2. s = EPDとS (隔週の開始日)の差
  3. e = EPDとE (隔週の終わり)の差
  4. w = MOD( s ,14)

適用: = d -MOD( d ,14)+IF(MOD( d ,14)< w , e , s )

免責事項：数学が少し複雑に見える場合は申し訳ありませんが、誰かが説明する簡単な方法を持っている場合、私はいつでもそれを受け入れます.

于 2015-12-08T18:48:55.667 に答える