15

WinInet 関数を使用して Delphi から HTTP リクエストを作成しようとしています。

これまでのところ、私は持っています:

function request:string;
var
  hNet,hURL,hRequest: HINTERNET;
begin
  hNet := InternetOpen(PChar('User Agent'),INTERNET_OPEN_TYPE_PRECONFIG or INTERNET_OPEN_TYPE_PRECONFIG, nil, nil, 0);
  if Assigned(hNet) then 
  begin
  try
    hURL := InternetConnect(hNet,PChar('http://example.com'),INTERNET_DEFAULT_HTTP_PORT,nil,nil,INTERNET_SERVICE_HTTP,0,DWORD(0));
    if(hURL<>nil) then
      hRequest := HttpOpenRequest(hURL, 'POST', PChar('param=value'),'HTTP/1.0',PChar(''), nil, INTERNET_FLAG_RELOAD or INTERNET_FLAG_PRAGMA_NOCACHE,0);
    if(hRequest<>nil) then
      HttpSendRequest(hRequest, nil, 0, nil, 0);
    InternetCloseHandle(hNet);
  except
    on E : Exception do
      ShowMessage(E.ClassName+' error raised, with message : '+E.Message);
  end;
  end
end;

しかし、これは何もしません (ネットワークの http トラフィックを盗聴して、機能するかどうかを確認しています)。私は InternetOpenURL を正常に使用しましたが、POST 要求も送信する必要があり、その関数はそれを行いません。

誰かが私に簡単な例を見せてもらえますか? 私が望む結果は、http 応答ページを var で文字列として取得することです。

4

3 に答える 3

9

すべてのURL/ファイル名の部分が前のコードで台無しになりました。私は今JeffDeVoreからこれを使用しています、そしてそれはうまく働いています：

function request(const AUrl, AData: AnsiString; blnSSL: Boolean = True): AnsiString;
var
  aBuffer     : Array[0..4096] of Char;
  Header      : TStringStream;
  BufStream   : TMemoryStream;
  sMethod     : AnsiString;
  BytesRead   : Cardinal;
  pSession    : HINTERNET;
  pConnection : HINTERNET;
  pRequest    : HINTERNET;
  parsedURL   : TStringArray;
  port        : Integer;
  flags       : DWord;
begin
  ParsedUrl := ParseUrl(AUrl);

  Result := '';

  pSession := InternetOpen(nil, INTERNET_OPEN_TYPE_PRECONFIG, nil, nil, 0);

  if Assigned(pSession) then
  try
    if blnSSL then
      Port := INTERNET_DEFAULT_HTTPS_PORT
    else
      Port := INTERNET_DEFAULT_HTTP_PORT;
    pConnection := InternetConnect(pSession, PChar(ParsedUrl[0]), port, nil, nil, INTERNET_SERVICE_HTTP, 0, 0);

    if Assigned(pConnection) then
    try
      if (AData = '') then
        sMethod := 'GET'
      else
        sMethod := 'POST';

      if blnSSL then
        flags := INTERNET_FLAG_SECURE or INTERNET_FLAG_KEEP_CONNECTION
      else
        flags := INTERNET_SERVICE_HTTP;

      pRequest := HTTPOpenRequest(pConnection, PChar(sMethod), PChar(ParsedUrl[1]), nil, nil, nil, flags, 0);

      if Assigned(pRequest) then
      try
        Header := TStringStream.Create('');
        try
          with Header do
          begin
            WriteString('Host: ' + ParsedUrl[0] + sLineBreak);
            WriteString('User-Agent: Custom program 1.0'+SLineBreak);
            WriteString('Accept: text/html,application/xhtml+xml,application/xml;q=0.9,*/*;q=0.8'+SLineBreak);
            WriteString('Accept-Language: en-us,en;q=0.5' + SLineBreak);
            WriteString('Accept-Charset: ISO-8859-1,utf-8;q=0.7,*;q=0.7'+SLineBreak);
            WriteString('Keep-Alive: 300'+ SLineBreak);
            WriteString('Connection: keep-alive'+ SlineBreak+SLineBreak);
          end;

          HttpAddRequestHeaders(pRequest, PChar(Header.DataString), Length(Header.DataString), HTTP_ADDREQ_FLAG_ADD);

          if HTTPSendRequest(pRequest, nil, 0, Pointer(AData), Length(AData)) then
          begin
            BufStream := TMemoryStream.Create;
            try
              while InternetReadFile(pRequest, @aBuffer, SizeOf(aBuffer), BytesRead) do
              begin
                if (BytesRead = 0) then Break;
                BufStream.Write(aBuffer, BytesRead);
              end;

              aBuffer[0] := #0;
              BufStream.Write(aBuffer, 1);
              Result := PChar(BufStream.Memory);
            finally
              BufStream.Free;
            end;
          end;
        finally
          Header.Free;
        end;
      finally
        InternetCloseHandle(pRequest);
      end;
    finally
      InternetCloseHandle(pConnection);
    end;
  finally
    InternetCloseHandle(pSession);
  end;
end;

ParseUrlは、URLを「hostname / filename」に分割する関数であり、TStringArrayは文字列の配列です。明日もコードを確認する必要がありますが、問題はないようで、スニファで投稿データとヘッダーが送信されているのがわかりました。

于 2009-12-01T04:57:44.430 に答える
2

個人的には、すべてのTCP/IP作業にシナプスライブラリを使用することを好みます。たとえば、単純なHTTPPOSTは次のようにコーディングできます。

uses
  httpsend;

function testpost;
begin
  stm := tStringstream.create('param=value');
  try
    HttpPostBinary('http://example.com',Stm);
  finally
    stm.free;
  end;
end;

ライブラリはよく書かれており、特定の要件に合わせて非常に簡単に変更できます。最新のSubversionリリースは、Delphi2009とDelphi2010の両方で問題なく動作します。このフレームワークはコンポーネントベースではなく、マルチスレッド環境でうまく機能する一連のクラスとプロシージャです。

于 2009-12-01T17:06:00.183 に答える
1

3 番目のパラメーター (lpszObjectName)は、要求するURLHttpOpenRequestである必要があります。そのため、ドキュメントでは 5 番目のパラメーター (lpszReferer) を「要求内の URL (lpszObjectName) が取得されたドキュメントの URL を指定する null で終わる文字列へのポインター」と説明しています。

投稿されたデータはHttpSendRequest;で送信されます。lpOptional パラメータは次のように記述されます。

要求ヘッダーの直後に送信される任意のデータを含むバッファーへのポインター。このパラメーターは通常、POST および PUT 操作に使用されます。オプションのデータは、サーバーにポストされるリソースまたは情報です。送信するオプションのデータがない場合、このパラメーターは NULL にすることができます。

の 2 番目のパラメーターは、サーバー名のみにInternetOpenする必要があります。プロトコルを含めないでください。6 番目のパラメーターで指定するプロトコル。

リクエストを送信したら、 と でレスポンスを読むことができInternetReadFileますInternetQueryDataAvailable。

API 関数が 0 を返すかどうかだけをチェックしてから、次の行に進むことは避けてください。失敗した場合は、電話GetLastErrorして理由を確認してください。投稿したコードは例外を発生させないため、キャッチしても無駄です。（とにかく、あなたがやっているようにそれらを「処理」するのはばかげています。まだ修正方法がわからない例外をキャッチしないでください。他のすべては、呼び出し元、または呼び出し元の呼び出し元などに任せてください。 .)

于 2009-12-01T04:00:55.027 に答える