0

ここにある Perl で書かれたスクリプトを使用しようとしていますが、エラーが発生します。すでに作者に連絡していますが、まだ返事がありません。あなたが私を助けてくれることを願っています。

エラーは次のとおりです。

エラー: /home/bruno321/.config/Clementine/albumcovers/271b13967f57caba893b366730337fb03439c60a.jpg を /media/mp3_1/Musica/Amarok/Two%20Lone%20Swordsmen/A%20Bag%20of%20Blue%20Sparks/ にコピーできません。エラー: ファイルまたはディレクトリが存在しません

スペースを含まないディレクトリでは問題なく実行されるため、エラーはスペースの処理にあると思いますが、スクリプトが意図していると思われるように、ファイルの名前を「cover.jpg」に変更しません（確かに必要ですそれをすることです）。

#!/usr/bin/perl

use strict;
use warnings;
use Carp;

use DBI;
use strict;

use Data::Dumper;
use File::Basename;
use File::Copy;

my $db_filename = shift(@ARGV);
$db_filename
  || croak
"missing mandatory param: sqlite filename\n(try ~/.config/Clementine/clementine.db\n";

if ( !-f $db_filename ) {
    croak "no such database file: $db_filename\n";
}

my $force_rewrite = shift(@ARGV) || 0;

my $dbh =
  DBI->connect( "dbi:SQLite:$db_filename", q{}, q{},
    { 'RaiseError' => 1, 'AutoCommit' => 1 } );

my $query = q{SELECT artist,album, art_automatic,art_manual,filename
             FROM songs WHERE art_manual IS NOT NULL GROUP BY(album)  ORDER BY artist};

my $sth = $dbh->prepare($query);
$sth || croak 'prepare error: ' . $dbh->errstr . "\n";

$sth->execute || croak 'execute error: ' . $dbh->errstr . "\n";

my %treated = ();
while ( my $res = $sth->fetchrow_hashref ) {

    ( undef, my $dest_dir, undef ) = fileparse( $res->{'filename'} );

    next if $treated{$dest_dir};
    $treated{$dest_dir}++;

    # strip leading file://  -> should do this better
    $dest_dir =~ s/^file:\/\///g;

    my $dest_file = $dest_dir . 'cover.jpg';

    # unless we are given overwrite option, skip dirs that have covers
    if ( !$force_rewrite ) {
        next if ( -f $dest_file );
    }

    #print "CMD: cp $res->{'art_manual'} $dest_file\n";
    copy( $res->{'art_manual'}, $dest_dir )
      || printf( "ERROR: unable to copy %s to %s. error: %s\n",
        $res->{'art_manual'}, $dest_dir, $! );
}
exit;
4

1 に答える 1

7

どうやら$dest_dir、リテラルにする必要がある場所は URL エンコードされています。つまり、プレフィックスをトリミングした後、16 進エスケープを対応するリテラル文字file://にデコードする必要があります。Using Perl, how do I decode or create those %-encodings on the web? を%NN参照してください。基本的に、あなたがしたい

use URI::Escape 'uri_unescape';

その後

$dest_dir = uri_unescape($dest_dir);

さらに、作成していますが$dest_file、それを無視して、$dest_dir代わりにファイルをコピーしています。

追加の文体上の問題として、警告とエラーは stdout ではなく stderr に送られるべきです。

于 2013-08-14T20:28:07.197 に答える