1

私はelispの初心者です。それでは初歩的な質問失礼します。「コマンド」を関数 compile-pkg に渡そうとしていますが、関数 compile-make() の emacs で間違った引数を取得し続けています。

(defun compile-pkg (&optional command startdir)
  "Compile a package, moving up to the parent directory
  containing configure.ac, if it exists. Start in startdir if defined,
  else start in the current directory."
  (interactive)

  (let ((dirname)
    (dir-buffer nil))
    (setq startdir (expand-file-name (if startdir startdir ".")))
    (setq command  (if command command compile-command))

    (setq dirname (upward-find-file "Makefile" startdir))
    (setq dirname (if dirname dirname (expand-file-name ".")))
    ; We've now worked out where to start. Now we need to worry about
    ; calling compile in the right directory
    (save-excursion
      (setq dir-buffer (find-file-noselect dirname))
      (set-buffer dir-buffer)
      (compile command)
      (kill-buffer dir-buffer))))

(defun upward-find-file (filename &optional startdir)
  "Move up directories until we find a certain filename. If we
  manage to find it, return the containing directory. Else if we
  get to the toplevel directory and still can't find it, return
  nil. Start at startdir or . if startdir not given"

  (let ((dirname (expand-file-name
          (if startdir startdir ".")))
    (found nil) ; found is set as a flag to leave loop if we find it
    (top nil))  ; top is set when we get
            ; to / so that we only check it once

    ; While we've neither been at the top last time nor have we found
    ; the file.
    (while (not (or found top))
      ; If we're at / set top flag.
      (if (string= (expand-file-name dirname) "/")
      (setq top t))

      ; Check for the file
      (if (file-exists-p (expand-file-name filename dirname))
      (setq found t)
    ; If not, move up a directory
    (setq dirname (expand-file-name ".." dirname))))
    ; return statement
    (if found (concat dirname "/") nil)))

(defun compile-make ()
  (compile-pkg "make"))

(global-set-key [f1] 'compile-make)

私は何を間違っていますか？

4

1 に答える 1

2

最初に間違っているのはcompile-make、コマンドである必要があることです。これは、単純な変更で実行できます。

(defun compile-make ()
  (interactive)
  (compile-pkg "make"))

なぜ必要なのかを理解するには、Emacs lisp チュートリアル、特に関数をインタラクティブにするセクションを見てください。interactive

注:一般に、表示されていた正確なエラー メッセージをカット アンド ペーストすると役に立ちます。私はそれがあったと思います：

Wrong type argument: commandp, compile-make
于 2013-08-14T23:16:48.680 に答える