0

算術式を表すインターフェースを実装しようとしています。インターフェイスは Java 側で使用されますが、ロジック全体は clojure にあります。

持つ：

(defprotocol ExtendsExpression
  (toTree [this]))

(extend-type String
  ExtendsExpression
  (toTree [this] (symbol this)))

(extend-type Number
  ExtendsExpression
  (toTree [this] this))

(definterface Expression
  (toTree []))

(defrecord Expression1 [^String oper arg]
  Expression
  (toTree [this]
    (list (symbol oper) (toTree arg))))


(defrecord Expression2 [^String oper arg1 arg2]
  Expression
  (toTree [this]
    (list (symbol oper) (toTree arg1) (toTree arg2))))

(defrecord Expression3 [^String oper arg1 arg2 arg3]
  Expression
  (toTree [this]
    (list (symbol oper) (toTree arg1) (toTree arg2) (toTree arg3))))

私はそれを次のように使用しようとします：

(toTree (Expression3. "+" "a" "b" (Expression2. "*" "c" "d")))

しかし、私は得ています:

IllegalArgumentException No implementation of method: :toTree of protocol: #'user/ExtendsExpression found for class: user.Expression3  clojure.core/-cache-protocol-fn (core_deftype.clj:541)

clojure が Expression3 の ExtendsExpression の toTree を呼び出そうとするのはなぜですか? Expression3 では、Expression インターフェイスの toTree メソッドが呼び出されることを期待しています。

4

1 に答える 1

2

はい、わかった ;）

(defprotocol ExtendsExpression
  (to-tree [this]))

(extend-type String
  ExtendsExpression
  (to-tree [this] (symbol this)))

(extend-type Number
  ExtendsExpression
  (to-tree [this] this))

(definterface Expression
  (toTree []))

(defrecord Expression1 [^String oper arg]
  ExtendsExpression
  (to-tree [this]
    (list (symbol oper) (to-tree arg)))
  Expression
  (toTree [this] (to-tree this)))


(defrecord Expression2 [^String oper arg1 arg2]
  ExtendsExpression
  (to-tree [this]
    (list (symbol oper) (to-tree arg1) (to-tree arg2)))
  Expression
  (toTree [this] (to-tree this)))

(defrecord Expression3 [^String oper arg1 arg2 arg3]
  ExtendsExpression
  (to-tree [this]
    (list (symbol oper) (to-tree arg1) (to-tree arg2) (to-tree arg3)))
  Expression
  (toTree [this] (to-tree this)))

(to-tree (Expression3. "+" "a" "b" (Expression2. "*" "c" "d"))) ;=> (+ a b (* c d))

レコードは Expression インターフェイスを実装しているため、Java から簡単に呼び出すことができます。

(.toTree (Expression3. "+" "a" "b" (Expression2. "*" "c" "d"))) ;=> (+ a b (* c d))

Expression3 が実装するインターフェイスを確認するだけです。

 (-> Expression3 clojure.reflect/reflect :bases pprint)
#{clojure.lang.IHashEq java.io.Serializable clojure.lang.IKeywordLookup
  clojure.lang.IPersistentMap clojure.lang.IRecord java.lang.Object
  user.ExtendsExpression clojure.lang.IObj clojure.lang.ILookup
  user.Expression java.util.Map}
于 2013-08-16T09:59:38.077 に答える