excel - Excel チャート/グラフからデータを取得する

Question

男の子の身長 (y 軸) と年齢 (x 軸) を示す MS Excel 2010 チャートがあります。

グラフをデータの形で表現する方法はありますか?

私の質問は、Excel の任意のグラフが与えられ、それが作成/作成されたデータ テーブルがない場合、利用可能なグラフからデータ テーブルを自分で作成できますか?

Answer 1

次の手順に従ってください。

ステップ 1: 次のコードを VBA モジュールにコピーします。

Sub GetChartValues()  
   Dim NumberOfRows As Integer  
   Dim X As Object  
   Dim Counter as Integer  
   Counter = 2  

   ' Calculate the number of rows of data.  
   NumberOfRows = UBound(ActiveChart.SeriesCollection(1).Values)  

   Worksheets("ChartData").Cells(1, 1) = "X Values"  

   ' Write x-axis values to worksheet.  
   With Worksheets("ChartData")  
      .Range(.Cells(2, 1), _  
      .Cells(NumberOfRows + 1, 1)) = _  
      Application.Transpose(ActiveChart.SeriesCollection(1).XValues)  
   End With  

   ' Loop through all series in the chart and write their values to  
   ' the worksheet.  
   For Each X In ActiveChart.SeriesCollection  
      Worksheets("ChartData").Cells(1, Counter) = X.Name  

      With Worksheets("ChartData")  
        .Range(.Cells(2, Counter), _  
         .Cells(NumberOfRows + 1, Counter)) = _  
         Application.Transpose(X.Values)  
      End With  

      Counter = Counter + 1  
   Next  
End Sub

ステップ 2: 新しいワークシートの名前を Chartdata に変更する

ステップ 3: 値を取得するグラフを選択します

ステップ 4: マクロを実行する

ステップ 5: Chartdata シートを参照してください。そこに値があります。

参照: MS Office Web サイト