gnuplot - 軸上の Gnuplot 画像

Question

私は、いくつかの環境を通じて特定の進歩をモデル化しようとしています。x 軸は、環境内の (x 座標に基づく) 位置を表します。

これを明確にするために、プロットの x 軸に環境の画像 (.png に基づく) が必要です (環境はかなり広く、それほど高くないので、見栄えが良いはずです)。 xtics/x 軸ラベル。

これにアプローチする方法について何か提案はありますか?

前もって感謝します！

Answer 1

plotイメージとデータの両方を 1 つのコマンドで、または を使用してプロットできますmultiplot。最初のバリアントは簡単ですが、画像はプロット内にあり、もう 1 つはもう少し複雑ですが、「軸画像」を任意に配置できます。

軸用のダミー画像「gradient.png」は

1 つのプロット コマンド:

set yrange[0:1]
set xrange[0:1]
plot 'gradient.png' binary filetype=png dx=0.0015 dy=0.002 with rgbimage t '',\
     x**2

結果は次のとおりです。

マルチプロットの使用

set yrange[0:1]
set xrange[0:1]

set lmargin at screen 0.1
set rmargin at screen 0.98
set tmargin at screen 0.98
set bmargin at screen 0.2
set xtics offset 0,-1.5
set xlabel 'xlabel' offset 0,-1.5
set ylabel 'ylabel'

set multiplot
plot x**2

set tmargin at screen 0.2
set bmargin at screen 0.15
unset border
unset tics
unset xlabel
unset ylabel
unset key
set autoscale xy
plot 'gradient.png' binary filetype=png with rgbimage 
unset multiplot

ご覧のとおり、これにはもう少し努力が必要です。詳細を説明するには：

• 軸イメージがメイン プロットの真下に配置されるように、明示的なマージンを設定する必要があります。

• 軸イメージをプロットする前に、 を削除ticsし、labels範囲をリセットautoscaleする必要があります (したがって、固定lmarginおよびも設定する必要がありますrmargin)。

• イメージ自体をプロットするには、プロット スタイル を使用しますwith rgbimage。

• xticsマリングだけでなく、xlabelオフセットも微調整する必要があります。

結果の画像は次のとおりです。