linux - gnuplot は x2 に y2 の値を表示します

Question

次のグラフがあります。

• 最初のデータ セット表示検索。
• 2 番目のデータ セット表示のクリック。

y1検索の規模をy2示し、クリックの規模を示します。にx1時間値が表示されます。

x2（上軸）にクリック数（時間ごと）を表示したい。コマンドを追加するset x2ticsと、希望どおりのクリックではなく、検索データが表示されます。

クリック単位を表示するように変更するにはどうすればよいですか?

gnuplot スクリプト:

set xlabel "Time"
set ylabel "Times"
set y2range [0:55000]
set y2tics 0, 1000
set ytics nomirror
set datafile separator "|"
set title "History of searches"
set xdata time          # The x axis data is time
set timefmt "%Y-%m-%d %H:%M"        # The dates in the file look like 10-Jun-04
set format x "%d/%m\n%H:%M"
set grid
set terminal png size 1024,768        # gnuplot recommends setting terminal before output
set output "outputFILE.png"  # The output filename; to be set after setting
                     # terminal
load "labelsFILE"

plot 'goodFILE' using 1:3 lt 2 with lines t 'Success'  , 'clicksFILE' using 1:2 lt 5 with lines t 'Clicks right Y' axis x1y2


replot

グラフ：

グラフ http://img42.imageshack.us/img42/1269/wu0b.png

Answer 1

わかりましたので、開始するには、次のようにクリック数でラベルを設定する方法を次に示します (データ ファイル名を使用)。

plot 'goodFILE' using 1:3 lt 2 with lines t 'Success',\
     'clicksFILE' using 1:2 lt 5 with lines t 'Clicks right Y' axis x1y2,\
     '' using 1:2:(sprintf("%dk", int($2/1000.0))) with labels axis x1y2 offset 0,1 t ''

これをプロット コマンドとして追加するだけで、問題なく動作するはずです。

ラベルがどのように見えるかを説明するために、いくつかのダミー データを使用した例を次に示します。

set terminal pngcairo
set output 'blubb.png'

set xlabel "Time"
set ylabel "Times"
set y2label "Clicks per hour"
set y2range [0:10000]
set yrange [0:1]
set ytics nomirror
set y2tics
set key left

set samples 11
set xrange[0:10000]
plot '+' using 1:1:(sprintf("%dk", int($1/1000.0))) every ::1::9 with labels axis x1y2 offset 0,1 t '',\
     '' using 1:1 with linespoints axis x1y2 pt 7 t 'Clicks per hour'

これにより、次のことが得られます。