5

私は内部目的で単純な文字列操作DSLに取り組んでいますが、Rubyで使用されている文字列補間をサポートする言語が必要です。

例えば：

name = "Bob"
msg = "Hello ${name}!"
print(msg)   # prints "Hello Bob!"

パーサーをANTLRv3に実装しようとしていますが、ANTLRの使用にかなり慣れていないため、この機能を実装する方法がわかりません。これまで、レクサーで文字列リテラルを指定しましたが、この場合、明らかにパーサーで補間コンテンツを処理する必要があります。

私の現在の文字列リテラルの文法は次のようになります。

STRINGLITERAL : '"' ( StringEscapeSeq | ~( '\\' | '"' | '\r' | '\n' ) )* '"' ;
fragment StringEscapeSeq : '\\' ( 't' | 'n' | 'r' | '"' | '\\' | '$' | ('0'..'9')) ;

文字列リテラルの処理をパーサーに移動すると、他のすべてが正常に機能しなくなるようです。大まかなWeb検索では情報が得られませんでした。これを始める方法について何か提案はありますか？

4

1 に答える 1

12

私はANTLRの専門家ではありませんが、可能な文法は次のとおりです。

grammar Str;

parse
    :    ((Space)* statement (Space)* ';')+ (Space)* EOF
    ;

statement
    :    print | assignment
    ;

print
    :    'print' '(' (Identifier | stringLiteral) ')' 
    ;

assignment
    :    Identifier (Space)* '=' (Space)* stringLiteral
    ;

stringLiteral
    :    '"' (Identifier | EscapeSequence | NormalChar | Space | Interpolation)* '"'
    ;

Interpolation
    :    '${' Identifier '}'
    ;

Identifier
    :    ('a'..'z' | 'A'..'Z' | '_') ('a'..'z' | 'A'..'Z' | '_' | '0'..'9')*
    ;

EscapeSequence
    :    '\\' SpecialChar
    ;

SpecialChar
    :     '"' | '\\' | '$'
    ;

Space
    :    (' ' | '\t' | '\r' | '\n')
    ;

NormalChar
    :    ~SpecialChar
    ;

お気づきのように、文法例の中にいくつかの(Space)*-es があります。これは、がlexer- ruleではなくparser-rulestringLiteralであるためです。そのため、ソース ファイルをトークン化するとき、レクサーは空白が文字列リテラルの一部なのか、それともソース ファイル内の無視できる単なるスペースなのかを判断できません。

この例を小さな Java クラスでテストしたところ、すべて期待どおりに機能しました。

/* the same grammar, but now with a bit of Java code in it */
grammar Str;

@parser::header {
    package antlrdemo;
    import java.util.HashMap;
}

@lexer::header {
    package antlrdemo;
}

@parser::members {
    HashMap<String, String> vars = new HashMap<String, String>();
}

parse
    :    ((Space)* statement (Space)* ';')+ (Space)* EOF
    ;

statement
    :    print | assignment
    ;

print
    :    'print' '(' 
         (    id=Identifier    {System.out.println("> "+vars.get($id.text));} 
         |    st=stringLiteral {System.out.println("> "+$st.value);}
         ) 
         ')' 
    ;

assignment
    :    id=Identifier (Space)* '=' (Space)* st=stringLiteral {vars.put($id.text, $st.value);}
    ;

stringLiteral returns [String value]
    :    '"'
        {StringBuilder b = new StringBuilder();} 
        (    id=Identifier           {b.append($id.text);}
        |    es=EscapeSequence       {b.append($es.text);}
        |    ch=(NormalChar | Space) {b.append($ch.text);}
        |    in=Interpolation        {b.append(vars.get($in.text.substring(2, $in.text.length()-1)));}
        )* 
        '"'
        {$value = b.toString();}
    ;

Interpolation
    :    '${' i=Identifier '}'
    ;

Identifier
    :    ('a'..'z' | 'A'..'Z' | '_') ('a'..'z' | 'A'..'Z' | '_' | '0'..'9')*
    ;

EscapeSequence
    :    '\\' SpecialChar
    ;

SpecialChar
    :     '"' | '\\' | '$'
    ;

Space
    :    (' ' | '\t' | '\r' | '\n')
    ;

NormalChar
    :    ~SpecialChar
    ;

そして、すべてをテストするための main メソッドを持つクラス:

package antlrdemo;

import org.antlr.runtime.*;

public class ANTLRDemo {
    public static void main(String[] args) throws RecognitionException {
        String source = "name = \"Bob\";        \n"+
                "msg = \"Hello ${name}\";       \n"+
                "print(msg);                    \n"+
                "print(\"Bye \\${for} now!\");    ";
        ANTLRStringStream in = new ANTLRStringStream(source);
        StrLexer lexer = new StrLexer(in);
        CommonTokenStream tokens = new CommonTokenStream(lexer);
        StrParser parser = new StrParser(tokens);
        parser.parse();
    }
}

次の出力が生成されます。

> Hello Bob
> Bye \${for} now!

繰り返しますが、私は専門家ではありませんが、これで (少なくとも)問題を解決できます。

HTH。

于 2009-12-08T17:00:56.710 に答える