0

xml エントリを属性別にグループ化してリストを作成したいと考えています。ここに私のxmlがあります:

<Content>
    <contenItem ProductType="Breakfast" name="Eggs" />
    <contenItem ProductType="Breakfast" name="Bacon" />
    <contenItem ProductType="Lunch" name="Fish" />
    <contenItem ProductType="Dinner" name="Steak" />
</Content>

この結果を取得しようとしていますが、方法がわかりませんでした

   <ul>
     <li>Breakfast
        <ul>
           <li>Eggs</li>
           <li>Bacon</li>
        </ul>
      </li>
       <li>Lunch
        <ul>
           <li>Fish</li>
        </ul>
      </li>
      <li>Dinner
        <ul>
           <li>Steak</li>
        </ul>
      </li>
    </ul>
4

1 に答える 1

0 
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="html" doctype-system="about:legacy-compat" encoding="UTF-8" indent="yes" />
<xsl:strip-space elements="*" />

<xsl:key name="kProductType" match="contenItem" use="@ProductType" />  

<xsl:template match="@*|node()">
 <xsl:copy>
   <xsl:apply-templates select="@*|node()"/>
 </xsl:copy>
</xsl:template>

<xsl:template match="/*">
 <ul>
   <xsl:apply-templates select="contenItem[
   generate-id() = generate-id(key('kProductType',@ProductType)[1])]" />
 </ul>
</xsl:template>

<xsl:template match="contenItem">
 <li>
   <xsl:value-of select="@ProductType" />
   <ul>
     <xsl:apply-templates select="key('kProductType',@ProductType)" mode="sublist"/>
   </ul>  
 </li>
</xsl:template>

<xsl:template match="contenItem" mode="sublist">
 <li>
   <xsl:value-of select="@name" />
 </li>
</xsl:template>


</xsl:stylesheet>
于 2013-08-30T05:35:41.620 に答える