10

私は Perl を初めて使用し、新しい Perl 6 文法機能を使用して優先順位を持つ演算子を使用してドメイン固有言語を作成したいと考えています。たとえば、「1 + 2 * 6」を正しい方法で解析します。

私が今まで見つけたドキュメント (例: this ) には、優先順位宣言を持つ演算子の文法規則の例がありません。

私はこの非常に単純な例を持っています

use v6;

#use Grammar::Tracer;

grammar TestGrammar {

    token TOP {
        <digit> <infix> <digit>
    }

    token infix:sym<times> is equiv(&infix:<*>) { <sym> }

}

sub MAIN() {
    my $text = "1 times 2" ;
    say $text ;

    my $match = TestGrammar.parse($text);
    say $match;
}

これは私に与えます

No such method 'infix' for invocant of type 'TestGrammar'

抽象構文木を構築したいだけです。

4

1 に答える 1

7

私の知る限り、中置演算子を設定したり、文法で優先順位などを定義したりすることはできません。これらは現在、Perl 6 の拡張にのみ適用されます。

ここで可能なアプローチ。足し算の前に乗法項を解析し、単語や記号 ( や など) も許可しtimesます*。

use v6;

grammar TestGrammar {

    rule TOP      { <expr=.add> }

    rule add      { <expr=.multiply> +% [ <add-op> ] }
    rule multiply { <digit> +%  [ <mult-op> ] }

    proto token mult-op {*}
    token mult-op:sym<times>   { <sym>|'*' }
    token mult-op:sym<divided> { <sym>|'/' }

    proto token add-op {*}
    token add-op:sym<plus>     { <sym>|'+' }
    token add-op:sym<minus>    { <sym>|'-' }

}

sub MAIN() {
    for ("2+2", "2 + 2", "1 * 2", "1 + 2 * 6", "4 times 7 minus 3") {
        say $_;
        my $match = TestGrammar.parse($_);
        say $match;
    }
}

%は区切り演算子であることに注意してください。乗法演算子 ( 、、または) で<digit> +% [ <mult-op> ]区切られた数字のリストを意味します。times*divided/

代替ソリューション 2014 年 9 月:

S05では、ルールとトークンは特別なメソッドですが、どちらもマルチとして宣言でき、通常のメソッドと同じように引数を取ることができると述べています。

このアプローチでは、再帰とマルチディスパッチの両方を利用して、演算子の優先レベルを実装します。

use v6;

grammar TestGrammar {

    rule TOP                { <expr(3)> }

    # operator multi-dispatch, loosest to tightest
    multi token op(3) {'+'|'-'|add|minus}
    multi token op(2) {'*'|'/'|times|divided}
    multi token op(1) {'**'}

    # expression multi-dispatch (recursive)
    multi rule expr(0)      { <digit> | '(' ~ ')' <expr(3)> }
    multi rule expr($pred)  { <expr($pred-1)> +% [ <op($pred)> ] }

}

sub MAIN() {
    for ("2+2", "2 + 2", "1 * 2", "1 + 2**3 * 6", "4 times (7 minus 3) * 3") {
        say $_;
        my $match = TestGrammar.parse($_);
        say $match;
    }
}
于 2013-09-02T07:33:42.923 に答える