2

コマンド ライン アプリケーションを自動化する必要があります。ユーザーにパスワードの入力を求めます。STDIN経由でパスワードを送信する私のアプローチはすべて失敗しました。現在、.NET を使用してラッパー プログラムでこれを実行しようとしています。

新しいプロセスを作成するアプリケーションを開始し、プロパティを設定してStartInfoからプロセスを開始します。

Dim app_path As String
Dim app_args As String
Dim myProcess As Process = New Process()
myProcess.StartInfo.FileName = app_path
myProcess.StartInfo.Arguments = app_args
myProcess.StartInfo.UseShellExecute = False
myProcess.Start()

プロパティを使用しようとしましStartInfo.RedirectStandardInputたが、成功しませんでした。

WriteConsoleInput今、私は次のように含めた関数に出くわしましたkernel32.dll:

Declare Function WriteConsoleInput Lib "kernel32.dll" Alias "WriteConsoleInputA" (ByVal hConsoleInput As Integer, ByVal lpBuffer As String, ByVal nNumberOfCharsToWrite As Integer, ByRef lpNumberOfCharsWritten As Integer) As Boolean

プロパティを介してプロセスのハンドルを取得できmyProcess.Handleます。しかし、この方法を使用して入力バッファーに入力を送信することもできませんでした。

私はそれらの質問を見つけましたが、役に立ちませんでした:

  • 'PAGE DOWN' をコンソールの入力バッファに書き込むにはどうすればよいですか? (1475353)

  • Java - 入力を外部 C/C++ アプリケーションに渡す (1421273)

  • stdin パイプを使用した Windows コンソール アプリの制御 (723424)

StraceNtX.exe を使用すると、アプリが入力を待っている瞬間に次の出力が得られます。

[T4024] GetConsoleMode(f, 12d35c, 12d3af, 77bff894, ...) = 1
[T4024] SetConsoleMode(f, 0, 12d3af, 77bff894, ...) = 1
[T4024] ReadConsoleInputA(f, 12d348, 1, 12d360, ...) = 1

他に何を試すべきか、または上記を正しい方法で行う方法を誰か教えてもらえますか? ありがとう！

Tim Robinsons answere に基づいて、このコードを取得しましたが、機能しません:

myProcess = New Process()
myProcess.StartInfo.FileName = app_path
myProcess.StartInfo.Arguments = app_args
myProcess.StartInfo.WindowStyle = ProcessWindowStyle.Normal
myProcess.StartInfo.UseShellExecute = False
myProcess.Start()
' Wait for process requesting passwort input
System.Threading.Thread.Sleep(3000)
Dim len As Integer
len = 0
Dim handle As Integer
handle = GetStdHandle(STD_INPUT_HANDLE)
WriteConsoleInput(handle, "Test", 4, len)

私のプログラムは、ラッパーとして機能するコマンドライン アプリケーションです。

入力は送信されますが、パスワード フィールドに入力されるのではなく、パスワード フィールドの下に新しいプロンプトが表示されます (入力を表示することさえありません)。

ティム、例を挙げてくれる？

4

2 に答える 2

2

お忙しいところ、お返事が遅くなり申し訳ありません。

これは、私のコードから取り除かれた完全なコード例です。重要なものを削除していないことを願っています。

Private Sub runWaitInput(ByVal exe As String, ByVal parameter As String, ByVal trigger As String, ByVal input As String)
    ' runs an process, waits for a certain string in stdout and then enters text '
    Dim proc As Process
    Dim stdOut As StreamReader
    Dim ch As Int32
    Dim buffer As String = ""
    Dim InputRecords(0) As KeyEventStruct

    ' create process '
    proc = New Process()
    proc.StartInfo.FileName = exe
    proc.StartInfo.Arguments = parameter
    proc.StartInfo.UseShellExecute = False
    proc.StartInfo.RedirectStandardOutput = True
    proc.Start()

    ' redirect stdOut '
    stdOut = proc.StandardOutput
    While Not proc.HasExited
        ' read character '
        ch = stdOut.Read()
        Console.Write(Convert.ToChar(ch))
        buffer = buffer & Convert.ToChar(ch)
        ' read output and check for trigger-text '
        If buffer.LastIndexOf(trigger) <> -1 Then
            buffer = ""
            InputRecords(0) = New KeyEventStruct
            InputRecords = generateInputRecord(input & Convert.ToChar(13))
            WriteConsoleInput(STD_INPUT_HANDLE, InputRecords, InputRecords.Count(), New Integer)
        End If
    End While
    Console.Write(stdOut.ReadToEnd())
End Sub

Function generateInputRecord(ByVal str As String) As KeyEventStruct()
    Dim ret(str.Count() - 1) As KeyEventStruct
    For i = 0 To str.Count - 1 Step 1
        With ret(i)
            .EventType = 1
            .bKeyDown = True
            .uChar.AsciiChar = Convert.ToInt32(str(i))
            .dwControlKeyState = 0
            .wRepeatCount = 1
            .wVirtualKeyCode = 0
            .wVirtualScanCode = 0
        End With
    Next
    Return ret
End Function

次のモジュールを使用します。

Imports System.Runtime.InteropServices

Module ConsoleUtils

    <Flags()> Public Enum ControlKeyState As Integer
        RightAltPressed = &H1
        LeftAltPressed = &H2
        RightCtrlPressed = &H4
        LeftCtrlPressed = &H8
        ShiftPressed = &H10
        NumLockOn = &H20
        ScrollLockOn = &H40
        CapsLockOn = &H80
        EnhancedKey = &H100
    End Enum

    <StructLayout(LayoutKind.Explicit)> Public Structure CHAR_UNION
        <FieldOffset(0)> Public UnicodeChar As Short
        <FieldOffset(0)> Public AsciiChar As Byte
    End Structure

    <DllImport("kernel32", EntryPoint:="WriteConsoleInputA", CharSet:=CharSet.Auto, SetLastError:=True, ThrowOnUnmappablechar:=True)> _
        Public Function WriteConsoleInput( _
            ByVal hConsoleInput As IntPtr, _
            ByVal lpBuffer() As KeyEventStruct, _
            ByVal nLength As Integer, _
            ByRef lpNumberOfEventsWritten As Integer _
        ) As Boolean
    End Function

    <DllImport("KERNEL32.DLL", EntryPoint:="GetStdHandle", SetLastError:=False, ExactSpelling:=True, CallingConvention:=CallingConvention.StdCall)> _
        Public Function GetStdHandle( _
            ByVal nStdHandle As Integer _
        ) As Integer
    End Function

    <StructLayout(LayoutKind.Sequential)> Public Structure KeyEventStruct
        Public EventType As Short
        <MarshalAs(UnmanagedType.Bool)> Public bKeyDown As Boolean
        Public wRepeatCount As Short
        Public wVirtualKeyCode As Short
        Public wVirtualScanCode As Short
        Public uChar As CHAR_UNION
        Public dwControlKeyState As ControlKeyState
    End Structure

    Public ReadOnly STD_OUTPUT_HANDLE As IntPtr = New IntPtr(GetStdHandle(-11))
    Public ReadOnly STD_INPUT_HANDLE As IntPtr = New IntPtr(GetStdHandle(-10))
    Public ReadOnly STD_ERROR_HANDLE As IntPtr = New IntPtr(GetStdHandle(-12))

End Module

この関数を使用すると、プロセスを開始し、出力行 (つまり、"password:") を待つことができます。次に、関数は提供されたテキストを入力し、その後に return を入力します。

これが役立つことを願っています！

よろしく sc911

于 2010-02-09T08:31:25.857 に答える
0

WriteConsoleInputプロセス ハンドルではなく、コンソール ハンドルが必要です。問題は、このコンソール ハンドルを取得する方法です。

プロセスがコンソール アプリで、子プロセスの開始時に何もリダイレクトしない場合、子プロセスは自分のプロセスのコンソールにアタッチされます。その場合、次のことができる場合があります。

  1. リダイレクトをオフにして子プロセスを開始する
  2. GetStdHandle(STD_INPUT_HANDLE)自分のコンソール ハンドルを取得するために呼び出す
  3. そのコンソールハンドルをに渡しますWriteConsoleInput

GUI アプリがある場合は、 を使用して自分自身にコンソールを割り当てることができますAllocConsole。

編集:最初は気づきませんでしたが、それは の正しい定義ではありませんWriteConsoleInput。文字列ではなく、の配列を取りINPUT_RECORDます。関数プロトタイプを pinvoke.net からコピーすると、 runas.exe を使用した私自身の実験は問題なく動作します。

于 2009-12-07T11:23:01.650 に答える