8

表を含む MS Word 文書があります。次のコードを使用して、VBA 経由でテキストを検索して置換しようとしています。

If TextBox1.Text <> "" Then
    Options.DefaultHighlightColorIndex = wdNoHighlight
    Selection.Find.ClearFormatting
    Selection.Find.Replacement.ClearFormatting
    Selection.Find.Replacement.Highlight = True
    With Selection.Find
        .Text = "<Customer_Name>"
        .Replacement.Text = TextBox1.Text
        .Forward = True
        .Wrap = wdFindContinue
        .Format = False
        .MatchCase = False
        .MatchWholeWord = False
        .MatchWildcards = False
        .MatchSoundsLike = False
        .MatchAllWordForms = False
    End With

Selection.Find.ClearFormatting
    With Selection.Find.Font
    .Italic = True
    End With
    Selection.Find.Replacement.ClearFormatting
    With Selection.Find.Replacement.Font
    .Italic = False
    End With
    Selection.Find.Execute Replace:=wdReplaceAll
    End If

これは、テーブルの外側にあるすべてのコンテンツを置き換えるのにうまく機能します。ただし、テーブル内のコンテンツは置き換えられません。

4

2 に答える 2

18

ドキュメント全体で置換を実行することが目標の場合 (コードからはそう見えますが、明示的ではありません)、オブジェクトDocument.Rangeの代わりに使用することをお勧めしSelectionます。を使用Document.Rangeすると、テーブル内であっても、すべてが確実に置き換えられます。

また、カーソル (または選択範囲) がマクロによって移動されないため、ユーザーにとって透過的です。

Sub Test()
  If TextBox1.Text <> "" Then
    Options.DefaultHighlightColorIndex = wdNoHighlight
    With ActiveDocument.Range.Find
      .Text = "<Customer_Name>"
      .Replacement.Text = TextBox1.Text
      .Replacement.ClearFormatting
      .Replacement.Font.Italic = False
      .Forward = True
      .Wrap = wdFindContinue
      .Format = False
      .MatchCase = False
      .MatchWholeWord = False
      .MatchWildcards = False
      .MatchSoundsLike = False
      .MatchAllWordForms = False
      .Execute Replace:=wdReplaceAll
    End With
  End If
End Sub
于 2013-09-04T10:47:45.417 に答える
8

私は次のコードを使用しましたが、ドキュメント内で見つかったすべてのオカレンスに対して魅力的に動作します.....。

  stringReplaced = stringReplaced + "string to be searched"
For Each myStoryRange In ActiveDocument.StoryRanges
    With myStoryRange.Find
        .Text = "string to be searched"
        .Replacement.Text = "string to be replaced"
        .Wrap = wdFindContinue
        .ClearFormatting
        .Replacement.ClearFormatting
        .Replacement.Highlight = False
        .Execute Replace:=wdReplaceAll
    End With
Next myStoryRange
于 2014-01-30T06:59:36.980 に答える