3

私は XSLT に慣れようとしています。名前空間の理由は理解していますが、単にローカル XML ファイルをローカル アプリケーションで使用できるように変換しようとしているだけです。

ここにあるファイルを変換しようとしています: http://uscodebeta.house.gov/download/releasepoints/us/pl/113/31/xml_usc01@113-31.zip

このコードを使用して：

<?xml version="1.0" encoding="UTF-8"?>
    <xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" indent="yes" name="xml"/>
    <xsl:template match="//title">
        <xsl:for-each select="section">
            <xsl:variable name="href"><xsl:value-of select="ancestor::title/num/@value" />-<xsl:value-of select="ancestor::chapter/num/@value" />-<xsl:value-of select="num/@value" />.xml</xsl:variable>
            <xsl:result-document href="$href">
                <xsl:element name="structure">
                    <xsl:element name="unit">
                        <xsl:attribute name="label">title</xsl:attribute>
                        <xsl:attribute name="identifier">
                            <xsl:value-of select="ancestor::title/num/@value" />
                        </xsl:attribute>
                        <xsl:attribute name="order_by">
                            <xsl:value-of select="ancestor::title/num/@value" />
                        </xsl:attribute>
                        <xsl:attribute name="level">1</xsl:attribute>
                        <xsl:value-of select="ancestor::title/num" /> <xsl:value-of select="ancestor::title/heading"/>
                    </xsl:element>
                </xsl:element>
            </xsl:result-document>
        </xsl:for-each>
    </xsl:template>
</xsl:stylesheet>

ここにある XML の例: https://github.com/statedecoded/statedecoded/wiki/XML-Format-for-Parser

これは最初の要素だけの変換ですが、コマンド ラインで Saxon を使用して実行すると、次の警告が表示されます。

Warning: SXXP0005: The source document is in namespace http://xml.house.gov/schemas/uslm/1.0, but all the template rules match elements in no namespace

出力は XML タグではなくプレーン テキストです。

どんな助けでも大歓迎です。

ありがとう

4

1 に答える 1

6

xpath-default-namespaceXSLT 2.0 を使用しているため、属性を on に追加できますxsl:stylesheet。詳細については、 http://www.w3.org/TR/xslt20/#standard-attributesを参照してください。

例えば：

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
xpath-default-namespace="http://xml.house.gov/schemas/uslm/1.0">

*パス内の各要素のプレフィックスとして使用するオプションもあります。ただし、スタイルシートが大きくなると、それは大変な作業になる可能性があります。

例：

ancestor::*:title/*:num

完全な例:

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xpath-default-namespace="http://xml.house.gov/schemas/uslm/1.0">
    <xsl:output indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:template match="@*|node()">
        <xsl:apply-templates select="@*|node()"/>
    </xsl:template>

    <xsl:template match="section">
        <xsl:result-document href="{ancestor::title/num/@value}-{ancestor::chapter/num/@value}-{num/@value}.xml">
            <structure>
                <unit label="title" identifier="{ancestor::title/num/@value}" 
                    order_by="{ancestor::title/num/@value}" level="1">
                    <xsl:value-of select="concat(ancestor::title/num,' ',ancestor::title/heading)"/>
                </unit>
            </structure>
        </xsl:result-document>
    </xsl:template>

</xsl:stylesheet>
于 2013-09-11T02:56:52.077 に答える