1

次のコードで eval を避けるべきですか? もしそうなら、どのように？それとも、これは eval を使用する方が優れている例外的なケースの 1 つですか?

(dolist (command '(....))
  (eval
   `(defadvice ,command (around blah activate)
      ...)))

上記のイディオムの実際の例:

(dolist (command '(paredit-comment-dwim comment-dwim))
  (eval
   `(defadvice ,command (around my-check-parens-and-warn-for-comment activate)
      (if (and (called-interactively-p 'any)
               (use-region-p))
          (progn
            (my-check-parens-and-warn-if-mismatch "You commented out a region and introduced a mismatched paren")
            ad-do-it
            (my-check-parens-and-warn-if-mismatch "You uncommented out a region and introduced a mismatched paren"))
        ad-do-it))))
4

1 に答える 1

3

2 つのソリューション:

  • ad-add-adviceの代わりに使用しdefadviceます。
  • Emacs トランクを使用している場合は、新しいadvice-add.

使用advice-addすると、次のコードのようになります。

(defun my-check-commented-parens (orig-fun &rest args)
  (if (not (and (called-interactively-p 'any)
                (use-region-p)))
      (apply orig-fun args)
    (my-check-parens-and-warn-if-mismatch "You commented out a region and introduced a mismatched paren")
    (apply orig-fun args)
    (my-check-parens-and-warn-if-mismatch "You uncommented out a region and introduced a mismatched paren")))

(dolist (command '(paredit-comment-dwim comment-dwim))
  (advice-add command :around #'my-check-commented-parens))
于 2013-09-21T16:17:44.367 に答える