1

私は次のすべての結果に対して合計演算を実行しようとしています：

combination(0,_,[]).
combination(K,L,[X|Xs]) :-
   K > 0,
   el(X,L,R),
   K1 is K-1,
   combination(K1,R,Xs).

el(X,[X|L],L).
el(X,[_|L],R) :- el(X,L,R).

たとえば、ユーザーはis_sum_equal_10（[1,2,3,4,5,6,7]）と入力し、いずれかの順列の合計が10に等しい場合、結果はtrueになります。

私はそれをすべてまとめるのに苦労しています、誰かが私が各順列の組み合わせルールを使用するis_sum_equal_10ルールを定義するのを手伝ってくれますか？

4

1 に答える 1

2

OK、まあ、本当に書くのはとても簡単です。特定の組み合わせの合計が10になるかどうかを言うルールが必要です。次に、さまざまなサイズの組み合わせリストをカウントアップするためのルールが必要です（これは、書き方によって必要になります）。ルールを確認するときに減らす必要があるKとの組み合わせ）。

1 ?- [user].
|: combination(0,_,[]).
|: combination(K,L,[X|Xs]) :- K > 0,
|:    el(X,L,R), K1 is K-1, combination(K1,R,Xs).
|: el(X,[X|L],L).
|: el(X,[_|L],R) :- el(X,L,R).
|: 
|: totals_10([],10).
|: totals_10([X|Xs],T) :- N is T+X, totals_10(Xs,N).
|: 
|: is_comb_sum_equal_10(Numbers,_,R) :- combination(R,Numbers,C), totals_10(C,0).
|: is_comb_sum_equal_10(Numbers,N,R) :- Rnext is R+1, Rnext =< N,
|:    is_comb_sum_equal_10(Numbers,N,Rnext).
|: 
|: is_sum_equal_10(Numbers) :- length(Numbers,N), is_comb_sum_equal_10(Numbers,N,0).
|: 
% user://1 compiled 0.13 sec, 1,824 bytes
true.

2 ?- is_sum_equal_10([2,3,5]).
true .

3 ?- is_sum_equal_10([2,235,124,3,3347,5,2373]).
true .

4 ?- is_sum_equal_10([2,235,124,3,3347,6,2373]).
false.

5 ?- is_sum_equal_10([1,1,1,1,1,-1,1,1,1,1,12]).
false.

6 ?- is_sum_equal_10([1,1,1,1,1,-1,1,1,1,1,11]).
true ;
false.

実際のリストやis_sum_equal_10のリストの大きさは気にしないので、組み合わせを合計するだけで済みます。さらに良いことに、基本ケースの原則として合計が正しいことを確認してください。最後に合計して必要な値と照合するのではなく、目的の合計から減算してベースで0にする方が、少しすっきりしていると思います。これにより、特定の合計を探すための非常に単純な単一のルールセットが得られます。

7 ?- [user].
|: is_subset_sum(0,[]).
|: is_subset_sum(N,[_|Xs]) :- is_subset_sum(N,Xs).
|: is_subset_sum(N,[X|Xs]) :- R is N-X, is_subset_sum(R,Xs).
|: 
% user://2 compiled 0.03 sec, 540 bytes
true.

8 ?- is_subset_sum(10,[3,5,6]).
false.

9 ?- is_subset_sum(10,[123,4,1,77,3,2,34]).
true .

10 ?- is_subset_sum(11,[0,2,4,6,8,10,12,14,16,18,20,22]).
false.

もちろん、このアプローチははるかに理解しやすく、はるかに効率的です。

于 2009-12-13T06:31:02.990 に答える