3

その中で別のプロシージャを呼び出す Oracle プロシージャに取り組んでいます。パラメータの(parm1)1 つに、カンマ区切りのリストに 1 つ以上の値を含めることができます。これらの値をループして、一度に 1 つずつ別のプロシージャに渡すにはどうすればよいですか?

これが私がやりたいことの例です：

When Parm1 = 123,312

callProcedure2(123)
callProcedure2(321)

-また-

When Parm1 123

callProcedure2(123)

これはループを使用して実現できると思いますが、ループ内で各値を個別の呼び出しとして使用する方法がわかりません。

どんな助けでも大歓迎です！

ありがとう！

4

4 に答える 4

16 
CURSOR V_CUR IS
select regexp_substr(Parm1 ,'[^,]+', 1, level) As str from dual
connect by regexp_substr(Parm1, '[^,]+', 1, level) is not null;

このcurorは次のような結果をもたらします

123
321

カーソルを反復処理し、ループ内でプロシージャを呼び出します。

For i IN V_CUR
LOOP
    callProdcedure2(i.str);
END LOOP;
于 2013-10-03T20:52:25.213 に答える
8

部分文字列をループするだけです：

declare 
  parm1 varchar2(1000) := '123,234,345,456,567,789,890';

  vStartIdx binary_integer;
  vEndIdx   binary_integer;
  vCurValue varchar2(1000);
begin

  vStartIdx := 0;
  vEndIdx   := instr(parm1, ','); 

  while(vEndIdx > 0) loop
    vCurValue := substr(parm1, vStartIdx+1, vEndIdx - vStartIdx - 1);

    -- call proc here
    dbms_output.put_line('->'||vCurValue||'<-');

    vStartIdx := vEndIdx;
    vEndIdx := instr(parm1, ',', vStartIdx + 1);  
  end loop;

  -- Call proc here for last part (or in case of single element)
  vCurValue := substr(parm1, vStartIdx+1);
  dbms_output.put_line('->'||vCurValue||'<-');

end;
于 2013-10-04T14:46:45.590 に答える
0

forループで使用できる関数を使用することができます ( regexpThinkJet なし):

型と関数を作成する

CREATE OR REPLACE TYPE t_my_list AS TABLE OF VARCHAR2(100);
CREATE OR REPLACE
       FUNCTION cto_table(p_sep in Varchar2, p_list IN VARCHAR2)
         RETURN t_my_list
       AS
         l_string VARCHAR2(32767) := p_list || p_sep;
         l_sep_index PLS_INTEGER;
         l_index PLS_INTEGER := 1;
         l_tab t_my_list     := t_my_list();
       BEGIN
         LOOP
           l_sep_index := INSTR(l_string, p_sep, l_index);
           EXIT
         WHEN l_sep_index = 0;
           l_tab.EXTEND;
           l_tab(l_tab.COUNT) := TRIM(SUBSTR(l_string,l_index,l_sep_index - l_index));
           l_index            := l_sep_index + 1;
         END LOOP;
         RETURN l_tab;
       END cto_table;
/

次に、forループで呼び出す方法:

DECLARE
  parm1 varchar2(4000) := '123,234,345,456,567,789,890';
BEGIN
    FOR x IN (select * from (table(cto_table(',', parm1)) ) )
    LOOP
        dbms_output.put_line('callProdcedure2 called with ' || x.COLUMN_VALUE);
        callProdcedure2(x.COLUMN_VALUE);
    END LOOP;
END;
/

オラクルによって与えられたデフォルト名に注意してくださいCOLUMN_VALUE。これは、結果を使用するために必要です。

期待どおりの結果:

callProdcedure2 called with 123
callProdcedure2 called with 234
...
于 2016-03-31T08:27:30.927 に答える