4

vb.net アプリケーション用に Inno Setup を使用してインストーラーを作成しようとしています。

このアプリケーションには、MySQL ODBC に対する前提条件の依存関係があります。そのため、システムに MySQL ODBC が存在するかどうかを確認し、存在しない場合はインストールできるかどうかを考えていました。率直に言って、私は初心者のプログラマーであり、InnoSetup のスクリプト言語である debian についてまったく知りません。

しばらくの間、グーグルなどで助けを探していましたが、いくつかの例以外は何も見つからず、スクリプトを自分でコーディングしようとしました。

スクリプトは次のとおりです。

; Script generated by the Inno Setup Script Wizard.
; SEE THE DOCUMENTATION FOR DETAILS ON CREATING INNO SETUP SCRIPT FILES!

[Setup]
; NOTE: The value of AppId uniquely identifies this application.
; Do not use the same AppId value in installers for other applications.
; (To generate a new GUID, click Tools | Generate GUID inside the IDE.)
AppId={{ID goes here}
AppName=DCS
AppVersion=1.0
;AppVerName=DCS 1.0
AppPublisher=Syed
DefaultDirName={pf}\DCS
DisableDirPage=yes
DefaultGroupName=DCS
DisableProgramGroupPage=yes
OutputBaseFilename=setup
SetupIconFile=C:\logo.ico
Compression=lzma
SolidCompression=yes

[Languages]
Name: "english"; MessagesFile: "compiler:Default.isl"

[Tasks]
Name: "desktopicon"; Description: "{cm:CreateDesktopIcon}"; GroupDescription: "{cm:AdditionalIcons}"; Flags: unchecked

[Files]
Source: "C:\VS12\Projects\DCS\bin\Debug\DCS.exe"; DestDir: "{app}"; Flags: ignoreversion
Source: "C:\VS12\Projects\DCS\bin\Debug\DCS.vshost.exe.config"; DestDir: "{app}"; Flags: ignoreversion
Source: "C:\VS12\Projects\DCS\bin\Debug\DCS.vshost.exe.manifest"; DestDir: "{app}"; Flags: ignoreversion
Source: "C:\VS12\Projects\DCS\bin\Debug\DCS.application"; DestDir: "{app}"; Flags: ignoreversion
Source: "C:\VS12\Projects\DCS\bin\Debug\DCS.exe.config"; DestDir: "{app}"; Flags: ignoreversion
Source: "C:\VS12\Projects\DCS\bin\Debug\DCS.exe.manifest"; DestDir: "{app}"; Flags: ignoreversion
Source: "C:\VS12\Projects\DCS\bin\Debug\DCS.pdb"; DestDir: "{app}"; Flags: ignoreversion
Source: "C:\VS12\Projects\DCS\bin\Debug\DCS.vshost.application"; DestDir: "{app}"; Flags: ignoreversion
Source: "C:\VS12\Projects\DCS\bin\Debug\DCS.vshost.exe"; DestDir: "{app}"; Flags: ignoreversion
Source: "C:\VS12\Projects\DCS\bin\Debug\DCS.xml"; DestDir: "{app}"; Flags: ignoreversion
Source: "C:\VS12\Projects\DCS\bin\Debug\mysql-connector-odbc-5.1.12-win32.msi"; DestDir: "{app}"; Flags: ignoreversion
; NOTE: Don't use "Flags: ignoreversion" on any shared system files

[code]
function IsMySQLOdbcInstalled(): boolean;
begin
    If NOT RegKeyExists(HKEY_LOCAL_MACHINE, 'Software\ODBC\ODBCINST.INI\MySQL ODBC 5.1 Driver') then
    Result := True
    Else
    Result := False;
end;

[Icons]
Name: "{group}\DCS"; Filename: "{app}\DCS.exe"
Name: "{commondesktop}\DCS"; Filename: "{app}\DCS.exe"; Tasks: desktopicon

[Run]
Filename: {src}\mysql-connector-odbc-5.1.12-win32.msi; Check: IsMySQLOdbcInstalled()
Filename: "{app}\DCS.exe"; Description: "{cm:LaunchProgram,DCS}"; Flags: nowait postinstall skipifsilent

これで、コンパイルは正常に行われ、setup.exe 実行可能ファイルが生成されます。実行すると、アプリ DCS はインストールされますが、MySQL ODBC はインストールされず、エラーが発生します。

Unable to execute file:
'Output path'\mysql-connector-odbc-5.1.12-win32.msi
Create Process failed; code2.
The system cannot find the file specified. 

OK

出力フォルダーには mysql-connector-odbc msi インストール フォルダーが必要だと思いました。確認するために、手動でコピーし、再コンパイルしてセットアップを実行しましたが、同じ結果が得られましたが、いくつかの変更が加えられました。

Unable to execute file:
'Output path'\mysql-connector-odbc-5.1.12-win32.msi
Create Process failed; code193.
%1 is not a vaild Win32 application. 

OK

また、インストールを開始する前にインストーラーが MySQL ODBC ドライバーをチェックするようにしたかったのですが、ここでは、メイン アプリケーションのインストール後にチェックします。このスクリプトを修正するのを手伝ってくれる人はいますか?

ありがとう

4

1 に答える 1

2

問題はあなたの[Run]セクションにあります。パスからその MySQL ODBC インストーラーを実行します{src}。mysql-connector-odbc-5.1.12-win32.msiインストーラー ファイルをフォルダーにコピーするため{app}、同じフォルダーから実行する必要があります。[Run]スクリプトのセクションを次のように修正します。

[Run]
; on the following line, run the executable from the {app} directory instead
; of {src}; the {src} folder is the folder in which the Setup files are located
; since it is not an *.exe file, you must also specify the shellexec flag
Filename: {app}\mysql-connector-odbc-5.1.12-win32.msi; Check: IsMySQLOdbcInstalled(); Flags: shellexec
Filename: "{app}\DCS.exe"; Description: "{cm:LaunchProgram,DCS}"; Flags: nowait postinstall skipifsilent

アップデート：

追加の要件を満たすために、メインのインストール プロセスの前に ODBC ドライバー インストーラーを実行します。次のスクリプト例を作成しました (ODBC ドライバーのセットアップに関連する部分のみが保持されています)。

とにかく、ODBC ドライバー インストーラーをサイレント モードでデフォルト設定で実行すると、煩わしさが軽減されるのではないかと思います。は、ODBC ドライバー インストーラーを制御するためのパラメーターであり、関数の 2 番目のパラメーターに渡すことができるパラメーターは、Execウィンドウの表示フラグをSW_HIDEではなく、SW_SHOWNORMALユーザーから非表示に保つように指示することができます)。このコードはテストされていないことに注意してください。

[Setup]
AppName=DCS
AppVersion=1.0
DefaultDirName={pf}\DCS

[Files]
; keep just the only one flag, "dontcopy"; it will tell the installer to not copy
; this file entry to the target machine, but will be part of the setup binary and
; available for manual extracting by using the ExtractTemporaryFile(s) function
Source: "C:\VS12\Projects\DCS\bin\Debug\mysql-connector-odbc-5.1.12-win32.msi"; Flags: dontcopy

[Run]
; remove the ODBC driver installer entry from [Run] section since the [Run] section
; is executed after the installation is succesfully finished and your requirement is
; to run it before the installation process
; Filename: {app}\mysql-connector-odbc-5.1.12-win32.msi; Check: IsMySQLOdbcInstalled()

[Code]
function IsMySQLODBC51Installed: Boolean;
begin
  // the result was inverted in the original code; the original function returned
  // True if the ODBC driver was not installed, False otherwise, and according to
  // the function name it should be vice-versa
  Result := RegKeyExists(HKEY_LOCAL_MACHINE, 'Software\ODBC\ODBCINST.INI\MySQL ODBC 5.1 Driver');
end;

procedure CurStepChanged(CurStep: TSetupStep);
var
  ResultCode: Integer;
begin
  // if we are right before the main installation starts and ODBC driver is not yet
  // installed, then...
  if (CurStep = ssInstall) and not IsMySQLODBC51Installed then
  begin
    // now extract the ODBC installaer to the Inno Setup's temporary folder
    ExtractTemporaryFile('mysql-connector-odbc-5.1.12-win32.msi');
    // and execute the ODBC driver installation (it is necessary to use ShellExec
    // since it is not an *.exe file); if the execution fails, then...
    if not ShellExec('', ExpandConstant('{tmp}\mysql-connector-odbc-5.1.12-win32.msi'), '', '', 
      SW_SHOWNORMAL, ewWaitUntilTerminated, ResultCode) then
    begin
      // show the error message with exit code
      MsgBox('MySQL ODBC Driver setup failed!' + #13#10 + 'Exit code: ' + IntToStr(ResultCode) +
        '; ' + SysErrorMessage(ResultCode), mbError, MB_OK);
      // here you can optionally call Abort to abort the upcoming installation process
      // so if you uncomment the following line, the main installation will not run if
      // the ODBC driver installer execution failed
      // Abort;
    end;
  end;
end;
于 2013-10-07T07:23:15.297 に答える