258

ANTLR を使い始めたいのですが、antlr.orgサイトの例を数時間見直した後でも、文法から Java へのプロセスを明確に理解することはできません。

パーサー定義から Java ソースコードに至るまで、ANTLR で実装された 4 つの操作の電卓のような単純な例はありますか?

4

5 に答える 5

467

注：この回答はANTLR3用です！ANTLR4の例を探している場合は、このQ&Aで、単純な式パーサーとANTLR4を使用したエバリュエーターを作成する方法を示します。

最初に文法を作成します。以下は、4 つの基本的な数学演算子 (+、-、​​、および /) を使用して構築された式を評価するために使用できる簡単な文法です。括弧を使用して式をグループ化することもできます。

この文法は非常に基本的なものであることに注意してください。2 つの欠点を挙げると、単項演算子 (-1+9 のマイナス) や .99 のような小数 (先頭の数字なし) は処理されません。これは、自分で作業できる例にすぎません。

文法ファイルExp.gの内容は次のとおりです。

grammar Exp;

/* This will be the entry point of our parser. */
eval
    :    additionExp
    ;

/* Addition and subtraction have the lowest precedence. */
additionExp
    :    multiplyExp 
         ( '+' multiplyExp 
         | '-' multiplyExp
         )* 
    ;

/* Multiplication and division have a higher precedence. */
multiplyExp
    :    atomExp
         ( '*' atomExp 
         | '/' atomExp
         )* 
    ;

/* An expression atom is the smallest part of an expression: a number. Or 
   when we encounter parenthesis, we're making a recursive call back to the
   rule 'additionExp'. As you can see, an 'atomExp' has the highest precedence. */
atomExp
    :    Number
    |    '(' additionExp ')'
    ;

/* A number: can be an integer value, or a decimal value */
Number
    :    ('0'..'9')+ ('.' ('0'..'9')+)?
    ;

/* We're going to ignore all white space characters */
WS  
    :   (' ' | '\t' | '\r'| '\n') {$channel=HIDDEN;}
    ;

(パーサー規則は小文字で始まり、レクサー規則は大文字で始まります)

文法を作成したら、そこからパーサーとレクサーを生成します。ANTLR jarをダウンロードして、文法ファイルと同じディレクトリに保存します。

シェル/コマンド プロンプトで次のコマンドを実行します。

java -cp antlr-3.2.jar org.antlr.Tool Exp.g

エラーメッセージは生成されず、ファイルExpLexer.java、ExpParser.java、およびExp.tokensが生成されるはずです。

すべてが正しく機能するかどうかを確認するには、次のテスト クラスを作成します。

import org.antlr.runtime.*;

public class ANTLRDemo {
    public static void main(String[] args) throws Exception {
        ANTLRStringStream in = new ANTLRStringStream("12*(5-6)");
        ExpLexer lexer = new ExpLexer(in);
        CommonTokenStream tokens = new CommonTokenStream(lexer);
        ExpParser parser = new ExpParser(tokens);
        parser.eval();
    }
}

そしてそれをコンパイルします：

// *nix/MacOS
javac -cp .:antlr-3.2.jar ANTLRDemo.java

// Windows
javac -cp .;antlr-3.2.jar ANTLRDemo.java

そしてそれを実行します：

// *nix/MacOS
java -cp .:antlr-3.2.jar ANTLRDemo

// Windows
java -cp .;antlr-3.2.jar ANTLRDemo

すべてがうまくいけば、コンソールには何も表示されません。これは、パーサーがエラーを検出しなかったことを意味します。変更"12*(5-6)"し"12*(5-6"てから再コンパイルして実行すると、次のように出力されます。

line 0:-1 mismatched input '<EOF>' expecting ')'

さて、ここで文法に Java コードを少し追加して、パーサーが実際に役立つ処理を行うようにします。コードを追加するには、文法内に単純な Java コードを配置{します。}

しかし最初に: 文法ファイル内のすべてのパーサー規則はプリミティブ double 値を返す必要があります。returns [double value]各ルールの後に追加することでそれを行うことができます：

grammar Exp;

eval returns [double value]
    :    additionExp
    ;

additionExp returns [double value]
    :    multiplyExp 
         ( '+' multiplyExp 
         | '-' multiplyExp
         )* 
    ;

// ...

これについてはほとんど説明する必要はありません。すべてのルールは double 値を返すことが期待されています。ここで、コード ブロック内から戻り値double value(プレーンな Java コード ブロック内にはない)と "対話" する{...}には、 の前にドル記号を追加する必要がありますvalue。

grammar Exp;

/* This will be the entry point of our parser. */
eval returns [double value]                                                  
    :    additionExp { /* plain code block! */ System.out.println("value equals: "+$value); }
    ;

// ...

文法は次のとおりですが、Java コードが追加されています。

grammar Exp;

eval returns [double value]
    :    exp=additionExp {$value = $exp.value;}
    ;

additionExp returns [double value]
    :    m1=multiplyExp       {$value =  $m1.value;} 
         ( '+' m2=multiplyExp {$value += $m2.value;} 
         | '-' m2=multiplyExp {$value -= $m2.value;}
         )* 
    ;

multiplyExp returns [double value]
    :    a1=atomExp       {$value =  $a1.value;}
         ( '*' a2=atomExp {$value *= $a2.value;} 
         | '/' a2=atomExp {$value /= $a2.value;}
         )* 
    ;

atomExp returns [double value]
    :    n=Number                {$value = Double.parseDouble($n.text);}
    |    '(' exp=additionExp ')' {$value = $exp.value;}
    ;

Number
    :    ('0'..'9')+ ('.' ('0'..'9')+)?
    ;

WS  
    :   (' ' | '\t' | '\r'| '\n') {$channel=HIDDEN;}
    ;

このevalルールは double を返すようになったので、ANTLRDemo.java を次のように変更します。

import org.antlr.runtime.*;

public class ANTLRDemo {
    public static void main(String[] args) throws Exception {
        ANTLRStringStream in = new ANTLRStringStream("12*(5-6)");
        ExpLexer lexer = new ExpLexer(in);
        CommonTokenStream tokens = new CommonTokenStream(lexer);
        ExpParser parser = new ExpParser(tokens);
        System.out.println(parser.eval()); // print the value
    }
}

もう一度、文法から新しいレクサーとパーサーを (再) 生成し (1)、すべてのクラスをコンパイルし (2)、ANTLRDemo を実行します (3):

// *nix/MacOS
java -cp antlr-3.2.jar org.antlr.Tool Exp.g   // 1
javac -cp .:antlr-3.2.jar ANTLRDemo.java      // 2
java -cp .:antlr-3.2.jar ANTLRDemo            // 3

// Windows
java -cp antlr-3.2.jar org.antlr.Tool Exp.g   // 1
javac -cp .;antlr-3.2.jar ANTLRDemo.java      // 2
java -cp .;antlr-3.2.jar ANTLRDemo            // 3

式の結果が12*(5-6)コンソールに表示されます。

繰り返しますが、これは非常に簡単な説明です。ANTLR wikiを参照して、いくつかのチュートリアルを読んだり、私が投稿したものを少し遊んだりすることをお勧めします。

幸運を！

編集：

この投稿では、上記の例を拡張してMap<String, Double>、提供された式で変数を保持する を提供できるようにする方法を示します。

このコードを現在のバージョンの Antlr (2014 年 6 月) で動作させるには、いくつかの変更を加える必要がありました。ANTLRStringStreamになる必要がANTLRInputStreamあり、戻り値を から に変更するparser.eval()必要があり、最後の節parser.eval().valueを削除する必要がありました。WS$channel

于 2009-12-19T11:24:41.090 に答える
18

Gabriele Tomassetti によるANTLR メガ チュートリアルは非常に役に立ちます。

文法の例、さまざまな言語 (Java、JavaScript、C#、および Python) での訪問者の例、および他の多くのものがあります。強くお勧めします。

編集: ANTLR に関する Gabriele Tomassetti によるその他の有用な記事

于 2017-11-09T08:18:24.447 に答える
7

Antlr 4 の場合、Java コード生成プロセスは次のとおりです。

java -cp antlr-4.5.3-complete.jar org.antlr.v4.Tool Exp.g

それに応じて、クラスパスの jar 名を更新します。

于 2016-04-16T06:48:13.053 に答える
3

バージョン 4.7.1 は若干異なります: インポートの場合:

import org.antlr.v4.runtime.*;

メイン セグメントの場合 - CharStreams に注意してください。

CharStream in = CharStreams.fromString("12*(5-6)");
ExpLexer lexer = new ExpLexer(in);
CommonTokenStream tokens = new CommonTokenStream(lexer);
ExpParser parser = new ExpParser(tokens);
于 2018-12-27T03:00:13.557 に答える