0

たくさんのプロパティを持つ表示オブジェクトがあります。私がやりたいことは、このクラスを複製することです。AS3 でカスタム クラスのディープ コピーを作成することはできないことを理解しているため、プロパティをコピーするだけに頼り、クローン メソッドを使用して、オリジナルとまったく同じプロパティを持つ新しいインスタンスを作成しました。

表示オブジェクトのすべてのプロパティを取得するのに問題があります。確かに、各 var を 1 つずつ呼び出して配列に入れ、その配列を次のようにクローンに返すことができます。

function clone():Array
    array.push(displayObject.x);
    array.push(displayObject.y);
    array.push(displayObject.price);
    return array;

しかし、それは本当のオブジェクト指向ではありません。だから私はすべてのオブジェクトのプロパティを取得する方法を探しています。それから、それらのプロパティを新しいオブジェクトに入れます。

ああ、私は AS3 for Air for Flex で実行しているので、これを行う方法である mx.utils.ObjectUtil を使用できません。

4

2 に答える 2

1

私有財産をコピーすることはできません。ByteArray を使用してプロパティをコピーできます

犬はクローンのターゲットクラスです

public class Dog  {

    public function Dog()
    {
    }

    public function setName($name:String):void {
        name = $name;
    }

    public var subDogs:Array = [];

    public var age:int;

    private var name:String;
}

そして、ここにクローンの方法があります

var dog:Dog = new Dog();
dog.subDogs.push(new Dog());
dog.setName("puppy");
dog.age = 15;

registerClassAlias("vo.Dog", vo.Dog);
var dogA:Object = CloneUtil.copy(dog);

var d:Dog = copy(dog) as Dog;

private function copy(source:Object):* {

      var ba:ByteArray = new ByteArray();
      ba.writeObject(source);

      ba.position = 0;

      return ba.readObject();
 }
于 2013-10-15T13:05:49.860 に答える
0 
package
{
    import flash.display.Sprite;
    import flash.utils.Dictionary;
    import flash.utils.describeType;
    import flash.utils.getQualifiedClassName;

    public class DynamicClone extends Sprite
    {
        public function DynamicClone()
        {
            var p1 : Player = new Player;
            p1.name = "Simsoft";
            p1.hiddenAccessor = 10;

            var p2 : * = clone( p1 );

            // p2 is a Player instance
            trace(getQualifiedClassName( p2 )); // Player

            // p1 and p2 are not the same instance
            trace(p1 == p2); // False

            // But public properties are cloned
            trace(p2.name); // Simsoft
            trace(p2.hiddenAccessor); // 10
        }

        public function clone( source : Object, cloneGetSet : Boolean = true) : *
        {
            if( !source)
                return null;

            if( source is Array || source is Vector.<*> || source is Vector.<uint> || source is Vector.<int> || source is Vector.<Number> || source is Vector.<Boolean>)
                return source.concat();

            var newInstance : Object = new ( source.constructor );

            // Copy dynamic var
            for(var dynamicVar : String in source)
                newInstance[ dynamicVar ] = source[ dynamicVar ];

            var typeDescription : XML = describeType( source );

            // Copy variables
            for each(var variable : String in typeDescription..variable.@name)
                newInstance[ variable ] = source[ variable ];

            // Copy getter / setter
            if(cloneGetSet)
                for each(var getset : String in typeDescription..accessor.(@access == "readwrite").@name)
                    newInstance[ getset ] = source[ getset ];

            return newInstance;
        }
    }
}

internal class Player {

    // Will be clone
    public var name : String;

    // Won't be clone
    private var _score : uint;

    // Will be clone throught getter/setter
    private var _hidden : uint;

    // Can be clone because we have a getter and a setter
    public function get hiddenAccessor():uint
    {
        return _hidden;
    }

    public function set hiddenAccessor(value:uint):void
    {
        _hidden = value;
    }
}
于 2013-10-15T13:19:29.210 に答える