3

XML データ フィードを受け取り、それを json に変換し、フラット化して json オブジェクトを持たないようにする必要があります。複数回発生する要素を除いて、機能していますが、複数回発生します。apply-templates コマンドでなぜそれが起こっているのか理解していますが、それを修正する方法がわかりません。

元の XML は次のようになります。

<entry>
  <id>542345255</id>
  <published>2013-10-15T15:30:02Z</published>
  <link rel="alternate" type="text/html" href="http://test.com"/>
  <link rel="self" type="application/json" href="http://test1.com"/>
</entry>

望ましい結果は次のようになります。

{
  "id" : "542345255",
  "published" : "2013-10-15T15:30:02Z",
  "link_rel" : "[alternate, self]",
  "link_type" : "[text/html, application/json]",
  "link_href" : "[http://test.com, http://test1.com]"
}

私のXSLTは次のとおりです。

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="text" encoding="utf-8"/>

<xsl:variable name="links" select="entry/link"/>

<xsl:template match="entry">
  <xsl:text>{</xsl:text>
  <xsl:apply-templates/>
  <xsl:text>}</xsl:text>
</xsl:template>

<xsl:template match="id">
  <xsl:text>"id" : "</xsl:text>
  <xsl:value-of select="."/>
  <xsl:text>", </xsl:text>
</xsl:template>

<xsl:template match="published">
  <xsl:text>"postedTime" : "</xsl:text>
  <xsl:value-of select="."/>
  <xsl:text>", </xsl:text>
 </xsl:template>

 <xsl:template match="link">

   <xsl:text>"link_rel" : "[</xsl:text>
   <xsl:for-each select="$links">
     <xsl:value-of select="./@rel"/>
     <xsl:if test="position()!=last()">, </xsl:if>
   </xsl:for-each>
   <xsl:text>]", </xsl:text>

   <xsl:text>"link_type" : "[</xsl:text>
   <xsl:for-each select="$links">
     <xsl:value-of select="./@type"/>
     <xsl:if test="position()!=last()">, </xsl:if>
    </xsl:for-each>
    <xsl:text>]", </xsl:text>

    <xsl:text>"link_href" : "[</xsl:text>
    <xsl:for-each select="$links">
      <xsl:value-of select="./@href"/>
      <xsl:if test="position()!=last()">, </xsl:if>
    </xsl:for-each>
    <xsl:text>]", </xsl:text>

  </xsl:template>
</xsl:stylesheet>

これで、私が得る結果は次のとおりです。

{
  "id" : "542345255",
  "published" : "2013-10-15T15:30:02Z",
  "link_rel" : "[alternate, self]",
  "link_type" : "[text/html, application/json]",
  "link_href" : "[http://test.com, http://test1.com]"
  "link_rel" : "[alternate, self]",
  "link_type" : "[text/html, application/json]",
  "link_href" : "[http://test.com, http://test1.com]"
}
4

3 に答える 3

1

を使用して、もう少し一般的なことを行うことができますxsl:for-each-group。(例の XSLT は 2.0 です。)

例...

XML 入力

<entry>
    <id>542345255</id>
    <published>2013-10-15T15:30:02Z</published>
    <link rel="alternate" type="text/html" href="http://test.com"/>
    <link rel="self" type="application/json" href="http://test1.com"/>
</entry>

XSLT 2.0

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text"/>
    <xsl:strip-space elements="*"/>

    <xsl:template match="/*">
        <xsl:text>{&#xA;</xsl:text>
        <xsl:for-each-group select="*[text()]" group-by="name()">
            <xsl:call-template name="json">
                <xsl:with-param name="name" select="name()"/>
            </xsl:call-template>
        </xsl:for-each-group>
        <xsl:for-each-group select="*/@*" group-by="concat(../name(),name())">
            <xsl:call-template name="json">
                <xsl:with-param name="name" select="concat(../name(),'_',name())"/>
            </xsl:call-template>
        </xsl:for-each-group>
        <xsl:text>}</xsl:text>
    </xsl:template>

    <xsl:template match="*[text()]" mode="json">
        <xsl:value-of select="concat('&quot;',name(),'&quot;',' : &quot;',.,'&quot;&#xA;')"/>
    </xsl:template>

    <xsl:template name="json">
        <xsl:param name="name"/>
        <xsl:value-of select="concat('&#x9;&quot;',$name,'&quot;',' : &quot;')"/>
        <xsl:if test="count(current-group())>1">
            <xsl:text>[</xsl:text>
        </xsl:if>
        <xsl:value-of select="current-group()" separator=", "/>
        <xsl:if test="count(current-group())>1">
            <xsl:text>]</xsl:text>
        </xsl:if>
        <xsl:text>&quot;</xsl:text>
        <xsl:if test="(self::* and (//@*)[1]) or not(last()=position())">
            <xsl:text>,</xsl:text>
        </xsl:if>
        <xsl:text>&#xA;</xsl:text>                  
    </xsl:template>

</xsl:stylesheet>

出力

{
    "id" : "542345255",
    "published" : "2013-10-15T15:30:02Z",
    "link_rel" : "[alternate, self]",
    "link_type" : "[text/html, application/json]",
    "link_href" : "[http://test.com, http://test1.com]"
}
于 2013-10-18T01:55:11.860 に答える
1

入力要素と出力要素の間には 1 対 1 の関係がないため、すべてのlink要素が同時に処理されるように、特定のテンプレートを呼び出す必要がある場合があります。試す：

<xsl:template match="entry">
  <xsl:text>{</xsl:text>
  <xsl:apply-templates/>
  <xsl:call-template name="link" />
  <xsl:text>}</xsl:text>
</xsl:template>

そして代わりに

<xsl:template match="link">

使用する

<xsl:template name="link">
于 2013-10-17T20:01:42.173 に答える