1

次の fortran90 コードを gfortran でコンパイルしようとしました。このプログラムは、7 つの引数を持つ倍精度関数 distance() の値を出力するだけです。実行しようとすると「segmentation fault(core dumped)」というメッセージが出ますが、書き直すと

distance(z1,z2,z3,z4,z5,13.0d0,z7) to distance(z1,z2,z3,z4,z5,z6,z7) ここで、z6 の値は 13.0d0 で、再コンパイルすると、正しい値 13.000 が得られます。 ..

誰かが理由を知っていますか？彼らは私と同じように見えます。ありがとう

program distancetest
implicit none
double precision::drand,distance
double precision::z1,z2,z3,z4,z5,z6,z7
!*********************************
z1=1.0d0
z2=1.0d0
z3=1.0d0
z4=4.0d0
z5=5.0d0
z6=13.0d0
z7=100.0d0
write(*,*) distance(z1,z2,z3,z4,z5,13.0d0,z7)
end program distancetest
!*********************************
double precision function distance(x1,y1,z1,x2,y2,z2,l)
implicit none
double precision::x1,x2,y1,y2,z1,z2,l,x,y,z
x1=x1-l*dble(floor(x1/l))
y1=y1-l*dble(floor(y1/l))
z1=z1-l*dble(floor(z1/l))
x2=x2-l*dble(floor(x2/l))
y2=y2-l*dble(floor(y2/l))
z2=z2-l*dble(floor(z2/l))
x=min(abs(x1-x2),l-abs(x1-x2))
y=min(abs(y1-y2),l-abs(y1-y2))
z=min(abs(z1-z2),l-abs(z1-z2))
distance=sqrt(x*x+y*y+z*z)
end function distance
4

2 に答える 2

2

この関数は、すべての仮引数 bar を変更しますl。変更された仮引数に変数以外を関連付けるとエラーになります。 13.0d0は変数ではありませんz6。

于 2013-10-20T00:50:13.773 に答える
1

IanH の回答を拡張すると、コンパイラが引数の一貫性をチェックできるようにプロシージャをモジュールに入れ、それらのモジュールを使用し、引数の意図を指定すると、ほとんどの Fortran コンパイラがこの問題を検出します。

module MyFunc
   implicit none
contains
   double precision function distance(x1,y1,z1,x2,y2,z2,l)
   implicit none
   double precision, intent (inout)::x1,x2,y1,y2,z1,z2
   double precision, intent (in) :: l
   double precision :: x,y,z
   x1=x1-l*dble(floor(x1/l))
   y1=y1-l*dble(floor(y1/l))
   z1=z1-l*dble(floor(z1/l))
   x2=x2-l*dble(floor(x2/l))
   y2=y2-l*dble(floor(y2/l))
   z2=z2-l*dble(floor(z2/l))
   x=min(abs(x1-x2),l-abs(x1-x2))
   y=min(abs(y1-y2),l-abs(y1-y2))
   z=min(abs(z1-z2),l-abs(z1-z2))
   distance=sqrt(x*x+y*y+z*z)
   end function distance
end module MyFunc


program distancetest
use MyFunc
implicit none
double precision::z1,z2,z3,z4,z5,z6,z7
!*********************************
z1=1.0d0
z2=1.0d0
z3=1.0d0
z4=4.0d0
z5=5.0d0
z6=13.0d0
z7=100.0d0
write(*,*) distance(z1,z2,z3,z4,z5,13.0d0,z7)
end program distancetest

たとえば、gfortran から:

write(*,*) distance(z1,z2,z3,z4,z5,13.0d0,z7)
                                   1
Error: Non-variable expression in variable definition context (actual argument to INTENT = OUT/INOUT) at (1)
于 2013-10-20T17:31:14.420 に答える