3

次のような XML ドキュメントがあります。

<library>
  <artist name="a">
   <album name="1"></album>
   <album name="2"></album>
  </artist>
  <artist name="b">
   <album name="8"></album>
   <album name="9"></album>
  </artist>
</library>`

Ubuntu の Vala でアプリケーションをコーディングしており、libxml2 ライブラリを使用して XML ドキュメントを操作しています。albumドキュメント内の位置に関係なく、すべてのノードを取得したかったのです。前述のジョブを実行するために、次のコードを作成しました。

document = Xml.Parser.parse_file (PATH_TO_DB);
...
Xml.XPath.Context context;
unowned Xml.XPath.Object *object;

context = new Xml.XPath.Context(document);
object = context.eval("//album");

if(object->nodesetval->is_empty())
    return null;

return object->nodesetval->item(0);
...

この XPath クエリは、 の下のアルバムartist a、つまりアルバム 1 と 2 のみを返します。ただし、context.eval("/library/artist[@name="b"]/album");の下のすべてのアルバムを返していartist bます。

上記のコードに相当する Python は、目的の結果を生成しています。

doc = libxml2.parseFile("data.xml")
ctxt = doc.xpathNewContext()
res = ctxt.xpathEval("//album")

Vala コードの何が問題になっていますか?

4

1 に答える 1

1

最初に、 を調べて、返されたオブジェクトが NodeSet であることを確認する必要がありますobject->type == Xml.ObjectType.NODESET。

次に、結果のノードセットの最初の項目のみを返します。項目がありnodeset->length()ます。

void main() {
    var document = Xml.Parser.parse_file ("file.xml");
    run_query("//album", document);
    run_query("/library/artist[@name=\"b\"]/album", document);
}

void run_query(string query, Xml.Doc* document) {
    stdout.printf("Query: %s\n", query);
    Xml.XPath.Context context;
    unowned Xml.XPath.Object *object;

    context = new Xml.XPath.Context(document);
    object = context.eval(query);
    assert(object->type == Xml.XPath.ObjectType.NODESET);

    if(object->nodesetval->is_empty()) {
        stdout.printf("empty");
        return;
    }

    for (var i = 0; i < object->nodesetval->length(); i++) {
        var node = object->nodesetval->item(i);
        stdout.printf("node %s name=\"%s\"\n", node->name, node->get_prop("name"));
    }
}

プロデュース:

Query: //album
node album name="1"
node album name="2"
node album name="8"
node album name="9"
Query: /library/artist[@name="b"]/album
node album name="8"
node album name="9"
于 2013-10-20T14:17:21.470 に答える