1

2 つの列データを含むファイルがあります。プロットすると、次のようになりますgnuplot 画像

緑色の線は平均を示しています。Y軸に平均値を表示したい。出来ますか？コード：

set style data lines
set termoption enhanced
set term png
set title "17th oct"
stats 'data/17-10-2013' using 1:2 nooutput
set xdata time
set timefmt "%s"
set format x "%H"
set output "images/17_DB.png"
plot "data/17-10-2013" using 1:3 title " Data" , STATS_mean_y title " Mean"

4

1 に答える 1

1

値を表示するための 3 つの異なるオプションを次に示します。

set term pngcairo enhanced
set output "images/17_DB.png"

set title "17th oct"
stats 'data/17-10-2013' using 1:2 nooutput
set xdata time
set timefmt "%s"
set format x "%H"

# first option    
set ytics add (sprintf('%.1f', STATS_mean_y) STATS_mean_y)

# second option
set ytics add ('' STATS_mean_y)
set rmargin 3
set label left at graph 1.05,first STATS_mean_y sprintf('%.1f', STATS_mean_y)

set style data lines

# third option inside the key label
plot "data/17-10-2013" using 1:3 title "Data" , \
     STATS_mean_y title sprintf("Mean = %.1f", STATS_mean_y)

ここでは、さまざまなオプションに関するいくつかの注意事項を示します。

  1. 最初のオプションが最も簡単ですが、ラベルが別のラベル (ここでは ) と重なる可能性があり0ます。
  2. 2 番目のオプションは、空の市長ティックを追加し、ラベルを右側に配置します。set rmargin 2これには、右マージンを手動で増やす必要があります (たとえば、他の座標など、別の値を使用する必要がある場合があります)。
  3. 3 番目のオプションは、値をキー (凡例) エントリに配置するだけです。

より適切なx- 軸を作成するには、 を追加するとよいset autoscale xfixでしょう。これにより、右側の空白が取り除かれます。

于 2013-10-22T12:08:38.703 に答える