0

多くの IP アドレスに ping を実行するスクリプトを作成したいと考えています。しかし、エラーレベルは使いたくありません。

各 IP アドレスに 5 回 ping を実行し、結果を表示したい:

  • 5 パケットが失われた場合、エコー %ip - DOWN を表示したい
  • 3 つのパケットが失われた場合、エコーを表示したい %ip - 3 lost
  • 等...

だから私はこの行から変数で「失われたパケット」を取り戻したい：

"パケット: 送信 = 4、受信 = 4、損失 = 0 (損失 0%)

これは私のコードですが、これは機能しません。

echo off 

set perte=0 
set servers=servers.txt 

for /f %%i in (%servers%) do call :testping %%i 
goto:eof

:testping 
FOR /f "tokens=3 delims==" %%a IN (' ping -n 5 %1 ^|find "lost"') 
DO (set perte=%%b) 

if %perte%==1 echo %1 lost 1 ping
if %perte%==2 echo %1 lost 2 ping
if %perte%==3 echo %1 lost 3 ping
if %perte%==4 echo %1 lost 4 ping
if %perte%==5 echo %1 DOWN
if %perte%==0 echo %1 UP
goto:eof
4

2 に答える 2

0

ほぼ完了しました。試す

@echo off 

    setlocal enableextensions 

    set servers=servers.txt

    for /f %%i in (%servers%) do call :testping %%i

    endlocal
    exit /b

:testping 
    rem
    rem How/Why delims are defined as =,(
    rem Packets: Sent = 5, Received = 5, Lost = 0 (0% loss), 
    rem ..............^..^..........^..^......^...^.........
    rem token: 1       2  3          4  5      6   7
    rem
    FOR /f "tokens=6 delims==,(" %%a IN (' ping -n 5 %1 ^| find /i "lost" ') do (
        if %%a EQU 0 (
            echo %1 UP
        ) else if %%a EQU 5 (
            echo %1 DOWN
        ) else (
            echo %1 lost %%a ping
        )
    )
    goto :EOF
于 2013-10-28T08:59:29.813 に答える