2

ダンプ (?) の質問で申し訳ありません。ツールバーに GTK コンボボックスを追加するにはどうすればよいですか? 私はそれをグーグルで検索しましたが、答えが見つかりませんでした。エラーなしでコンパイルされますが、アプリケーションを実行すると、次のメッセージがコンソールに出力されます。

Gtk-CRITICAL **: gtk_toolbar_insert: assertion 'GTK_IS_TOOL_ITEM (item)' failed

ツールバー + コンボボックスの例を次に示します。

using Gtk;

public class Example : Object  {
    private Window _win;
    private Toolbar _tb;

    public Example() {
        _win = new Window();
        _win.title = "Test";
        _win.window_position = WindowPosition.CENTER;
        _win.set_default_size(800, 600);
        _win.destroy.connect(Gtk.main_quit);

        _tb = new Toolbar();
        var img = new Image.from_icon_name("document-new", Gtk.IconSize.SMALL_TOOLBAR);
        var btn = new ToolButton(img, "New");
        _tb.add(btn);

        add_zoombox();

        var vbox = new Box(Orientation.VERTICAL, 0);
        vbox.pack_start(_tb, false, true, 0);

        _win.add(vbox);
    }

    private void add_zoombox() {
        ListStore list = new ListStore(1, typeof (int));
        for(int i = 25; i<= 400; i*=2) {
            TreeIter iter;
            list.append(out iter);
            list.set(iter, 0, i);
        }

        ComboBox cb = new ComboBox.with_model(list);
        CellRendererText r = new CellRendererText();
        cb.pack_start(r, false);
        cb.set_active(0);
        _tb.add(cb);
        cb.show();
    }

    public void show_window() {
        _win.show_all();
    }


}

public static int main (string[] args) {
    Gtk.init(ref args);
    Example ex = new Example();
    ex.show_window();
    Gtk.main();
    return 0;
}
4

1 に答える 1

3

自分で問題を解決しました。ドキュメントをもう一度読んだ後、ツールバーには ToolButtons、ToggleToolButtons、および RadioToolButtons のみを含めることができることがわかりました。Combobox またはその他のアイテムをツールバーに追加するには、最初に ToolItem に追加する必要があります。変更されたコードは次のとおりです。

ToolItem container = new ToolItem();
_tb.add(container);
container.add(cb);
cb.show();
于 2013-10-28T08:25:08.980 に答える