xml - 子ノードの条件に基づいて出力に親を書き込む XSLT

Question

ある条件でxmlを出力したい。

ここに私の入力XMLがあります

<YIORDER01>
    <IDOC>
        <E1ORHDR>
            <E1OROPR>
                <VORNR>0010</VORNR>
                <E1OROPR_MAT>
                    <MATNR>M0003-01</MATNR>
                    <YE1OROPR_MAT>
                        <STTXT>REL</STTXT>
                        <MTART>ZPAR</MTART>
                        <POSTP>L</POSTP>
                    </YE1OROPR_MAT>
                </E1OROPR_MAT>
                <E1OROPR_MAT>
                    <MATNR>M0003-01</MATNR>
                    <YE1OROPR_MAT>
                        <STTXT>REL</STTXT>
                        <MTART>XYZ</MTART>
                        <POSTP>M</POSTP>
                    </YE1OROPR_MAT>
                </E1OROPR_MAT>
            </E1OROPR>
            <E1OROPR>
                <VORNR>0020</VORNR>
                <E1OROPR_MAT>
                    <MATNR>M0003-01</MATNR>
                    <YE1OROPR_MAT>
                        <STTXT>REL</STTXT>
                        <MTART>ZPAR</MTART>
                        <POSTP>L</POSTP>
                    </YE1OROPR_MAT>
                </E1OROPR_MAT>
            </E1OROPR>
        </E1ORHDR>
    </IDOC>
</YIORDER01>

そして出来上がりはこんな感じ。

<PartOrderList>
   <PartOrder>
      <OperationBONumber>0010</OperationBONumber>
      <PartOrderLine>
         <MaterialNumber>M0003-01</MaterialNumber>
         <ShipmentType>REL</ShipmentType>
      </PartOrderLine>
   </PartOrder>
   <PartOrder>
      <OperationBONumber>0020</OperationBONumber>
   </PartOrder>
</PartOrderList>

そして、私のXSLTはこれです

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="YIORDER01">
        <xsl:element name="PartOrderList">
            <xsl:for-each select="IDOC/E1ORHDR/E1OROPR">
                <xsl:element name="PartOrder">
                    <xsl:element name="OperationBONumber">
                        <xsl:value-of select="VORNR"/>
                    </xsl:element>
                    <xsl:for-each select="E1OROPR_MAT">
                        <xsl:if test="YE1OROPR_MAT/MTART = &apos;ZPAR&apos; and YE1OROPR_MAT/POSTP = &apos;L&apos;">
                            <xsl:element name="PartOrderLine">
                                <xsl:element name="MaterialNumber">
                                    <xsl:value-of select="MATNR"/>
                                </xsl:element>
                                <xsl:element name="ShipmentType">
                                    <xsl:value-of select="YE1OROPR_MAT/STTXT"/>
                                </xsl:element>
                            </xsl:element>
                        </xsl:if>
                    </xsl:for-each>
                </xsl:element>
            </xsl:for-each>
        </xsl:element>
    </xsl:template>
</xsl:stylesheet>

ここでの問題は、「PartOrderLine」の子がないため、出力に 2 番目の「PartOrder」タグが必要ないことです。

xslt で使用されるルール:

入力の「E1OROPR」ごとに、出力に「PartOrder」タグを作成します
"MTART" = "ZPAR" および "POSTP" = "L" の場合にのみ、"PartOrder" 内に "PartOrderLine" タグを作成します。
出力に有効な「PartOrderLine」タグがない場合は、「PartOrder」タグを作成しないでください。

xslt を使用すると、ルール 1 と 2 を達成できますが、ルール 3 を達成する方法がわかりません
。xslt を使用してこれを達成する方法はありますか??

助けてください。

score 3 · Accepted Answer

条件を述語として外側のfor-each選択式に追加して、少なくとも 1 つの要素を生成することがわかっている要素のみを for-each するようにする必要があります。PartOrderLine

<xsl:for-each select="IDOC/E1ORHDR/E1OROPR[
      E1OROPR_MAT/YE1OROPR_MAT[MTART = 'ZPAR' and POSTP = 'L']]">

score 0 · Accepted Answer

参考：これが私がそれにアプローチする方法です。この方法の利点は次のとおりです。

有効な明細ルールは 1 回だけ定義されるため、ロジックを変更すると、PO と POLine の両方が変更されます。
何かを修正したい場合は、すべてのデータを簡単に見つけることができます。
すべてのテンプレートを並行して実行できるため、(一般的に) マルチプロセッサマシンでより高速になります。

.

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">

  <xsl:output method="xml" indent="yes"/>

  <!-- Part Order List -->
  <xsl:template match="/*">
    <xsl:element name="PartOrderList">
      <xsl:apply-templates select=".//E1OROPR" /> 
    </xsl:element>
  </xsl:template>

  <!-- Part Order List > Part Order -->
  <xsl:template match="//E1OROPR">
    <xsl:variable name="IsValid">
      <xsl:call-template name="HasOrIsValidPOLine" />
    </xsl:variable>
    <xsl:if test="$IsValid='VALID'"> <!-- only display the part order if there's a valid line under it-->
      <xsl:element name="PartOrder">
        <xsl:apply-templates select=".//VORNR" />
        <xsl:apply-templates select=".//E1OROPR_MAT" />
      </xsl:element>
    </xsl:if>
  </xsl:template>

  <!-- Part Order List > Part Order > Operational BO Number -->
  <xsl:template match="//VORNR">
    <xsl:element name="OperationBONumber">
      <xsl:value-of select="text()"/>
    </xsl:element>
  </xsl:template>

  <!-- Part Order List > Part Order > Part Order Line -->
  <xsl:template match="//E1OROPR_MAT">
    <xsl:variable name="IsValid">
      <xsl:call-template name="HasOrIsValidPOLine" />
    </xsl:variable>
    <xsl:if test="$IsValid='VALID'">
      <!-- only display the part order line if it's valid-->
      <xsl:element name="PartOrderLine">
        <xsl:apply-templates select=".//MATNR" />
        <xsl:apply-templates select=".//STTXT" />
      </xsl:element>
    </xsl:if>
  </xsl:template>

  <!-- Part Order List > Part Order > Part Order Line > Material Number -->
  <xsl:template match="//MATNR">
    <xsl:element name="MaterialNumber">
      <xsl:value-of select="text()"/>
    </xsl:element>
  </xsl:template>

  <!-- Part Order List > Part Order > Part Order Line > Shipment Type -->
  <xsl:template match="//STTXT">
    <xsl:element name="ShipmentType">
      <xsl:value-of select="text()"/>
    </xsl:element>
  </xsl:template>

  <xsl:template name="HasOrIsValidPOLine">
    <xsl:choose>
      <xsl:when test=".//MTART/text() = 'ZPAR' and .//POSTP/text() = 'L'">VALID</xsl:when>
      <xsl:otherwise>INVALID</xsl:otherwise>
    </xsl:choose>
  </xsl:template>

</xsl:stylesheet>

とはいえ、これをさらに改善するためにできることはおそらくたくさんあります/どのオプションを選択するかは、最も快適に作業できるコードに依存する必要があります(ある程度; 新しいアプローチには学習曲線があり、最初は不快になる可能性があります) 、したがって、これは長期的な考慮のために考慮する必要があります)。

xml - 子ノードの条件に基づいて出力に親を書き込む XSLT

2 に答える 2

Related

Reference