svn - Tortoise で誰かがプロジェクトをコミットしたことを知る方法

Question

お願いします、

開発者がいつプロジェクトを「コミット」するかを知る必要があるため、他の開発者にバージョンを更新する必要があることを通知できます。

これを行うコマンドラインはありますか？

Answer 1

使用できる CommitMonitor という簡単なツールがあります。トレイに座って、新しいコミットを通知します。ただし、これはWindowsのみです。

http://stefanstools.sourceforge.net/CommitMonitor.html

通常、コミットでは、他の全員がすぐに更新する必要はありません。通常、開発者はいつ更新するかを自分で決めます。なぜなら、作業の途中での更新はあなたを引き戻すからです (つまり、再構築を行ったり、作業中のコードのマージ競合を修正したりする必要があります)。

Answer 2

Windows の post-commit フックである post-commit.cmd を介して、tolist.txt 内の人々に通知します。

set repo=%1
set rev=%2
set svnlook="svnlook.exe"
if exist "%repo%\hooks\blat" set blat="%repo%\hooks\blat\blat.exe"

:ok

if [%blat%]==[] goto :exitzero

set tmpfile=c:\temp\blat%RANDOM%

:: Build subject line
for /f "tokens=1,2 delims=/" %%i in ('svnlook dirs-changed %repo% -r %rev%') do set lev1=%%i&&set lev2=%%j
for /f %%i in ('svnlook author %repo% -r %rev%') do set author=%%i
set subject="%author% committed to %lev1%/%lev2%"

:: Build email text
echo>>%tmpfile% Author, Commit date, Message length, and Message
%svnlook% info %repo% -r %rev% >>%tmpfile%
echo.>>%tmpfile%
echo>>%tmpfile% List of files changed:
%svnlook% changed %repo% -r %rev% >>%tmpfile%

set tolist="%repo%\hooks\tolist.txt"

%blat% -install smtpaddress.company.com myuserid@company.com
%blat% %tmpfile% -tf %tolist% -from Subversion -replyto myuserid@company.com -subject %subject%
del %tmpfile%

:exitzero
exit 0

tolist.txt には、userid@company.com の電子メール アドレスのリストが 1 行に 1 つずつ含まれています。

このコマンド ファイルを機能させるには、blat をダウンロードしてリポジトリの「hooks」サブディレクトリに配置する必要があります。