0

ORACLEのTABLE関数に問題があります。

SET SERVEROUTPUT ON SIZE 100000;

DECLARE 

int_position NUMBER(20);

TYPE T_REC_EMP IS RECORD (  nameFile VARCHAR2(200) );    

R_EMP T_REC_EMP ; -- variable enregistrement de type T_REC_EMP

TYPE TAB_T_REC_EMP IS TABLE OF T_REC_EMP index by binary_integer ;
t_rec TAB_T_REC_EMP ; -- variable tableau d''enregistrements


PROCEDURE Pc_Insert ( v_value IN VARCHAR2) IS
BEGIN

  if t_rec.exists(t_rec.Last) then
    int_position := t_rec.last;
    int_position := int_position +1;

    t_rec(int_position).nomFichier := v_value;
  else
    t_rec(1).nomFichier :=v_value;
  end if;

END;

FUNCTION calice_ORACLE( n IN NUMBER) RETURN T_REC_EMP  PIPELINED IS

BEGIN

  FOR i in 1 .. n LOOP
    PIPE ROW(t_rec(i));
  END LOOP;

  RETURN;
END;

BEGIN

    Pc_Insert('allo1');
    Pc_Insert('allo2');
    Pc_Insert('allo3');

    SELECT * fROM TABLE(calice_ORACLE(2));

END;
/

関数が SQL ステートメントでサポートされていないというエラーがあります (9i 9.2 vr を使用しています)。

4

2 に答える 2

1

  • （コメントですでに指摘されているように）クエリの結果をどうするかについての指示がないPL/SQLに埋め込まれたSELECTステートメントがあります。ローカルで宣言された変数を使用するかSELECT INTO、カーソルを使用して結果をループすることができますFOR rec IN (SELECT...) LOOP .. END LOOP。

  • おそらく、無名ブロックの代わりに PACKAGE を作成したいでしょう。次に、呼び出し元のプログラムで、 のようなクエリを発行できますSELECT * FROM TABLE(mypackagename.calice_ORACLE(2))。

于 2009-12-29T00:02:33.547 に答える
1

まず、連想配列をパイプライン化することはできません。コレクションの種類の詳細については、こちらを確認してください。http://www.developer.com/db/article.php/10920_3379271_2/Oracle-Programming-with-PLSQL-Collections.htm

次に、pl/sql でカーソルを選択または使用する必要があります。

どのように機能するかを少し確認できるように、いくつかのデモコードを作成しました。あなたが実際に何をしたいのかよくわかりませんが、少なくともこれはコンパイルされます。これは良いことです。

create or replace type t_rec_emp as object (namefile varchar2(200));    
/

create or replace type tab_t_rec_emp is table of t_rec_emp;
/

create or replace package mydemopack as
    t_rec tab_t_rec_emp := tab_t_rec_emp(); 
    procedure pc_insert ( v_value in varchar2);
    function calice_oracle( n in integer) return tab_t_rec_emp pipelined;

end;
/

create or replace package body mydemopack as
    procedure pc_insert ( v_value in varchar2) is
    begin
        t_rec.extend(1);
        t_rec(t_rec.count):= t_rec_emp(v_value);
    end;

    function calice_oracle( n in integer) return tab_t_rec_emp pipelined is

    begin

      for i in 1 .. n loop
        pipe row(t_rec(i));
      end loop;

      return;
    end;
end;
/


declare
    cursor c_cur is
        select * from table(myDemoPack.calice_oracle(2));
begin

    myDemoPack.pc_insert('allo1');
    myDemoPack.pc_insert('allo2');
    myDemoPack.pc_insert('allo3');

    for rec in c_cur loop
        dbms_output.put_line(rec.namefile);
    end loop;

end;
/
于 2009-12-30T09:39:13.640 に答える