10

例外ハンドルを使用して、 ORA-01400 エラー(("SCHEMA"."TABLE_NAME"."COLUMN_NAME") に NULL を挿入できません)を処理する必要があります。

ORACLE は (ACCESS_INTO_NULL、ZERO_DIVIDE などの) いくつかの例外を事前定義していますが、明らかに ORA-01400 エラーの例外を定義していません。この特定のエラー コードを処理するにはどうすればよいですか?

このようなものが必要です（他の提案が受け入れられます）。

....
 ...     
 INSERT INTO MY_TABLE (CODE, NAME) VALUES (aCode,aName);
 COMMIT;
   EXCEPTION
     WHEN NULL_VALUES THEN /* i don't know this value , exist?*/
       Do_MyStuff();
     WHEN OTHERS THEN
       raise_application_error(SQLCODE,MY_OWN_FORMAT_EXCEPTION(SQLCODE,SQLERRM),TRUE); 
    END;
4

4 に答える 4

14

事前定義された PL/SQL 例外は、Oracle にとって特別なものです。あなたは本当にそれらを台無しにすることはできません. 独自の事前定義された例外のセットが必要な場合、標準の例外のように「グローバルに」宣言することはできません。代わりに、すべての例外宣言を含む例外パッケージを作成し、それをアプリケーションコードで使用します。

例：

CREATE OR REPLACE PACKAGE my_exceptions
AS
  insert_null_into_notnull EXCEPTION;
  PRAGMA EXCEPTION_INIT(insert_null_into_notnull, -1400);

  update_null_to_notnull EXCEPTION;
  PRAGMA EXCEPTION_INIT(update_null_to_notnull, -1407);
END my_exceptions;
/

パッケージで定義された例外を使用する

CREATE OR REPLACE PROCEDURE use_an_exception AS
BEGIN
  -- application specific code ...
  NULL;
EXCEPTION
  WHEN my_exceptions.insert_null_into_notnull THEN
     -- application specific handling for ORA-01400: cannot insert NULL into (%s)
     RAISE;
END;
/

ソース: http://www.orafaq.com/wiki/Exception

于 2009-12-29T19:01:23.937 に答える
3

次のようなコードで例外を処理できます。

....
 ...
 INSERT INTO MY_TABLE (CODE, NAME) VALUES (aCode,aName);   
 COMMIT;   
   EXCEPTION   
     WHEN OTHERS THEN   
       IF SQLCODE = -1400 THEN
         Do_MyStuff();
       ELSE
         raise_application_error(SQLCODE,MY_OWN_FORMAT_EXCEPTION(SQLCODE,SQLERRM),TRUE);
       END IF;
    END;
于 2009-12-29T16:07:21.357 に答える
2

変数のように、独自の例外を定義できます (それらは他の変数と同じスコープを持つため、パッケージの例外などを定義できます...):

SQL> DECLARE
  2     NULL_VALUES EXCEPTION;
  3     PRAGMA EXCEPTION_INIT(NULL_VALUES, -1400);
  4  BEGIN
  5     INSERT INTO t VALUES (NULL);
  6  EXCEPTION
  7     WHEN null_values THEN
  8        dbms_output.put_line('null value not authorized');
  9  END;
 10  /

null value not authorized

PL/SQL procedure successfully completed
于 2009-12-29T15:56:36.870 に答える
-1 
 INSERT INTO MY_TABLE (CODE, NAME) VALUES (aCode,aName);
 COMMIT;  

      EXCEPTION
         WHEN NULL_VALUES /* i don't know this value , exist?*/
           emesg := SQLERRM;
           dbms_output.put_line(emesg); 
         WHEN OTHERS THEN
           emesg := SQLERRM;
           dbms_output.put_line(emesg);
         END;

SQLERRM は、SQL エラー メッセージを表示します。

http://www.psoug.org/reference/exception_handling.html

于 2009-12-29T16:14:22.020 に答える