34

Excelで次の機能を提供するExcelマクロを作成しようとしています。

=SQL("SELECT heading_1 FROM Table1 WHERE heading_2='foo'")

SQL クエリを使用して、ワークブックのテーブル内のデータを検索 (および場合によっては挿入) できるようにします。

これは私がこれまでに行ったことです：

Sub SQL()

Dim cn As ADODB.Connection
Dim rs As ADODB.Recordset

strFile = ThisWorkbook.FullName
strCon = "Provider=Microsoft.ACE.OLEDB.12.0;Data Source=" & strFile _
& ";Extended Properties=""Excel 12.0;HDR=Yes;IMEX=1"";"

Set cn = CreateObject("ADODB.Connection")
Set rs = CreateObject("ADODB.Recordset")

cn.Open strCon

strSQL = "SELECT * FROM [Sheet1$A1:G3]"

rs.Open strSQL, cn

Debug.Print rs.GetString

End Sub

私のスクリプトは、上記のスニペットのように、ハードコードされた範囲を持つチャームのように機能します。また、静的な名前付き範囲でも非常にうまく機能します。

ただし、動的な名前付き範囲または私にとって最も重要なテーブル名では機能しません。

私が見つけた最も近い答えは、同じ苦しみに苦しんでいるこの男です: http://www.ozgrid.com/forum/showthread.php?t=72973

誰か助けて？

編集

ここまででこれをクックしたので、結果の名前を SQL クエリで使用できます。制限は、テーブルがどのシートにあるかを知る必要があることです。それについて何かできることはありますか？

Function getAddress()

    myAddress = Replace(Sheets("Sheet1").Range("Table1").address, "$", "")
    myAddress = "[Sheet1$" & myAddress & "]"

    getAddress = myAddress

End Function

ありがとう！

4

8 に答える 8

15

できることの 1 つは、動的な名前付き範囲のアドレスを取得し、それを SQL 文字列の入力として使用することです。何かのようなもの：

Sheets("shtName").range("namedRangeName").Address

次のようなアドレス文字列を吐き出します$A$1:$A$8

編集：

以下のコメントで述べたように、完全なアドレス (シート名を含む) を動的に取得し、それを直接使用するか、後で使用するためにシート名を解析できます。

ActiveWorkbook.Names.Item("namedRangeName").RefersToLocal

のような文字列になります=Sheet1!$C$1:$C$4。したがって、上記のコード例では、SQL ステートメントは次のようになります。

strRangeAddress = Mid(ActiveWorkbook.Names.Item("namedRangeName").RefersToLocal,2)

strSQL = "SELECT * FROM [strRangeAddress]"
于 2013-11-03T17:50:30.610 に答える
9 
Public Function GetRange(ByVal sListName As String) As String

Dim oListObject As ListObject
Dim wb As Workbook
Dim ws As Worksheet

Set wb = ThisWorkbook

For Each ws In wb.Sheets
    For Each oListObject In ws.ListObjects
        If oListObject.Name = sListName Then
            GetRange = "[" & ws.Name & "$" & Replace(oListObject.Range.Address, "$", "") & "]"
        Exit Function
        End If
    Next oListObject
Next ws


End Function

あなたのSQLでは、このように使用します

sSQL = "Select * from " & GetRange("NameOfTable") & ""
于 2015-10-20T11:20:31.450 に答える
6

Joan-Diego Rodriguez のルーチンを Jordi のアプローチと Jacek Kotowski のコードの一部で構築 - この関数は、アクティブなワークブックのテーブル名を SQL クエリで使用できるアドレスに変換します。

MikeL への注記: 「[#All]」の追加には、報告された問題を回避する見出しが含まれます。

Function getAddress(byVal sTableName as String) as String 

    With Range(sTableName & "[#All]")
        getAddress= "[" & .Parent.Name & "$" & .Address(False, False) & "]"
    End With

End Function
于 2017-07-18T18:02:13.700 に答える
2

テーブルがあるシートの名前を取得することに関する質問の2番目の部分に答えるだけです:

Dim name as String

name = Range("Table1").Worksheet.Name

編集：

より明確にするために、誰かが Sheet オブジェクトで Range を使用することを提案しました。この場合、必要はありません。テーブルが存在する Range は、テーブルの名前を使用して取得できます。この名前は本全体で使用できます。したがって、Range だけを呼び出すとうまく機能します。

于 2016-06-02T07:08:23.967 に答える
-3

これを見つけて、それは私のために働いた。 

strSQL = "SELECT * FROM DataTable"

'DataTable は名前付き範囲です

Excel シート内の名前付き範囲で SQL ステートメントを実行するにはどうすればよいですか?

于 2017-01-25T20:02:24.103 に答える