1

inno セットアップで、特定のフォルダーの dll (.net と com dll の両方) をループし、各 dll を登録する必要があります。各 dll タイプ (.net/com) を識別し、dll のタイプに応じて regasm/regsvr を使用する方法はありますか。

フォルダー内の .net dll をループして、それぞれを登録するコードがあります。コードはここにあります。この場合、すべての dll は .net タイプでした。同じフォルダーに存在する両方のdllで同じことを達成する方法。

4

1 に答える 1

1

次の関数 (元は の同じ名前のメソッドに基づく) は、パラメーターで指定されたファイルが .NET アセンブリであるthis articleかどうかを判断するのに役立つ場合があります。FileNameその名前が示すように、ファイルが .NET アセンブリの場合は True を返し、そうでない場合は False を返します。この関数は、64 ビット ライブラリだけでなく 32 ビット ライブラリでも機能するはずです。

このコードを変更したものは、Unicode Inno Setup でのみ機能することに注意してください。ANSI バージョンの Inno Setup で使用することは意図されていません。ANSI バージョンの場合、以下に掲載されているヘルパー関数を使用します。

[Code]
function BufferToWord(const Buffer: string): Word;
begin
  Result := Ord(Buffer[1]);
end;

function BufferToLongWord(const Buffer: string): LongWord;
begin
  Result := (Ord(Buffer[2]) shl 16) + Ord(Buffer[1]);
end;

function ReadFromStream(Stream: TStream; Size: Integer): LongWord;
var
  Buffer: string;
begin
  SetLength(Buffer, Size div 2);
  Stream.ReadBuffer(Buffer, Size);
  case Size of
    2: Result := BufferToWord(Buffer);
    4: Result := BufferToLongWord(Buffer);
  else
    RaiseException('Unexpected byte size to be read.');
  end;
end;

function IsDotNetAssembly(const FileName: string): Boolean;
var
  FileStream: TFileStream;
  PEOffset: LongWord;
  MagicNumber: Word;
  ComDescriptor: LongWord;
  DataDirOffset: LongWord;
begin
  // initialize result
  Result := False;
  // open the file to be read
  FileStream := TFileStream.Create(FileName, fmOpenRead or fmShareDenyNone);
  try
    // seek to the PE header start offset and read the value of
    FileStream.Position := $3C;
    PEOffset := ReadFromStream(FileStream, SizeOf(PEOffset));
    // seek to the optional header because of the Magic number,
    // which will tell us if the image is 32 or 64-bit; read it
    FileStream.Position := PEOffset + $18;
    MagicNumber := ReadFromStream(FileStream, SizeOf(MagicNumber));
    // according to image bitness we set the offset to the data
    // directory
    case MagicNumber of
      $010B: DataDirOffset := $60; // 32-bit image
      $020B: DataDirOffset := $70; // 64-bit image
    else
      RaiseException('Invalid image format.');
    end;
    // position to RVA 15 of the data directory array
    FileStream.Position := PEOffset + $18 + DataDirOffset + $70;
    // read the value of the COM descriptor
    ComDescriptor := ReadFromStream(FileStream, SizeOf(ComDescriptor));
    // if this value is non zero, the file is a CLR assembly
    Result := ComDescriptor <> 0;
  finally
    FileStream.free;
  end;
end;

上記のコードを Inno Setup の ANSI バージョンで使用するには、上記のヘルパー関数をこれらに置き換えます。Inno Setup のストリームはバッファとして文字列のみを使用でき、Unicode と ANSI バージョンの Inno Setup では文字列ごとのバイト数が異なるため、これを行うことが重要です。

function BufferToWord(const Buffer: AnsiString): Word;
begin
  Result := (Ord(Buffer[2]) shl 8) + Ord(Buffer[1]);
end;

function BufferToLongWord(const Buffer: AnsiString): LongWord;
begin
  Result := (Ord(Buffer[4]) shl 24) + (Ord(Buffer[3]) shl 16) +
    (Ord(Buffer[2]) shl 8) + Ord(Buffer[1]);
end;

function ReadFromStream(Stream: TStream; Size: Integer): LongWord;
var
  Buffer: AnsiString;
begin
  SetLength(Buffer, Size);
  Stream.ReadBuffer(Buffer, Size);
  case Size of
    2: Result := BufferToWord(Buffer);
    4: Result := BufferToLongWord(Buffer);
  else
    RaiseException('Unexpected byte size to be read.');
  end;
end;

上記の関数の使用法は簡単です。

if IsDotNetAssembly('C:\Wherever\WhateverBinary.dll') then
  MsgBox('The binary file is a .NET assembly!', mbInformation, MB_OK)
else
  MsgBox('The binary file is not a .NET assembly!', mbInformation, MB_OK);
于 2013-11-12T20:13:20.900 に答える