unit-testing - モッキングドメインオブジェクトが機能しない

Question

私はgrails/groovyの初心者なので、この単純な問題を許してください。しかし、私は本当にすべてを試しましたが、成功していません。一般に、サービスメソッドの非常に単純な単体テストを記述したいと考えています。しかし、モックにリストがない理由がわかりません。

私のサービス:

class MenuService {

def mailService

def prepareMenu() {
    def newDinners = []
    def soups = Dish.findAllWhere(dishKind: DishKind.SOUP)
    def mainCourses = Dish.findAllWhere(dishKind: DishKind.MAIN_COURSE)
    def salads = Dish.findAllWhere(dishKind: DishKind.SALAD)
    def menu = checkIfMenuExists(Menu.last())

    deleteUsedMainCoursesAndSoups(menu, soups, mainCourses)
    deleteUsedSalads(menu, salads)

    Collections.shuffle(mainCourses)
    mainCourses = mainCourses.subList(0, 7);

    mainCourses.each {
        Dinner dinner = new Dinner()
        dinner.mainCourse = it
        if (it.withSoup) {
            Collections.shuffle(soups)
            dinner.soup = soups.get(0)
            soups.remove(0)
        }
        newDinners.add(dinner)
    }

    Collections.shuffle(salads)
    salads = salads.subList(0, 2)

    menu.dinners = newDinners
    menu.salads = salads

    menu.save()
    sendMenu(menu)
}

private void deleteUsedSalads(Menu menu, salads) {
    if (!menu.salads.isEmpty()) {
        menu.salads.each {
            if (salads.contains(it)) {
                salads.remove(it)
            }
        }
    }
}

private void deleteUsedMainCoursesAndSoups(Menu menu, soups, mainCourses) {
    if (!menu.dinners.isEmpty()) {
        menu.dinners.each {
            if (mainCourses.contains(it.mainCourse)) {
                mainCourses.remove(it)
            } else if (soups.contains(it.soup))
                soups.remove(it)
        }
    }
}

private Menu checkIfMenuExists(Menu menu) {
    if (menu == null) {
        menu = new Menu()
        menu.dinners = new ArrayList<Dinner>()
        menu.salads = new ArrayList<Dish>()
    }
    menu
}

def sendMenu(Menu menu) {
    mailService.sendMail {
        to ""
        subject ""
        body(view: "/mail", model: [dinners: menu.dinners, salads: menu.salads])
    }
}

}

そして私はそれのためのテストを持っています:

@TestFor(MenuService)
@Mock([Dish, Menu])
@TestMixin(DomainClassUnitTestMixin)
class MenuServiceTests {
def menuService = new MenuService()

void testIfItChoosesNewMenu() {

    def soups = [
            new Dish(name: "Soup 1", dishKind: DishKind.SOUP, ingredients: ""),
            new Dish(name: "Soup 2", dishKind: DishKind.SOUP, ingredients: ""),
            new Dish(name: "Soup 3", dishKind: DishKind.SOUP, ingredients: ""),
            new Dish(name: "Soup 4", dishKind: DishKind.SOUP, ingredients: ""),
            new Dish(name: "Soup 5", dishKind: DishKind.SOUP, ingredients: ""),
            new Dish(name: "Soup 6", dishKind: DishKind.SOUP, ingredients: ""),
            new Dish(name: "Soup 7", dishKind: DishKind.SOUP, ingredients: "")
    ]
    def mainCourses = [
            new Dish(name: "Main course 1", dishKind: DishKind.MAIN_COURSE, ingredients: ""),
            new Dish(name: "Main course 2", dishKind: DishKind.MAIN_COURSE, ingredients: ""),
            new Dish(name: "Main course 3", dishKind: DishKind.MAIN_COURSE, ingredients: ""),
            new Dish(name: "Main course 4", dishKind: DishKind.MAIN_COURSE, ingredients: ""),
            new Dish(name: "Main course 5", dishKind: DishKind.MAIN_COURSE, ingredients: ""),
            new Dish(name: "Main course 6", dishKind: DishKind.MAIN_COURSE, ingredients: ""),
            new Dish(name: "Main course 7", dishKind: DishKind.MAIN_COURSE, ingredients: ""),
            new Dish(name: "Main course 8", dishKind: DishKind.MAIN_COURSE, ingredients: ""),
            new Dish(name: "Main course 9", dishKind: DishKind.MAIN_COURSE, ingredients: ""),
            new Dish(name: "Main course 10", dishKind: DishKind.MAIN_COURSE, ingredients: ""),
            new Dish(name: "Main course 11", dishKind: DishKind.MAIN_COURSE, ingredients: ""),
            new Dish(name: "Main course 12", dishKind: DishKind.MAIN_COURSE, ingredients: ""),
            new Dish(name: "Main course 13", dishKind: DishKind.MAIN_COURSE, ingredients: ""),
            new Dish(name: "Main course 14", dishKind: DishKind.MAIN_COURSE, ingredients: "")
    ]
    def salads = [
            new Dish(name: "Salad 1", dishKind: DishKind.SALAD, ingredients: ""),
            new Dish(name: "Salad 2", dishKind: DishKind.SALAD, ingredients: ""),
            new Dish(name: "Salad 3", dishKind: DishKind.SALAD, ingredients: ""),
            new Dish(name: "Salad 4", dishKind: DishKind.SALAD, ingredients: ""),
    ]

    mockDomain(Dish, [soups, mainCourses, salads])
    Menu menu = menuService.prepareMenu()

    assertEquals 2, menu.salads.size()
    assertEquals 7, menu.dinners.size()
}

}

テストを実行すると失敗します:

Failure:  testIfItChoosesNewMenu(familyhelper.MenuServiceTests)
java.lang.IndexOutOfBoundsException: toIndex = 7
at java.util.SubList.<init>(AbstractList.java:602)
at java.util.RandomAccessSubList.<init>(AbstractList.java:758)
at java.util.AbstractList.subList(AbstractList.java:468)
at familyhelper.MenuService.prepareMenu(MenuService.groovy:18)
at familyhelper.MenuServiceTests.testIfItChoosesNewMenu(MenuServiceTests.groovy:51)

なぜなら：

    def soups = Dish.findAllWhere(dishKind: DishKind.SOUP)
    def mainCourses = Dish.findAllWhere(dishKind: DishKind.MAIN_COURSE)
    def salads = Dish.findAllWhere(dishKind: DishKind.SALAD)

空です。@Mock アノテーションを追加すると、ドメインオブジェクトのすべての動的関数が注入されることを読みましたが、それでも役に立ちません。このテストを修正する方法を知っている人はいますか? 前もって感謝します

score 2 · Accepted Answer

ドメインクラスを明示的にモックする必要はありません。@Mock がそれを行う必要があります。

@TestFor(MenuService)
@Mock([Dish, Menu])
class MenuServiceTests {

    void testIfItChoosesNewMenu() {

        def soups = [
            new Dish(name: "Soup 1", dishKind: DishKind.SOUP, ingredients: ""),
            new Dish(name: "Soup 2", dishKind: DishKind.SOUP, ingredients: ""),
            new Dish(name: "Soup 3", dishKind: DishKind.SOUP, ingredients: ""),
            new Dish(name: "Soup 4", dishKind: DishKind.SOUP, ingredients: ""),
            new Dish(name: "Soup 5", dishKind: DishKind.SOUP, ingredients: ""),
            new Dish(name: "Soup 6", dishKind: DishKind.SOUP, ingredients: ""),
            new Dish(name: "Soup 7", dishKind: DishKind.SOUP, ingredients: "")
        ]

        def mainCourses = [
            new Dish(name: "Main course 1", dishKind: DishKind.MAIN_COURSE, ingredients: ""),
            new Dish(name: "Main course 2", dishKind: DishKind.MAIN_COURSE, ingredients: ""),
            new Dish(name: "Main course 3", dishKind: DishKind.MAIN_COURSE, ingredients: ""),
            new Dish(name: "Main course 4", dishKind: DishKind.MAIN_COURSE, ingredients: ""),
            new Dish(name: "Main course 5", dishKind: DishKind.MAIN_COURSE, ingredients: ""),
            new Dish(name: "Main course 6", dishKind: DishKind.MAIN_COURSE, ingredients: ""),
            new Dish(name: "Main course 7", dishKind: DishKind.MAIN_COURSE, ingredients: ""),
            new Dish(name: "Main course 8", dishKind: DishKind.MAIN_COURSE, ingredients: ""),
            new Dish(name: "Main course 9", dishKind: DishKind.MAIN_COURSE, ingredients: ""),
            new Dish(name: "Main course 10", dishKind: DishKind.MAIN_COURSE, ingredients: ""),
            new Dish(name: "Main course 11", dishKind: DishKind.MAIN_COURSE, ingredients: ""),
            new Dish(name: "Main course 12", dishKind: DishKind.MAIN_COURSE, ingredients: ""),
            new Dish(name: "Main course 13", dishKind: DishKind.MAIN_COURSE, ingredients: ""),
            new Dish(name: "Main course 14", dishKind: DishKind.MAIN_COURSE, ingredients: "")
        ]

        def salads = [
            new Dish(name: "Salad 1", dishKind: DishKind.SALAD, ingredients: ""),
            new Dish(name: "Salad 2", dishKind: DishKind.SALAD, ingredients: ""),
            new Dish(name: "Salad 3", dishKind: DishKind.SALAD, ingredients: ""),
            new Dish(name: "Salad 4", dishKind: DishKind.SALAD, ingredients: "")
        ]

        //Save the domain classes
        [soups, mainCourses, salads].each{it*.save(flush: true, failOnError: true)}

        //Note service is auto injected by @TestFor
        //SO no need to instantiate
        Menu menu = service.prepareMenu() 

        assertEquals 2, menu.salads.size()
        assertEquals 7, menu.dinners.size()
    }
}

ビルドテストデータプラグインをまだ認識していない場合は、これらの種類のテストに使用することをお勧めします。全体として、spock をテストフレームワークとして使用することもお勧めします。

score 1 · Accepted Answer

GORM を使用して DB で何かを見つけるには、まずそれを保存する必要があります。@Alidad は正しかったですが、おそらく以下を使用する必要があります。

 new Dish(...).save(false)

falseinsaveは、ドメインエンティティの検証を無効にします。

score 1 · Accepted Answer

ディッシュを保存するのを忘れた可能性があります。

def salads = [
            new Dish(name: "Salad 1", dishKind: DishKind.SALAD, ingredients: "").save(),
            new Dish(name: "Salad 2", dishKind: DishKind.SALAD, ingredients: "").save(),
            new Dish(name: "Salad 3", dishKind: DishKind.SALAD, ingredients: "").save(),
            new Dish(name: "Salad 4", dishKind: DishKind.SALAD, ingredients: "").save(),
    ]

unit-testing - モッキング ドメイン オブジェクトが機能しない

3 に答える 3

Related

Reference

unit-testing - モッキングドメインオブジェクトが機能しない