2

次の XSLT スタイルシート (簡略化) があります。

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:exsl="http://exslt.org/common"
exclude-result-prefixes="exsl">

<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

<xsl:variable name="categories">
    <category name="one"/>
    <category name="two"/>
    <category name="three"/>
</xsl:variable>

<xsl:template match="/">
<result>

<xsl:for-each select="exsl:node-set($categories)/category">
<xsl:element name="{@name}">

<!-- THIS IS THE PROBLEMATIC PART -->
    <xsl:for-each select="/input/object">
        <item>
            <xsl:value-of select="."/>
        </item>
    </xsl:for-each>

</xsl:element>
</xsl:for-each>
</result>
</xsl:template>
</xsl:stylesheet>

これは、次のソース XML ドキュメントを参照しています (これも簡略化されています)。

<?xml version="1.0" encoding="utf-8"?>
<input>
    <object category="one">a</object>
    <object category="one">b</object>
    <object category="two">c</object>
    <object category="one">d</object>
    <object category="three">e</object>
</input>

ソース ドキュメントへの参照は結果を生成しません。出力は、カテゴリごとに 1 つの空の要素です。

<?xml version="1.0" encoding="UTF-8"?>
<result>
  <one/>
  <two/>
  <three/>
</result>

ソース ドキュメントのアイテムで要素を「埋める」にはどうすればよいですか?

明確にするために、この背後にある「実際の」問題は、別のアプローチを使用して既に解決されています。このアプローチが機能しない理由を理解しようとしています。

4

1 に答える 1

5

XPathではxsl:for-each、選択した「ドキュメント」のコンテキストで解釈されます。つまり/、node-set($categories). 次のコードを試してみてください。

<xsl:template match="/">
  <xsl:variable name="root" select="/"/>
  <result>

  <xsl:for-each select="exsl:node-set($categories)/category">
    <xsl:element name="{@name}">

    <xsl:for-each select="$root/input/object">
        <item>
            <xsl:value-of select="."/>
        </item>
    </xsl:for-each>

    </xsl:element>
  </xsl:for-each>
  </result>
</xsl:template>

変数rootを使用して、テンプレートによって選択されたドキュメントへのアクセスを内側のxsl:for-eachループに渡します。(注: 変数はテンプレートの外に配置することもできます。)

元のコードで に/置き換えることで、実際にノードセットを使用するselect="/input/object"ことを再確認できます。select="/category"要素に空のアイテム (カテゴリごとに 1 つ) を取得します。

于 2013-11-21T07:31:46.197 に答える