1

新しいプロジェクトの Background クラスを作成しました。背景は基本的に、単純なストロークと塗りつぶしの色を重ねた 2 つの角丸長方形になります。

とにかく、今は丸みを帯びた四角形を 1 つ描画しようとしていますが、何らかの理由でステージ上のどこにも表示されません:( エラーはなく、トレースは正しくトレースされています。これは私がフォローしている例です。また、背景を描画する Document クラスのコードも含めました。

Background.as

package src.display{

import flash.display.DisplayObject;
import flash.display.Graphics;
import flash.display.JointStyle;
import flash.display.LineScaleMode;
import flash.display.Shape;
import flash.display.Sprite;
import flash.events.Event;

public class Background extends Sprite {

    private const position:Number = 0;

    private var child:Shape       = new Shape();
    private var bgColor:uint      = 0xE8E7E7;
    private var borderColor:uint  = 0xCCCCCC;
    private var borderSize:uint   = 1;
    private var cornerRadius:uint = 3;
    private var sizeW:uint;
    private var sizeH:uint;

    public function Background():void {
        if (stage) {
            init();
        } else {
            addEventListener(Event.ADDED_TO_STAGE, init);
        }
    }

    private function init(e:Event = null):void {
        removeEventListener(Event.ADDED_TO_STAGE, init);
    }

    public function draw(w, h):void {
        sizeW=w; //w & h are passed from Document class
        sizeH=h;

        child.graphics.beginFill(bgColor);
        child.graphics.lineStyle(borderSize, borderColor);
        child.graphics.drawRoundRect(position, position, sizeW-1, sizeH-1, cornerRadius);
        child.graphics.endFill();

        addChild(child);

        trace("child.x = "+child.x);
        trace("child.x = "+child.y);
        trace("child.w = "+child.width);
        trace("child.h = "+child.height);

    }
}

}

私のトレースはすべて正しく出てきます：

child.x = 0
child.x = 0
child.w = 520
child.h = 510

Background クラスを初期化する Document クラスのコードは次のとおりです。

private function drawBackground():void
    {
        trace("\r"+"drawBackground called");

        bg = new Background();
        bg.draw(globalWidth, globalHeight);

        trace("drawBackground end");
    }
4

1 に答える 1

3

bgフラッシュディスプレイリストのどこかに、たとえばステージに追加する必要があります。

bg = new Background();
bg.draw(globalWidth, globalHeight);
stage.addChild(bg);

描画関数を呼び出すたびに子を追加する必要がないことにもう1つ注意し、それをinit関数に追加します。

private function init(e:Event = null):void {
 removeEventListener(Event.ADDED_TO_STAGE, init);
 addChild(child);
}
于 2010-01-07T20:16:59.323 に答える