linux - PE COFF と ELF のハイブリッドを作成できた人はいますか?

Question

つまり、単一のバイナリ ファイルを Win32 と Linux i386 の両方で実行できますか?

Answer 1

2 つのタイプの形式が競合しているため、これは不可能です。

• PE ファイルの最初の 2 文字は'M' 'Z';でなければなりません。
• ELF ファイルの最初の 4 文字は、'\x7f' 'E' 'L' 'F'.

明らかに、両方の形式を満たす 1 つのファイルを作成することはできません。

---

16 ビット COM ファイルと Linux ELF ファイルの両方として有効なポリグロット バイナリに関するコメントに応えて、それは可能です (ただし、実際には COM ファイルは Windows ではなく DOS プログラムであり、Win32 でもありません)。

これは私がまとめたものです - NASM でコンパイルしてください。これは、ELF ファイル ( '\x7f' 'E') の最初の 2 バイトがたまたま有効な 8086 マシン コード (45 バイトの相対 jump-if-greater-than 命令) であるためです。Brian Raiter から盗用された最小限の ELF ヘッダー。

BITS 32
ORG 0x08048000

  ehdr:                                                 ; Elf32_Ehdr
                db      0x7F, "ELF", 1, 1, 1, 0         ;   e_ident
        times 8 db      0
                dw      2                               ;   e_type
                dw      3                               ;   e_machine
                dd      1                               ;   e_version
                dd      _start                          ;   e_entry
                dd      phdr - $$                       ;   e_phoff
                dd      0                               ;   e_shoff
                dd      0                               ;   e_flags
                dw      ehdrsize                        ;   e_ehsize
                dw      phdrsize                        ;   e_phentsize
                dw      1                               ;   e_phnum
                dw      0                               ;   e_shentsize
                dw      0                               ;   e_shnum
                dw      0                               ;   e_shstrndx
  ehdrsize      equ     $ - ehdr

times 0x47-($-$$) db    0

; DOS COM File code
BITS 16
    mov dx, msg1 - $$ + 0x100
    mov ah, 0x09
    int 0x21
    mov ah, 0x00
    int 0x21
  msg1:         db      `Hello World (DOS).\r\n$`

BITS 32
  phdr:                                                 ; Elf32_Phdr
                dd      1                               ;   p_type
                dd      0                               ;   p_offset
                dd      $$                              ;   p_vaddr
                dd      $$                              ;   p_paddr
                dd      filesize                        ;   p_filesz
                dd      filesize                        ;   p_memsz
                dd      5                               ;   p_flags
                dd      0x1000                          ;   p_align
  phdrsize      equ     $ - phdr

; Linux ELF code
  _start:
    mov eax, 4      ; SYS_write
    mov ebx, 1      ; stdout
    mov ecx, msg2
    mov edx, msg2_len
    int 0x80
    mov eax, 1      ; SYS_exit
    mov ebx, 0
    int 0x80
  msg2:         db      `Hello World (Linux).\n`
  msg2_len      equ     $ - msg2

  filesize      equ     $ - $$

Answer 2

2つの形式は十分に異なるため、ハイブリッドはありそうにありません。

ただし、Linuxは、「インタプリタ」によるさまざまな実行可能形式のロードをサポートしています。このようにし.exeて、CIL（コンパイルされたC＃または他の.NET言語）を含むコンパイル済みファイルを、たとえばLinuxで直接実行できます。

Answer 3

もちろん。Javaを使用します。