xslt - 孫のすべてのトークンに対して node() を複製し、孫の要素テキストを XSLT 1.0 のトークンで置き換えますか?

Question

私の（簡略化された）入力XML は次のようになります。

<?xml version="1.0" encoding="utf-8"?>
<root>
  <recordList>

    <record>
      <id>16</id>

      <MaterialGroup>
        <material>
          <term>metal, glass</term>
        </material>
        <material.notes />
        <material.part>body</material.part>
      </MaterialGroup>

      <MaterialGroup>
        <material>
          <term>wood</term>
        </material>
        <material.notes>fragile</material.notes>
        <material.part>lid</material.part>
      </MaterialGroup>
    </record>

    <record>
      ...
    </record>

  </recordList>
</root>

term複数のマテリアルのカンマ区切りのリスト ( ) が含まれる場合があることに注意してくださいmetal, glass。

望ましい出力:

を分割し、そのためのすべての属性とノードを使用しmaterial/termて祖父母を複製する必要があります。Material

<?xml version="1.0" encoding="utf-8"?>
...
      <MaterialGroup>
        <material>
          <term>metal</term>
        </material>
        <material.notes />
        <material.part>body</material.part>
      </MaterialGroup>

      <MaterialGroup>
        <material>
          <term>glass</term>
        </material>
        <material.notes />
        <material.part>body</material.part>
      </MaterialGroup>

      <MaterialGroup>
        <material>
          <term>wood</term>
        </material>
        <material.notes>fragile</material.notes>
        <material.part>lid</material.part>
      </MaterialGroup>
    </record>
...

1 つ目MaterialGroupは、区切られた孫要素内のトークンごとにコピーされmaterial/term、termテキストはトークン テキストに設定されます。material.partsそのままmaterial.notesコピーできます。

私のスタイルシート:

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:msxsl="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="msxsl"
>
  <xsl:output method="xml" indent="yes"/>
  <xsl:variable name="separator" select="','"/>

  <xsl:template match="@* | node()">
    <xsl:copy>
      <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
  </xsl:template>


  <xsl:template match="material/term" mode="s">
    <xsl:param name="split_term"/>
    <xsl:value-of select="$split_term"/>
  </xsl:template>


  <xsl:template match="MaterialGroup" name="tokenize">
    <xsl:param name="text" select="material/term"/>

    <xsl:choose>
      <xsl:when test="not(contains($text, $separator))">
        <xsl:copy>
          <xsl:apply-templates/>
          <xsl:apply-templates select="material/term" mode="s">
            <xsl:with-param name="split_term">
              <xsl:value-of select="normalize-space($text)"/>
            </xsl:with-param>
          </xsl:apply-templates>

        </xsl:copy>

      </xsl:when>

      <xsl:otherwise>
        <xsl:copy>

          <xsl:apply-templates/>
          <xsl:apply-templates select="material/term" mode="s">
            <xsl:with-param name="split_term">
              <xsl:value-of select="normalize-space(substring-before($text, $separator))"/>
            </xsl:with-param>
          </xsl:apply-templates>

        </xsl:copy>

        <xsl:call-template name="tokenize">
          <xsl:with-param name="text" select="substring-after($text, $separator)"/>
        </xsl:call-template>
      </xsl:otherwise>
    </xsl:choose>

  </xsl:template>

</xsl:stylesheet>

実際の出力:

<?xml version="1.0" encoding="utf-8"?>
<root>
  <recordList>

    <record>
      <id>16</id>

      <MaterialGroup>
        <material>
          <term>metal, glass</term>
        </material>
        <material.notes />
        <material.part>body</material.part>
        metal
      </MaterialGroup>

      <MaterialGroup>
        <material>
          <term>metal, glass</term>
        </material>
        <material.notes />
        <material.part>body</material.part>
        glass
      </MaterialGroup>

      <MaterialGroup>
        <material>
          <term>wood</term>
        </material>
        <material.notes>fragile</material.notes>
        <material.part>lid</material.part>
        wood
      </MaterialGroup>
    </record>

    <record>
      ...
    </record>
  </recordList>
</root>

トークン ( metal、 ) は、以下の子glassとしてテキスト要素として発生します。実際に表示されるテキスト要素 ( ) は変更されていません。MaterialGroupmaterial.partsmaterial/term

同様の問題に対するいくつかの解決策を見ましたが、成功しませんでした：

https://stackoverflow.com/a/5480198/2044940
https://stackoverflow.com/a/10430719/2044940
http://codesequoia.wordpress.com/2012/02/15/xslt-example-add-a- new-node-to-elements/
...

何か案は？

---

編集：マイケルが提案したモードなしのMartinによるソリューション：

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:msxsl="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="msxsl"
>
  <xsl:output method="xml" indent="yes"/>
  <xsl:strip-space elements="*"/>

  <xsl:param name="separator" select="', '"/>

  <xsl:template match="@* | node()">
    <xsl:param name="term"/>
    <xsl:copy>
      <xsl:apply-templates select="@* | node()">
        <xsl:with-param name="term" select="$term"/>
      </xsl:apply-templates>
    </xsl:copy>
  </xsl:template> 


  <xsl:template match="material/term">
    <xsl:param name="term"/>
    <xsl:copy>
      <xsl:value-of select="$term"/>
    </xsl:copy>
  </xsl:template>


  <xsl:template match="MaterialGroup" name="tokenize">
    <xsl:param name="text" select="material/term"/>

    <xsl:choose>
      <xsl:when test="not(contains($text, $separator))">
        <xsl:copy>
          <xsl:apply-templates>
            <xsl:with-param name="term" select="$text"/>
          </xsl:apply-templates>
        </xsl:copy> 
      </xsl:when>

      <xsl:otherwise> 
        <xsl:copy>
          <xsl:apply-templates>
            <xsl:with-param name="term" select="substring-before($text, $separator)"/>
          </xsl:apply-templates>
        </xsl:copy> 

        <xsl:call-template name="tokenize">
          <xsl:with-param name="text" select="substring-after($text, $separator)"/>
        </xsl:call-template>
      </xsl:otherwise>
    </xsl:choose>

  </xsl:template>

</xsl:stylesheet>