3

これはクライアントサーバーアプリケーションです。exeファイルのリストを置き換えたり、スクリプトを実行したり、その他の更新が必要なものをすべて置き換える更新プログラムを作成しています。これはサーバーにインストールされます。

まず、実行可能ファイルがネットワーク共有を介して開かれているかどうかを確認する必要があります。これを手動で行うには、[コンピューターの管理]、[共有ファイル]、[ファイルを開く]の順に移動します。これは、ファイルが開いているかどうかを確認する唯一の方法のようです。R / Wを使用してファイルが開いているかどうかを確認しようとしましたが、機能しませんでした。Win32_ServerConnectionを調べましたが、名前ではなく、開いているファイルの数がリストされています。

Delphiで実行できない場合は、Delphi 7またはC＃でコーディングしたいと思います。サーバー上で開いているファイルを表示できるプログラムをいくつか見つけましたが、これを行う方法については何もありません。

4

5 に答える 5

2

削除してみませんか？ファイルが現在開いている場合は、エラーが発生します。また、削除が機能する場合は、更新された実行可能ファイルをコピーするだけです。

于 2010-01-19T19:46:59.153 に答える
2

Windows 2000以降では、NetFileEnumAPIを使用できます。

program test;

{$APPTYPE CONSOLE}

uses
  Windows,
  Classes,
  SysUtils;

type
  PFileInfo3 = ^TFileInfo3;
  TFileInfo3 = record
    fi3_id: DWORD;
    fi3_permissions: DWORD;
    fi3_num_locks: DWORD;
    fi3_pathname: PWideChar;
    fi3_username: PWideChar;
  end;

  TNetFileEnumCallback = function(const FileInfo: TFileInfo3; Data: Pointer): Boolean;

const
  netapi = 'netapi32.dll';

function NetApiBufferFree(Buffer: Pointer): DWORD; stdcall; external netapi;
function NetFileEnum(servername: PWideChar; basepath: PWideChar; username: PWideChar; level: DWORD; var bufptr: Pointer;
  prefmaxlen: DWORD; var entriesread: DWORD; var totalentries: DWORD; resume_handle: PDWORD): DWORD; stdcall;
  external netapi;

procedure EnumNetFileUsers(const LocalPath: WideString; Callback: TNetFileEnumCallback; Data: Pointer = nil);
const
  EntryCount = 32;
var
  NetResult, EntriesRead, TotalEntries, ResumeHandle: Cardinal;
  Buf: Pointer;
  P: PFileInfo3;
  I: Integer;
begin
  EntriesRead := 0;               
  TotalEntries := 0;
  ResumeHandle := 0;
  repeat
    NetResult := NetFileEnum(nil, PWideChar(LocalPath), nil, 3, Buf, EntryCount * SizeOf(TFileInfo3), EntriesRead,
      TotalEntries, @ResumeHandle);
    if not (NetResult in [ERROR_SUCCESS, ERROR_MORE_DATA]) then
      RaiseLastOSError(NetResult);
    try
      P := Buf;
      for I := 0 to EntriesRead - 1 do
      begin
        if Callback(P^, Data) then
          Break;

        Inc(P);
      end;
    finally
      NetApiBufferFree(Buf);
    end;
  until NetResult = ERROR_SUCCESS;
end;

function ShowFileInfo(const FileInfo: TFileInfo3; Data: Pointer): Boolean;
begin
  Result := False;
  Writeln(Format('id: %d, permissions: $%.8x, num_locks: %d, pathname: ''%s'', username: ''%s''',
    [FileInfo.fi3_id, FileInfo.fi3_permissions, FileInfo.fi3_num_locks, FileInfo.fi3_pathname, FileInfo.fi3_username]));
end;

begin
  try
    if ParamCount = 1 then
      EnumNetFileUsers(ParamStr(1), ShowFileInfo);
  except
    on E: Exception do
    begin
      Writeln(Format('[%s] %s', [E.ClassName, E.Message]));
      ExitCode := 1;
    end;
  end;
end.

パラメータで渡されるパスはLocalPath、二重の円記号で始まる必要があるようです。例：

test.exe C:\\Dev\Test\test.exe

次の出力を生成します（ファイルが共有を介して開かれている場合）。

id: -469761405, permissions: $00000001, num_locks: 0, pathname: 'C:\\Dev\Test\test.exe', username: 'Ondrej'

また、MSDNは次のように述べていることに注意してください。

「AdministratorsまたはServerOperatorsローカルグループのメンバーのみがNetFileEnum関数を正常に実行できます。」

于 2010-01-19T21:54:45.143 に答える
1

これが実行される「サーバー」の静的リストを保持でき、プロセスマシン名、ホスト名、またはコンピューター名を検索して一致するものを探すことができます。リストにある場合は、オープンローカルと見なすことができます。

string name = Environment.MachineName;
string name = System.Net.Dns.GetHostName();
string name = System.Windows.Forms.SystemInformation.ComputerName;

Process[] myProcesses = Process.GetProcessesByName("myExeProcName",MachineName);
foreach(Process myProcess in myProcesses)
{
    Console.Write("MachineName : " + myProcess.MachineName + "\n");
}
于 2010-01-19T20:28:05.560 に答える
1

このような関数を使用して、ファイルシステム上のファイルを変更できるかどうかを確認します。基本的に、fNameという名前の新しいファイルを「作成」しようとしますが、既存のファイル（存在する場合）を開いて、有効なファイルハンドルを取得します。それが失敗した場合、ファイルは使用中です。この関数は実際にはファイルを作成せず、既存のファイルシステムを変更しません（ハンドルを使用して何もしません）。それを使って何かをしたい場合は、ファイルハンドルをファイルに取得できるかどうかをチェックするだけです。

これは、リモートコンピューター上の共有から開かれているファイルに対しても機能します。

 function IsFileInUse(fName: string): boolean;
  var
    HFileRes: HFILE;
  begin
    Result := false;
    if not FileExists(fName) then
      exit;
    HFileRes := CreateFile(pchar(fName),
      GENERIC_READ or GENERIC_WRITE,
      0, nil, OPEN_EXISTING,
      FILE_ATTRIBUTE_NORMAL,
      0);
    Result := (HFileRes = INVALID_HANDLE_VALUE);
    if not Result then
      CloseHandle(HFileRes);
  end;
于 2010-01-20T00:07:28.927 に答える
-1

System.IOでFileSystemWatcherを見たことがありますか？

http://msdn.microsoft.com/en-us/library/system.io.filesystemwatcher.aspx

于 2010-01-19T19:39:54.097 に答える