0

ストアド プロシージャをトリガーして毎日午前 5 時に実行するオラクル ジョブを作成しましたが、ジョブを月曜日から金曜日の午前 5 時にのみ実行するように制限したいと考えています。作成したジョブは次のとおりです。

 DECLARE 
   X NUMBER;
 BEGIN  
   SYS.DBMS_JOB.SUBMIT  ( 
     job       => X    ,
     what      => 'BEGIN  usp_procedurename(''ENV''); END;'   ,
     next_date => to_date('10/01/2014 05:00:00','dd/mm/yyyy hh24:mi:ss')   ,
     interval  => 'SYSDATE + 1'   ,
     no_parse  => FALSE  );  
   SYS.DBMS_OUTPUT.PUT_LINE('Job Number is: ' || to_char(x));
   COMMIT;
 END;

ジョブを月曜日から金曜日の午前 5 時にのみ実行するように制限する間隔を変更する方法はありますか、それとも他の方法はありますか?

これに関するヘルプをいただければ幸いです。ありがとう

4

1 に答える 1

3

dbms_job は使用しないでください - dbms_scheduler によって廃止され、置き換えられて久しいです。

dbms_scheduler を使用すると、次のように実行できます。

begin
  dbms_scheduler.create_job(
      job_name => 'MY_JOB'
     ,job_type => 'PLSQL_BLOCK'
     ,job_action => 'BEGIN  usp_procedurename(''ENV''); END;'
     ,start_date      => to_timestamp_tz('2014-01-09 12:00:00 Europe/Berlin',
                                         'yyyy-mm-dd hh24:mi:ss tzr')
     ,repeat_interval => 'FREQ=DAILY;BYHOUR=05;BYDAY=Mon,Tue,Wed,Thu,Fri'
     ,enabled => TRUE
     ,comments => 'my job (runs Monday to Friday at 05:00)');
end;

注: 開始日には常にタイムゾーン付きのタイムスタンプを使用する必要があります。そうしないと、国が夏時間から夏時間に切り替わるさまざまな時間にジョブが実行されます。

于 2014-01-09T13:10:52.707 に答える