2

Access 2010 レポートの変更に取り組んでいます。レポートには、各レコードのコメントを持つ「メモ」と呼ばれる SharePoint フィールドから生データを読み取る部分があります。「メモ」フィールドには、複数の文が含まれる場合があります。レポートでこれらの文を文ごとに箇条書きにする方法を見つける必要があります。

そのための巧妙な方法を考え出そうとしています。データ入力担当者に、新しい箇条書きの必要性を示す何らかの記号を未加工で使用してもらうことができます。このようにして、レポート式 (またはおそらく VBA 経由) で、それを分離することができます...しかし、どのように?

何かご意見は？

4

2 に答える 2

2

MS Access のメモ データ フィールドは、プロパティとしてリッチ テキストに設定できます。

 UPDATE Table1 
 SET Table1.AMemo = "<ul><li>" & 
     IIf(InStr([AMemo],".")>0,
     Replace(Mid([AMemo],1,Len([AMemo])-1),".","</li>"),[AMemo]) & "</li></ul>"

リッチテキスト

于 2014-01-27T16:13:45.827 に答える
1

最も基本的な形式では、次のようなことができます。[メモ] のテキストを ". " で分割し、文ごとに個別の "ポイント" を作成します。

サンプルデータ: [SharePointData]

SlideNumber  Notes                               
-----------  ------------------------------------
          1  Title slide.                        
          2  Brief overview. Just the highlights.
          3  More stuff.

VBA コード:

Option Compare Database
Option Explicit

Public Function SplitNoteText(RawText As Variant) As Variant
    Dim rtn As Variant, StringArray() As String, Point As Variant
    Const BulletChar = "-"
    rtn = Null
    If Not IsNull(RawText) Then
        rtn = ""
        StringArray = Split(RawText, ". ", -1, vbBinaryCompare)
        For Each Point In StringArray
            If Len(Point) > 0 Then
                If Len(rtn) > 0 Then
                    rtn = rtn & vbCrLf & vbCrLf
                End If
                rtn = rtn & BulletChar & " " & Point
                If Right(Point, 1) <> "." Then
                    ' add back the period that got "consumed" in the Split
                    rtn = rtn & "."
                End If
            End If
        Next
    End If
    SplitNoteText = rtn
End Function

テスト クエリ:

SELECT SlideNumber, Notes, SplitNoteText(Notes) AS Points FROM SharePointData;

結果：

SlideNumber  Notes                                 Points                                     
-----------  ------------------------------------  ----------------------
          1  Title slide.                          - Title slide.                             
          2  Brief overview. Just the highlights.  - Brief overview.

                                                   - Just the highlights.
          3  More stuff.                           - More stuff.
于 2014-01-27T16:18:21.990 に答える