vb.net - VB.NET の List(Of Event)

Question

以下はより大きなプロジェクトの一部ですが、この質問の目的のために、次のコードがあります。

Public MustInherit Class Class1(Of T As {System.Windows.Forms.Control, New})
Inherits System.Windows.Forms.UserControl

Friend Items As New Dictionary(Of Integer, T)

    Sub Add(ByRef Item As T, ByVal Index As Integer)
        Me.Items.Add(Index, Item)
        AddHandler Item.Click, AddressOf Class1Click
    End Sub

    Public Shadows Event Click(ByVal sender As System.Object, ByVal e As System.EventArgs, ByVal Index As Integer)

    Sub Class1Click(ByVal sender As System.Object, ByVal e As System.EventArgs)
        RaiseEvent Click(sender, e, DirectCast(sender, T).Index)
    End Sub

End Class

Public Class Class1CheckBox
    Inherits Class1(Of System.Windows.Forms.CheckBox)
End Class

<Global.Microsoft.VisualBasic.CompilerServices.DesignerGenerated()> _
Partial Class Form1
    Inherits System.Windows.Forms.Form
    ...
    'NOTE: The following procedure is required by the Windows Form Designer
    'It can be modified using the Windows Form Designer.  
    'Do not modify it using the code editor.
    <System.Diagnostics.DebuggerStepThrough()> _
    Private Sub InitializeComponent()
        Me.MyClass1 = New Class1CheckBox()
        Me.CheckBox1 = New System.Windows.Forms.CheckBox()
        Me.CheckBox2 = New System.Windows.Forms.CheckBox()
        Me.CheckBox3 = New System.Windows.Forms.CheckBox()
        Me.CheckBox4 = New System.Windows.Forms.CheckBox()
        Me.SuspendLayout()
        ...
        Me.CheckBox1.Name = "CheckBox1"
        Me.CheckBox2.Name = "CheckBox2"
        Me.CheckBox3.Name = "CheckBox3"
        Me.CheckBox4.Name = "CheckBox4"
        ...
    End Sub
    ...
    Friend WithEvents CheckBox1 As System.Windows.Forms.CheckBox
    Friend WithEvents CheckBox2 As System.Windows.Forms.CheckBox
    Friend WithEvents CheckBox3 As System.Windows.Forms.CheckBox
    Friend WithEvents CheckBox4 As System.Windows.Forms.CheckBox
    Friend WithEvents MyClass1 As Class1CheckBox

End Class

Public Class Form1
    Private Sub MyClass1_Click(ByVal sender As Object, ByVal e As System.EventArgs, ByVal Index As Integer) Handles MyClass1.Click
        MessageBox.Show(DirectCast(sender, CheckBox).Name)
    End Sub

    Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        Me.Controls.OfType(Of CheckBox).AsParallel.ForAll(Sub(n) Me.MyClass1.Add(n, n.Index))
    End Sub

End Class

上記のコードは美しく動作します。4 つのチェックボックスのいずれかがクリックされるたびに、クリックイベントが MyClass1 によってインターセプトされ、MyClass1 によって処理されます。それが私が欲しいものです。

問題は、「クリック」がハードコードされていることです。Class1 はジェネリックであることに注意してください。System.Windows.Forms.Control を継承する任意のクラスを受け入れることができるようにしたいと考えています。一部のコントロールには、Check イベント、ホバー、または GotFocus がある場合があります。必要なのは次のようなものです。適切な構文が何であるかわかりません。

Public Class Class1CheckBox
    Inherits Class1(Of System.Windows.Forms.CheckBox)
    MyBase.AddEvent("Hover", <signature>...)
End Class

Public MustInherit Class Class1(Of T As {System.Windows.Forms.Control, New})
    Inherits System.Windows.Forms.UserControl

    Friend Items As New Dictionary(Of Integer, T)
    Friend Events As New List(Of Event)

    Sub AddEvent(EventName As String, ...)
        Events.Add(EventName...)
    End Sub

    Sub Add(ByRef Item As T, ByVal Index As Integer)
        Me.Items.Add(Index, Item)
        For Each MyEvent As Event In Events
            AddHandler ...
        Next MyEvent
    End Sub

    'Public Shadows Event Click(ByVal sender As System.Object, ByVal e As System.EventArgs, ByVal Index As Integer)

    'Sub Class1Click(ByVal sender As System.Object, ByVal e As System.EventArgs)
    '    RaiseEvent Click(sender, e, DirectCast(sender, T).Index)
    'End Sub

End Class

ある種の一連のイベントを作成するための適切な構文は何ですか?また、これらのイベントを発生させるにはどうすればよいでしょうか?

ありがとう、

score 0 · Accepted Answer

あなたが望むことは不可能です。メソッドやプロパティと同様に、イベントはメンバーです。持っている型にそのメンバーがあることがわかっていない限り、メンバーにアクセスするコードを書くことはできません。

メソッドやプロパティと同様に、実行時に使用するイベントを決定する場合は、Reflection を使用する必要があります。

score 0 · Accepted Answer

jmcilhinney が正しく言うように、リフレクションを使用する必要があります。

簡単な例を次に示します。

Imports System.Reflection

Public MustInherit Class Class1(Of T As {Control, New})

    Private _Items As New Dictionary(Of Integer, T)
    Private _Events As New Dictionary(Of String, [Event])

    Protected Sub AddEvent(eventName As String, [delegate] As [Delegate])
        If (Not Me._Events.ContainsKey(eventName)) Then
            Dim info As EventInfo = GetType(T).GetEvent(eventName)
            If (info Is Nothing) Then
                Throw New ArgumentOutOfRangeException("eventName")
            End If
            Me._Events.Add(eventName, New [Event]([delegate], info))
        End If
    End Sub

    Public Sub AddItem(item As T, index As Integer)
        Me._Items.Add(index, item)
        For Each [event] As KeyValuePair(Of String, [Event]) In Me._Events
            [event].Value.Info.AddEventHandler(item, [event].Value.Delegate)
        Next
    End Sub

    Friend Class [Event]
        Friend Sub New([Delegate] As [Delegate], Info As EventInfo)
            Me.[Delegate] = [Delegate]
            Me.Info = Info
        End Sub
        Public ReadOnly [Delegate] As [Delegate]
        Public ReadOnly Info As EventInfo
    End Class

End Class

Public Class Class1CheckBox
    Inherits Class1(Of CheckBox)

    Public Sub New()
        Me.AddEvent("CheckedChanged", New EventHandler(Sub(sender As Object, e As EventArgs) MsgBox(DirectCast(sender, CheckBox).Name & " is checked: " & DirectCast(sender, CheckBox).Checked.ToString())))
    End Sub

End Class

vb.net - VB.NET の List(Of Event)

2 に答える 2

Related

Reference