apache-flex - スプライトの異なる領域の異なるアルファ値 (Flex/Actionscript)

Question

ここに私の問題があります:
画面全体を覆うスプライトがあります。
このスプライトの特定の長方形を除いて、
スプライトの残りの部分をアルファ = 0.5 にしたいと考えています。
そして、その特定の長方形については、アルファ= 0
が必要です。それは可能ですか? どのように？

Answer 1

最も簡単な解決策は、スプライトに半透明の を指定し、と の両方を true にmask設定することです。cacheAsBitmapmaskSprite

Answer 2

おそらく、 LAYERとERASE BlendMode を組み合わせて使用​​すると、必要なことが行われます。

例：

import flash.display.BlendMode;
import flash.display.Graphics;
import flash.display.Sprite;
import flash.geom.Rectangle;

public class PunchTest extends Sprite {
    private var punchSprite:Sprite = new Sprite();

    public function doPunch(target:Sprite, rect:Rectangle):void {
        var g:Graphics = punchSprite.graphics;
        g.clear();
        g.beginFill(0, 1);
        g.drawRect(rect.x, rect.y, rect.width, rect.height);
        g.endFill();
        punchSprite.blendMode = BlendMode.ERASE;
        target.blendMode = BlendMode.LAYER;
        target.addChild(punchSprite);
    }

    public function PunchTest() {
        super();
        var g:Graphics = graphics;

        // draw a red backgound
        g.beginFill(0xff0000, 1);
        g.drawRect(0, 0, 500, 500);
        g.endFill();

        // add a blue coverring sprite at 0.5 alpha
        var coverSprite:Sprite = new Sprite();
        g = coverSprite.graphics;
        g.beginFill(0x00ff00, 0.5);
        g.drawRect(50, 50, 300, 300);
        g.endFill();
        addChild(coverSprite);

        // do a hole into the cover sprite
        doPunch(coverSprite, new Rectangle(80, 80, 100, 100));
    }
}