csv - Outlook 2007 メール フォルダーとサブフォルダーを csv にエクスポートする

Question

メールを Outlook 2007 フォルダーから CSV ファイルにエクスポートする最良の方法は何ですか? サブフォルダー内にもメール メッセージを含めたいと思います。組み込みの csv エクスポーターでは、オプションでサブフォルダーを含めることはできませんが、それ以外の場合は、まさに私が望むことを行います。

Answer 1

Office オートメーションがここに行く方法だと思います.. Excel がインストールされている場合は、ワークシートのセルにプロパティを直接挿入できます。Excel でマクロを記述して Outlook を自動化することも、Outlook でマクロを記述してデータをワークシートにプッシュすることもできます。

以下では、Outlook 用の VBA の簡単な部分を作成し、代わりに FSO を使用して汚れた作業を行いました。これにより、作業するためのスケルトンが得られます。さらに多くのエラー処理テストなどが必要になります。

Sub SaveItemsToExcel()

    On Error GoTo ErrorHandlerExit


   Dim oNameSpace As Outlook.NameSpace
   Dim oFolder As Outlook.MAPIFolder
   'You must set a reference to the Microsoft Scripting Runtime library touse the FileSystemObject

   Dim objFS As Scripting.FileSystemObject
   Dim objOutputFile As Scripting.TextStream

   Set objFS = New Scripting.FileSystemObject
   Set objOutputFile = objFS.OpenTextFile("C:\Temp\Export.csv", ForWriting, True)
   Set oNameSpace = Application.GetNamespace("MAPI")
   Set oFolder = oNameSpace.PickFolder

   If oFolder Is Nothing Then
      GoTo ErrorHandlerExit
   End If


    ' Check if folder can contain Mail Items
    If oFolder.DefaultItemType <> olMailItem Then
      MsgBox "Folder does not contain mail messages"
      GoTo ErrorHandlerExit
    End If


   'Write header line
    objOutputFile.WriteLine "From,Subject,Recived"

    ProcessFolderItems oFolder, objOutputFile

    objOutputFile.Close

    Set oFolder = Nothing
    Set oNameSpace = Nothing
    Set objOutputFile = Nothing
    Set objFS = Nothing

ErrorHandlerExit:
   Exit Sub


End Sub

Sub ProcessFolderItems(oParentFolder As Outlook.MAPIFolder, ByRef objOutputFile As Scripting.TextStream)
    Dim oCount As Integer
    Dim oMail As Outlook.MailItem
    Dim oFolder As Outlook.MAPIFolder
    oCount = oParentFolder.Items.Count

    For Each oMail In oParentFolder.Items
        If oMail.Class = olMail Then

        objOutputFile.WriteLine oMail.SenderEmailAddress & "," & oMail.Subject & "," & oMail.ReceivedTime

        End If
    Next oMail

    Set oMail = Nothing
    'check to see if we have an child folders
    If (oParentFolder.Folders.Count > 0) Then
            For Each oFolder In oParentFolder.Folders
                ProcessFolderItems oFolder, objOutputFile
            Next
    End If


End Sub  

マーカス