すべて大文字としてインポートされたテーブルがあり、適切なケースに変換したいと考えています。これを完了するために使用したスクリプトはどれですか?
RyanKeeter
質問する
334530 次
24 に答える
122
この機能:
- 空白で区切られたすべての「UPPER CASE」単語を「Proper Cases」
- 「小文字の単語」だけを残す
- 英語以外のアルファベットでも正しく動作します
- 最近の SQL サーバー バージョンの高度な機能を使用しないという点で移植性があります。
- Unicode サポートに NCHAR および NVARCHAR を使用するように簡単に変更でき、適切なパラメータ長も使用できます。
- 空白の定義を構成できます
CREATE FUNCTION ToProperCase(@string VARCHAR(255)) RETURNS VARCHAR(255)
AS
BEGIN
DECLARE @i INT -- index
DECLARE @l INT -- input length
DECLARE @c NCHAR(1) -- current char
DECLARE @f INT -- first letter flag (1/0)
DECLARE @o VARCHAR(255) -- output string
DECLARE @w VARCHAR(10) -- characters considered as white space
SET @w = '[' + CHAR(13) + CHAR(10) + CHAR(9) + CHAR(160) + ' ' + ']'
SET @i = 1
SET @l = LEN(@string)
SET @f = 1
SET @o = ''
WHILE @i <= @l
BEGIN
SET @c = SUBSTRING(@string, @i, 1)
IF @f = 1
BEGIN
SET @o = @o + @c
SET @f = 0
END
ELSE
BEGIN
SET @o = @o + LOWER(@c)
END
IF @c LIKE @w SET @f = 1
SET @i = @i + 1
END
RETURN @o
END
結果：
dbo.ToProperCase('ALL UPPER CASE and SOME lower ÄÄ ÖÖ ÜÜ ÉÉ ØØ ĈĈ ÆÆ')
-----------------------------------------------------------------
All Upper Case and Some lower Ää Öö Üü Éé Øø Cc Ææ
于 2008-10-23T15:37:32.827 に答える
105
これがトリックを行うUDFです...
create function ProperCase(@Text as varchar(8000))
returns varchar(8000)
as
begin
declare @Reset bit;
declare @Ret varchar(8000);
declare @i int;
declare @c char(1);
if @Text is null
return null;
select @Reset = 1, @i = 1, @Ret = '';
while (@i <= len(@Text))
select @c = substring(@Text, @i, 1),
@Ret = @Ret + case when @Reset = 1 then UPPER(@c) else LOWER(@c) end,
@Reset = case when @c like '[a-zA-Z]' then 0 else 1 end,
@i = @i + 1
return @Ret
end
ただし、データを更新するには引き続き使用する必要があります。
于 2008-10-23T15:27:16.747 に答える
48
UPDATE titles
SET title =
UPPER(LEFT(title, 1)) +
LOWER(RIGHT(title, LEN(title) - 1))
于 2013-12-18T14:24:47.603 に答える
19
SQL Server で CLR を有効にできる場合 (2005 以降が必要) 、 TextInfo.ToTitleCase 組み込み関数を使用する CLR 関数を作成できます。コード行。
于 2008-10-23T22:05:43.357 に答える
8
私はゲームに少し遅れていますが、これはより機能的であり、ロシア語、ドイツ語、タイ語、ベトナム語などを含むあらゆる言語で機能すると思います。または ( または ) またはスペース (明らかに :)。
CREATE FUNCTION [dbo].[fnToProperCase]( @name nvarchar(500) )
RETURNS nvarchar(500)
AS
BEGIN
declare @pos int = 1
, @pos2 int
if (@name <> '')--or @name = lower(@name) collate SQL_Latin1_General_CP1_CS_AS or @name = upper(@name) collate SQL_Latin1_General_CP1_CS_AS)
begin
set @name = lower(rtrim(@name))
while (1 = 1)
begin
set @name = stuff(@name, @pos, 1, upper(substring(@name, @pos, 1)))
set @pos2 = patindex('%[- ''.)(]%', substring(@name, @pos, 500))
set @pos += @pos2
if (isnull(@pos2, 0) = 0 or @pos > len(@name))
break
end
end
return @name
END
GO
于 2016-07-28T21:22:56.143 に答える
3
これは、ループではなくシーケンスまたは番号テーブルを使用するバージョンです。WHERE 句を変更して、いつ文字を大文字に変換するかについての個人的な規則に合わせることができます。アポストロフィを除いて、非文字が続く文字を大文字にする単純なセットを含めました。これは、「3」は文字ではないため、123apple が「a」に一致することを意味します。空白 (スペース、タブ、キャリッジ リターン、ライン フィード) のみが必要な場合は、パターン'[^a-z]'を'[' + Char(32) + Char(9) + Char(13) + Char(10) + ']'.
CREATE FUNCTION String.InitCap( @string nvarchar(4000) ) RETURNS nvarchar(4000) AS
BEGIN
-- 1. Convert all letters to lower case
DECLARE @InitCap nvarchar(4000); SET @InitCap = Lower(@string);
-- 2. Using a Sequence, replace the letters that should be upper case with their upper case version
SELECT @InitCap = Stuff( @InitCap, n, 1, Upper( SubString( @InitCap, n, 1 ) ) )
FROM (
SELECT (1 + n1.n + n10.n + n100.n + n1000.n) AS n
FROM (SELECT 0 AS n UNION SELECT 1 UNION SELECT 2 UNION SELECT 3 UNION SELECT 4 UNION SELECT 5 UNION SELECT 6 UNION SELECT 7 UNION SELECT 8 UNION SELECT 9) AS n1
CROSS JOIN (SELECT 0 AS n UNION SELECT 10 UNION SELECT 20 UNION SELECT 30 UNION SELECT 40 UNION SELECT 50 UNION SELECT 60 UNION SELECT 70 UNION SELECT 80 UNION SELECT 90) AS n10
CROSS JOIN (SELECT 0 AS n UNION SELECT 100 UNION SELECT 200 UNION SELECT 300 UNION SELECT 400 UNION SELECT 500 UNION SELECT 600 UNION SELECT 700 UNION SELECT 800 UNION SELECT 900) AS n100
CROSS JOIN (SELECT 0 AS n UNION SELECT 1000 UNION SELECT 2000 UNION SELECT 3000) AS n1000
) AS Sequence
WHERE
n BETWEEN 1 AND Len( @InitCap )
AND SubString( @InitCap, n, 1 ) LIKE '[a-z]' /* this character is a letter */
AND (
n = 1 /* this character is the first `character` */
OR SubString( @InitCap, n-1, 1 ) LIKE '[^a-z]' /* the previous character is NOT a letter */
)
AND (
n < 3 /* only test the 3rd or greater characters for this exception */
OR SubString( @InitCap, n-2, 3 ) NOT LIKE '[a-z]''[a-z]' /* exception: The pattern <letter>'<letter> should not capatolize the letter following the apostrophy */
)
-- 3. Return the modified version of the input
RETURN @InitCap
END
于 2009-11-19T15:20:00.743 に答える
3
SSIS で大文字と小文字が混在するデータをインポートしていて、大文字と小文字が適切な列でルックアップを実行する必要がある場合、ソースが混在していてルックアップ ソースが適切な場合にルックアップが失敗することに気付くでしょう。また、派生列の SQL Server 2008r2 の SSIS である right 関数と left 関数を使用できないことにも気付くでしょう。これが私のために働く解決策です：
UPPER(substring(input_column_name,1,1)) + LOWER(substring(input_column_name, 2, len(input_column_name)-1))
于 2015-07-02T17:53:30.410 に答える
2
Server Server 2016 以降では、STRING_SPLITを使用できます
with t as (
select 'GOOFYEAR Tire and Rubber Company' as n
union all
select 'THE HAPPY BEAR' as n
union all
select 'MONK HOUSE SALES' as n
union all
select 'FORUM COMMUNICATIONS' as n
)
select
n,
(
select ' ' + (
upper(left(value, 1))
+ lower(substring(value, 2, 999))
)
from (
select value
from string_split(t.n, ' ')
) as sq
for xml path ('')
) as title_cased
from t
例
于 2020-10-19T22:34:32.540 に答える
1
フォンノイマン、マッケイン、デグズマン、ジョンソンスミスの世話をするために例外のルックアップを維持することは理にかなっています。
于 2011-07-06T21:01:54.037 に答える
1
上に投稿したリンクは、主な問題に対処する優れたオプションです。少なくともエレガントな方法では、すべてのケース (Smith-Jones、von Haussen、John Smith MD) をプログラムで説明することはできません。Tony は、これらのケースに対処するために、例外/ブレーク文字の概念を導入しています。とにかく、Cervo のアイデア (スペースに先行するすべての小文字) に基づいて、replace ステートメントは、代わりに単一のテーブルベースの置換にまとめることができます。実際、任意の下位/上位文字の組み合わせを @alpha に挿入でき、ステートメントは変更されません。
declare @str nvarchar(8000)
declare @alpha table (low nchar(1), up nchar(1))
set @str = 'ALL UPPER CASE and SOME lower ÄÄ ÖÖ ÜÜ ÉÉ ØØ ĈĈ ÆÆ'
-- stage the alpha (needs number table)
insert into @alpha
-- A-Z / a-z
select nchar(n+32),
nchar(n)
from dbo.Number
where n between 65 and 90 or
n between 192 and 223
-- append space at start of str
set @str = lower(' ' + @str)
-- upper all lower case chars preceded by space
select @str = replace(@str, ' ' + low, ' ' + up)
from @Alpha
select @str
于 2008-10-23T21:56:45.480 に答える
0
次の方が効率的であることがわかると思います。
IF OBJECT_ID('dbo.ProperCase') IS NOT NULL
DROP FUNCTION dbo.ProperCase
GO
CREATE FUNCTION dbo.PROPERCASE (
@str VARCHAR(8000))
RETURNS VARCHAR(8000)
AS
BEGIN
SET @str = ' ' + @str
SET @str = REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE( @str, ' a', ' A'), ' b', ' B'), ' c', ' C'), ' d', ' D'), ' e', ' E'), ' f', ' F'), ' g', ' G'), ' h', ' H'), ' i', ' I'), ' j', ' J'), ' k', ' K'), ' l', ' L'), ' m', ' M'), ' n', ' N'), ' o', ' O'), ' p', ' P'), ' q', ' Q'), ' r', ' R'), ' s', ' S'), ' t', ' T'), ' u', ' U'), ' v', ' V'), ' w', ' W'), ' x', ' X'), ' y', ' Y'), ' z', ' Z')
RETURN RIGHT(@str, LEN(@str) - 1)
END
GO
replaceステートメントは、SQLクエリに直接切り取って貼り付けることができます。これは非常に醜いですが、@ strを目的の列に置き換えることで、このように投稿されたudfsのように、暗黙カーソルの料金を支払う必要がなくなります。UDFを使用しても、はるかに効率的であることがわかりました。
ああ、手動で置換ステートメントを生成する代わりに、これを使用してください：
-- Code Generator for expression
DECLARE @x INT,
@c CHAR(1),
@sql VARCHAR(8000)
SET @x = 0
SET @sql = '@str' -- actual variable/column you want to replace
WHILE @x < 26
BEGIN
SET @c = CHAR(ASCII('a') + @x)
SET @sql = 'REPLACE(' + @sql + ', '' ' + @c+ ''', '' ' + UPPER(@c) + ''')'
SET @x = @x + 1
END
PRINT @sql
とにかくそれは行数に依存します。s / \ b（[az]）/ uc $ 1 /を実行できればいいのですが、私たちが持っているツールを使用しています。
列が大文字であるため、これを.... SELECT dbo.ProperCase（LOWER（column））として使用する必要があるため、これを使用する必要があることに注意してください。5,000エントリ（1秒でもない）の私のテーブルでは、実際にはかなり高速に動作します。
国際化に関するコメントの急増に応えて、SQLServerのupperとlowerの実装のみに依存するすべてのASCII文字を処理する次の実装を紹介します。ここで使用している変数はVARCHARであることに注意してください。これは、ASCII値のみを保持できることを意味します。さらに国際的なアルファベットを使用するには、NVARCHARを使用する必要があります。ロジックは似ていますが、ASCII AND CHARの代わりにUNICODEとNCHARを使用する必要があり、replaceステートメントははるかに巨大になります。
-- Code Generator for expression
DECLARE @x INT,
@c CHAR(1),
@sql VARCHAR(8000),
@count INT
SEt @x = 0
SET @count = 0
SET @sql = '@str' -- actual variable you want to replace
WHILE @x < 256
BEGIN
SET @c = CHAR(@x)
-- Only generate replacement expression for characters where upper and lowercase differ
IF @x = ASCII(LOWER(@c)) AND @x != ASCII(UPPER(@c))
BEGIN
SET @sql = 'REPLACE(' + @sql + ', '' ' + @c+ ''', '' ' + UPPER(@c) + ''')'
SET @count = @count + 1
END
SET @x = @x + 1
END
PRINT @sql
PRINT 'Total characters substituted: ' + CONVERT(VARCHAR(255), @count)
基本的に、私の方法の前提は、効率のために事前計算を交換することです。完全なASCII実装は次のとおりです。
IF OBJECT_ID('dbo.ProperCase') IS NOT NULL
DROP FUNCTION dbo.ProperCase
GO
CREATE FUNCTION dbo.PROPERCASE (
@str VARCHAR(8000))
RETURNS VARCHAR(8000)
AS
BEGIN
SET @str = ' ' + @str
SET @str = REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(@str, ' a', ' A'), ' b', ' B'), ' c', ' C'), ' d', ' D'), ' e', ' E'), ' f', ' F'), ' g', ' G'), ' h', ' H'), ' i', ' I'), ' j', ' J'), ' k', ' K'), ' l', ' L'), ' m', ' M'), ' n', ' N'), ' o', ' O'), ' p', ' P'), ' q', ' Q'), ' r', ' R'), ' s', ' S'), ' t', ' T'), ' u', ' U'), ' v', ' V'), ' w', ' W'), ' x', ' X'), ' y', ' Y'), ' z', ' Z'), ' š', ' Š'), ' œ', ' Œ'), ' ž', ' Ž'), ' à', ' À'), ' á', ' Á'), ' â', ' Â'), ' ã', ' Ã'), ' ä', ' Ä'), ' å', ' Å'), ' æ', ' Æ'), ' ç', ' Ç'), ' è', ' È'), ' é', ' É'), ' ê', ' Ê'), ' ë', ' Ë'), ' ì', ' Ì'), ' í', ' Í'), ' î', ' Î'), ' ï', ' Ï'), ' ð', ' Ð'), ' ñ', ' Ñ'), ' ò', ' Ò'), ' ó', ' Ó'), ' ô', ' Ô'), ' õ', ' Õ'), ' ö', ' Ö'), ' ø', ' Ø'), ' ù', ' Ù'), ' ú', ' Ú'), ' û', ' Û'), ' ü', ' Ü'), ' ý', ' Ý'), ' þ', ' Þ'), ' ÿ', ' Ÿ')
RETURN RIGHT(@str, LEN(@str) - 1)
END
GO
于 2008-10-23T15:51:03.703 に答える
0
戻って大文字ではないデータを取得するには遅すぎますか?
あなたの顧客ベースのフォン・ノイマン、マケイン、デグズマン、ジョンソン・スミスは、あなたの処理の結果を好まないかもしれません...
また、これはデータの 1 回限りのアップグレードを意図していると思いますか? 修正された名前をデータベースにエクスポート、フィルタリング/変更、および再インポートする方が簡単な場合があります。その後、非SQLアプローチを使用して名前を修正できます...
于 2008-10-23T17:44:11.713 に答える
0
悲しいことに、私はさらに別の機能を提案しています。これはほとんどのものよりも高速に見えますが、スペースで区切られた単語の最初の文字のみを大文字にします。入力が null でないこと、および文字列の途中に複数のスペースがある場合に機能することを確認しました。length 関数をクロス適用しているので、2 回呼び出す必要はありません。私は、SQL Server がその値をキャッシュしていると思っていたでしょう。買い手責任負担。
CREATE OR ALTER FUNCTION dbo.ProperCase(@value varchar(MAX)) RETURNS varchar(MAX) AS
BEGIN
RETURN (SELECT STRING_AGG(CASE lv WHEN 0 THEN '' WHEN 1 THEN UPPER(value)
ELSE UPPER(LEFT(value,1)) + LOWER(RIGHT(value,lv-1)) END,' ')
FROM STRING_SPLIT(TRIM(@value),' ') AS ss
CROSS APPLY (SELECT LEN(VALUE) lv) AS reuse
WHERE @value IS NOT NULL)
END
于 2021-03-26T23:23:51.810 に答える
0
最近、これに取り組まなければならず、私が望んでいたすべてのものに何もヒットしなかった後、次のことを思いつきました。これは、特別な単語処理の場合、文全体を実行します。また、多くの単純なメソッドでは処理されますが、より複雑なメソッドでは処理されない単一文字の「単語」にも問題がありました。単一のリターン変数、ループもカーソルもありません。
CREATE FUNCTION ProperCase(@Text AS NVARCHAR(MAX))
RETURNS NVARCHAR(MAX)
AS BEGIN
DECLARE @return NVARCHAR(MAX)
SELECT @return = COALESCE(@return + ' ', '') + Word FROM (
SELECT CASE
WHEN LOWER(value) = 'llc' THEN UPPER(value)
WHEN LOWER(value) = 'lp' THEN UPPER(value) --Add as many new special cases as needed
ELSE
CASE WHEN LEN(value) = 1
THEN UPPER(value)
ELSE UPPER(LEFT(value, 1)) + (LOWER(RIGHT(value, LEN(value) - 1)))
END
END AS Word
FROM STRING_SPLIT(@Text, ' ')
) tmp
RETURN @return
END
于 2019-10-08T15:33:16.930 に答える