2

CNFの命題式を使用して文字列をDIMACSに解析したいので、haskellのネストされたintリストです。この形式は、SAT 解決の他のオプションよりもパフォーマンスが高いと思われる haskell picosat バインディングに適しています。

問題は、これを実装したコードが複雑すぎることです。現在、見つけにくいバグの可能性を探しています。

(私のアプローチは、haskell hatt パッケージを使用し、パッケージを変更して、変数名に単一文字の代わりに文字列を使用し、hatt で式を解析し、結果の式を DIMACS 形式に変換することでした。)

CNF 記法で命題式を表す文字列を解析したい (以下の例を参照)。結果は、ネストされた int のリストになります。したがって、結果はhaskell picosat bindingssolveAllの一部に適しているはずです。

入力：

-- "&" ... conjunction
-- "|" ... disjunction
-- "-" ... not operator

let myCNF = "GP  &  (-GP  |  Ma)  &  (-Ma  |  GP)  &  (-Ma  |  TestP)  &  (-Ma  |  Alg)  &  (-Ma  |  Src)  &  (-Ma  |  Hi)  &  (-Ma  |  Wg | X | Y) & -Z"

結果：

-- DIMACS format
-- every Variable (e.g., "GP") gets a number, say GP gets the int num 1
-- in case of not GP (i.e., "-GP") the int number representing the variable is negative, thus -1

-- Note: I hope I didn't do a type
let myresult = [[1], [-1, 2], [-2, 1], [-2, 3], [-2, 3], [-2, 5], [-2, 6], [-2, 7, 8, 9], [-10]]

let myvars = ["GP", "Ma", "TestP", "Alg", "Src", "Hi", "Wg", "X", "Y", "Z"]

-- or alternativly the variables are stored in an associative array
let varOtherWay = (1, GP), (2, Ma) (3, TestP), (4, Alg), (5, Src), (6, Hi), (7, Wg), (8, X), (9, Y), (10, Z)
4

2 に答える 2

2

おそらく、CNF のステートメントを読み取るのに parsec は必要ありません。変数を抽出できますmap (splitOn "|") . splitOn "&"。残りは変数に整数を代入するだけです。

import qualified Data.Map as M 
import Data.List.Split
import Control.Monad.State 

deleteMany c [] = []
deleteMany c (x:xs) 
  | x`elem`c  =     deleteMany c xs
  | otherwise = x : deleteMany c xs

parseStatement :: String -> ( [[Int]] , M.Map Int String )
parseStatement = 
 f . flip runState (M.empty, 1) . mapM (mapM (readVar . toVar)) . varsOf . deleteMany "() "
  where 
    f (r, (m, _)) = (r , M.fromList $ map (uncurry (flip (,))) $ M.toList m)

    varsOf = map (splitOn "|") . splitOn "&"

    toVar ('-':v) = (True , v)
    toVar v       = (False, v)

    readVar (b,v) = do 
      (m, c) <- get 
      case M.lookup v m of 
        Nothing -> put (M.insert v c m, c+1) >> return (neg b c)
        Just n  ->                              return (neg b n)

    neg True  = negate
    neg False = id

エラー処理やより大きなパーサーへの統合に関しては、パーセック バージョンがまだ興味深いかもしれません。

parseStatement = parse statement "" . deleteMany " "

statement = sepBy1 clause (char '&')

clause = between (char '(') (char ')') x <|> x
  where x = sepBy1 var (char '|')

var = do
  n <- maybe False (const True) <$> optionMaybe (char '-')
  v <- many1 (noneOf "&|-() ")
  return (n, v)
于 2014-05-18T19:21:42.750 に答える
0

あなたが言及したピコサットバインディングを維持しています。この質問を見た後、picologicHackage に新しいパッケージを追加しました。このパッケージは、上に構築されpicosat、命題の数式を解析して変換し、それらを SAT ソルバーにフィードします。

import Picologic

p, q, r :: Expr
p = readExpr "~(A | B)"
q = readExpr "(A | ~B | C) & (B | D | E) & (D | F)"
r = readExpr "(φ <-> ψ)"

ps = ppExprU p
-- ¬(A ∨ B)
qs = ppExprU q
-- ((((A ∨ ¬B) ∨ C) ∧ ((B ∨ D) ∨ E)) ∧ (D ∨ F))
rs = ppExprU (cnf r)
-- ((φ ∧ (φ ∨ ¬ψ)) ∧ ((ψ ∨ ¬φ) ∧ ψ))

main :: IO ()
main = solveProp p >>= putStrLn . ppSolutions
-- ¬A ¬B
-- ¬A B
-- A ¬B

参照: http://hackage.haskell.org/package/picologic

于 2014-06-16T17:11:48.163 に答える